Discussion :

[anonymous9]

Bonjour à tous,

Ficher pièce jointe pour visu du problème.

en ligne 1 : intitulé des colonnes
COLONNE A = Numéro de facture (il peux y avoir plusieurs fois le meme numéro dans les cellules qui suivent)
COLONNE B = DATE (je souhaite mettre la somme du montant des factures avec le meme numéro de facture sur la meme ligne que la date)
COLONNE C = GENRE de facture (FACTURE = "F", ACOMPTE = "A", DEVIS = "D") . Dans la somme des montants des factures je ne souhaite pas inclure les DEvis)
COLONNE D = MONTANT DES FACTURES
COLONNE F = Somme factures (où je souhaite mettre la formule)

A partir de la ligne 2 : les données

La formule que j'ai mise en cellule F2 que j'ai copié le long de la colonne F : =SI(OU(C2="F";C2="A");SOMME.SI($A$2:$A$29;A2;$D$2:$D$29);"")

- La FOrmule ne fonctionne pas correctement, elle ne respecte pas les Devis, Acomptes...
- je n'arrive pas à mettre le résultat dans la ligne correspondante à la date
- et quelques bugs

Merci de votre aide si vous avez la solution

[Philippe Tulliez]

Bonjour,

COLONNE A = Numéro de facture (il peux y avoir plusieurs fois le meme numéro dans les cellules qui suivent)

Cela signifie que ta table de données contient le détail des factures, ou bien est-ce un même numéro avec un code Genre de facture différent ?
A première vue, si tu souhaites faire la somme de valeurs suivant plusieurs critères, il faut te diriger soit vers SOMMEPROD, soit vers SOMME.SI.ENS (moins souple que la précédente et non compatible avec version antérieure à 2007) soit vers une formule matricielle
Il y a également l'outil tableau croisé dynamique qui permet de faire la synthèse.
Il faudrait évidemment idéalement que les acomptes aient un signe opposé au montant de la facture sinon une double formule qui ferait la synthèse des Montants - la synthèse des acomptes

Par exemple cette formule donne la somme des factures ouvertes (toutes factures confondues)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI($C$2:$C$15;"=F";$D$2:$D$15) - SOMME.SI($C$2:$C$15;"=A";$D$2:$D$15)

)
Cette formule donne le solde par facture à condition que l'acompte soit encodé en négatif

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SOMMEPROD((($C$2:$C$15="F")+($C$2:$C$15="A")>0)*($A2=$A$2:$A$15)*$D$2:$D$15)

Sinon

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD( ($C$2:$C$15="F") * ($A2=$A$2:$A$15) * $D$2:$D$15) - SOMMEPROD( ($C$2:$C$15="A") * ($A2=$A$2:$A$15) * $D$2:$D$15)

Si tu tires la formule vers le bas, les lignes qui ont comme code "A" auront le même résultat alors tu peux faire précéder par un SI, comme par exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(C2="F";SOMMEPROD((($C$2:$C$15="F")+($C$2:$C$15="A")>0)*($A2=$A$2:$A$15)*$D$2:$D$15);"")

[anonymous9]

Bonjour,

Cela signifie que ta table de données contient le détail des factures, ou bien est-ce un même numéro avec un code Genre de facture différent ?
A première vue, si tu souhaites faire la somme de valeurs suivant plusieurs critères, il faut te diriger soit vers SOMMEPROD, soit vers SOMME.SI.ENS (moins souple que la précédente et non compatible avec version antérieure à 2007) soit vers une formule matricielle
Il y a également l'outil tableau croisé dynamique qui permet de faire la synthèse.
Il faudrait évidemment idéalement que les acomptes aient un signe opposé au montant de la facture sinon une double formule qui ferait la synthèse des Montants - la synthèse des acomptes

Par exemple cette formule donne la somme des factures ouvertes (toutes factures confondues)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMME.SI($C$2:$C$15;"=F";$D$2:$D$15) - SOMME.SI($C$2:$C$15;"=A";$D$2:$D$15)

)
Cette formule donne le solde par facture à condition que l'acompte soit encodé en négatif

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SOMMEPROD((($C$2:$C$15="F")+($C$2:$C$15="A")>0)*($A2=$A$2:$A$15)*$D$2:$D$15)

Sinon

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD( ($C$2:$C$15="F") * ($A2=$A$2:$A$15) * $D$2:$D$15) - SOMMEPROD( ($C$2:$C$15="A") * ($A2=$A$2:$A$15) * $D$2:$D$15)

Si tu tires la formule vers le bas, les lignes qui ont comme code "A" auront le même résultat alors tu peux faire précéder par un SI, comme par exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(C2="F";SOMMEPROD((($C$2:$C$15="F")+($C$2:$C$15="A")>0)*($A2=$A$2:$A$15)*$D$2:$D$15);"")

Merci Beaucoup de l'aide

c'est un même numéro avec un code Genre de facture différent.

Dans mon cas, j'ai appliqué cette formule, SI(OU($C2="F";$C2="A");SOMME.SI($A$2:$A$208;A2;$D$2:$D$208);"")

Par contre j'ai une question a quoi servent les * ou - ou + entre les formules et qui sont suivies d'un espace ?

[Philippe Tulliez]

Bonjour,

Par contre j'ai une question a quoi servent les * ou - ou + entre les formules et qui sont suivies d'un espace ?

La formule que j'ai proposée avec SOMMEPROD est basée sur l'utilisation détournée de cette formule et est basée sur une suite de test logique.
Une suite de * est équivalent à un ET et les + sont l'équivalent d'un OU.
Pour comprendre ce principe, nous allons prendre un cas simple.
Imaginons qu'en colonne A, nous ayons des lettres qui représente le sexe des personnes (F ou H), en colonne B la ville de naissance et en colonne C le nombre d'enfant.
Problème 1 : La commune de Champignac décide d'octroyer une prime de 50 € à toutes les femmes, née dans la commune et ayant au moins 1 enfant.
Si l'on prend cette formule que l'on place en colonne D2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= (A2="F") * (B2="Champignac") * (C2>0) * 50

La formule va renvoyer 50 si toutes les conditions sont remplies
C'est l'équivalent de la formule ci-dessous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=ET(A2="F";B2="Champignac";C2>0) * 50

Problème 2 : La commune de Champignac décide d'octroyer une prime de 50 € à toutes les femmes, née dans la commune ou ayant au moins 1 enfant.
La formule suivante va renvoyer 50 si les conditions sont remplies.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= ( ( (B2="Champignac") + (C2>0) ) >0) * (A2="F") * 50

C'est l'équivalent de

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=ET(A2="F";OU(B2="Champignac";C2>0)) * 50

Chaque test logique renvoie VRAI ou FAUX et VRAI vaut 1, FAUX vaut 0
Donc 1 * 1 * 1 * 50 donne 50 et 1 * 0 * 1 * 50 donne 0 c'est donc bien l'équivalent d'un ET
Pour le OU, prenons un simple exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=((B2="Champignac") + (C2>0)) * 50

Si une des conditions est remplie, la formule renverra 50 mais si les deux conditions sont remplies nous aurons 100 donc dans le cas d'une suite de + il faut ajouter l'opérateur de comparaison > ou >= par exemple pour refaire un test logique qui renverra VRAI ou FAUX soit 1 ou 0

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=(  ( (B2="Champignac") + (C2>0)) >0 ) * 50

Le groupe de test en rouge renvoie un seul VRAI soit 1.

J'espère que c'est plus clair.
Ce type de test fait également l'économie d'un SI et c'est plus rapide pour le processeur (pour des dizaines de milliers de cellules à traiter bien entendu).

[anonymous9]

Merci d'avoir pris le temps pour m'expliquer correctement

J'ai compris

Il me faut juste un peu de pratique maintenant