Discussion :

[alain54]

Bonjour,

Je suis nouveau sur ce forum et moyennement "doué" sur excel.

Après avoir parcouru le forum je n'ai pas trouvé de solution à mon problème.

J' ai besoin de passer d'une liste de dates d'absence par employé à un cumul par employé par nombre de jours d'absences consécutifs.

Je joint un fichier en exemple.

D'avance merci à ceux qui pourront m'aider.

[papouclo]

Bonjour,
Voici une proposition en supposant que le premier tableau est toujours ordonné comme dans l'exemple (ordre alphabétique sur la plage A5:A59 puis ordre chronologique sur la plage B5:B59)
Ecrire en E7 la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(SOMME($H$6:H6)<LIGNES($A$5:$A$59);DECALER($A$5;SOMME($H$6:H6););"")

en F7 la formule:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(E7="";"";DECALER($B$5;SOMME($H$6:H6);))

en G7 la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(E7="";"";SOMMEPROD(MAX(($A$5:$A$59=E7)*$B$6:$B$60*($B$6:$B$60=F7+LIGNE($B$6:$B$60)-EQUIV(F7;B:B;0)))))

en H7 la formule:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(E7="";"";G7-F7+1)

Recopier chacune des quatre formules vers le bas.
Cordialement
Claude

[alain54]

Merci papouclo de m'aider.

Il y à juste un problème , lorsque je met plus de lignes dans le fichier , le résultat tombe en anomalie.

Bien sur j'ai retouchée la formule en E7 et G7 par rapport au nombre de lignes à analyser.

Je joint le fichier pour exemple.

Cordialement.

[alain54]

Bonjour papouclo,

Le problème existe lorsqu'une même date de début d'absence existe déjà pour un employé de la liste.

Dans mon exemple EMPL4 à une période d'absence qui commence le 07/06/2013 ce qui génère une erreur sur la date de fin, EMPL2 à aussi une période d'absence qui commence le même jour.

Après plusieurs essais je confirme que le problème existe dans ce cas de figure.

Merci de m'aider à résoudre ce problème.

Cordialement.

[papouclo]

Bonjour,
J'ai dû batailler pour obtenir la deuxième version du classeur avant de la récupérer aujourd'hui.
S'il y a deux employés pour lesquels les absences débutent le même jour, cela pose bien sûr problème pour le second avec l'emploi de la fonction EQUIV.
En G7, remplacer la première formule donnée par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(E7="";"";SOMMEPROD(MAX(($A$5:$A$92=E7)*$B$6:$B$93*($B$6:$B$93=F7+LIGNE($B$6:$B$93)-5-SOMME($H$6:H6)))))

recopier vers le bas.
Cordialement
Claude

[alain54]

Bonjour papouclo,

D'abord un grand merci pour l'aide que vous m'apportez.

Il reste encore quelques cas bizarres , exemple EMPL8 qui est absent le 02/04/2013 et qui tombe en erreur.

Ce cas se présente chaque fois qu'un agent n'est absent qu'un jour , et que ce jour est sa première absence de l'année.

Je vous joint un fichier qui illustre ce cas.

Cordialement.

[papouclo]

Bonjour Alain,
Bravo pour la recherche de tous les cas pouvant poser problème.
Ecrire en G7 la formule

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(E7="";"";MAX(F7;SOMMEPROD(MAX(($A$5:$A$77=E7)*$B$6:$B$78*($B$6:$B$78=F7+LIGNE($B$6:$B$78)-5-SOMME($H$6:H6))))))

Remarque :
Le rajout de nouvelles lignes au tableau des colonnes A:B oblige chaque fois à modifier les formules des cellules E7 et G7 avant de recopier vers le bas.
Le choix de noms définis de façon dynamique au moyen de la fonction DECALER pour les plages A5:Ax et B6:Bx+1 éviterait cette corvée.
Cordialement
Claude

[alain54]

Un grand merci claude pour votre disponibilité , compétence et gentillesse.

Il me reste à faire travailler mes neurones pour votre remarque sur l’utilisation des plages et de la fonction DECALER.

Cordialement.