Demande d'aide sur enregistrement zone de liste

**zizou74** · 20/02/2014, 08h55

Bonjour ,

Je débute sur access, j'ai cherché des heures en vain mais désolé je n'y suis pas arrivé

J'ai créé un formulaire avec une zone de liste comprenant des marques de machines et et une seconde liste comprend les modèles. Tous les modèles s'affichent bien en fonction de mes marques sélectionnées mais seulement cela fonctionne uniquement sur la 1ère ligne car en passant à l'enregistrement suivant, dès lors que je sélectionne la marque le modèle de la 1ère ligne s'efface directement.

Voici mon sql de ma marque se trouvant dans l’onglet Evènement/Après MAJ :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Sub Form_Current()
  Me.Modeles.Requery
End Sub
 
Private Sub Marques_AfterUpdate()
Me.Modeles.Requery
Me.Modeles = Me.Modeles.ItemData(0)
End Sub

Dans modèle, je n'ai pas crée d’événement.

Merci d'avance encore pour votre aimable support.

Cordialement
Zizou

**ClaudeLELOUP** · 20/02/2014, 10h17

Bonjour,

Explique ce que tu essaies de faire.

Au besoin, montre une capture d'écran de ton formulaire pour expliquer le résultat que tu voudrais atteindre.

**zizou74** · 20/02/2014, 10h34

Merci pour votre réponse.

Voilà ce que je souhaite réaliser:

sur la 1ère ligne tout se présente bien et je peux compléter mes champs normalement.

Mais dès lors que je passe à la seconde ligne (2nd enregistrement) et je clique dans la zone marque, le choix de ma zone de liste "modèle" effectué dans le 1er enregistrement s'efface et ne reste pas mémorisé (voir pj).

Cordialement
Zizou

**ClaudeLELOUP** · 20/02/2014, 11h33

Ton code n'est certainement pas bon !

Affiche la propriété "Contenu" des deux zones de liste. (Si ce sont des requêtes enregistrées, montre leur sql.)

**zizou74** · 20/02/2014, 11h40

Zone de liste (marques):

Code SQL :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
SELECT [T-MARQUES].CodeMarques, [T-MARQUES].Marques
FROM [T-MARQUES]
ORDER BY [T-MARQUES].Marques

Zone de liste (modèles) :

Code SQL :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
SELECT [T-MODELES].CodeModeles, [T-MODELES].Modeles
FROM [T-MODELES]
WHERE ((([T-MODELES].Marques)=[Formulaires]![SF-PARC MACHINES]![CodeMarques]));

Merci.

**ClaudeLELOUP** · 20/02/2014, 12h13

Ça n'a pas l'air cohérent.

On dirait que la zone de liste qui contient la marque s'appelle "CodeMarques"

Comment s'appellent tes deux zones de listes ?

**zizou74** · 20/02/2014, 12h21

1ère zone de liste :[/B][/B]
Nom: marques
Source contrôle : CodeMarques

2nde zone de liste :
Nom: modeles
Source contrôle : CodeModeles

**ClaudeLELOUP** · 20/02/2014, 13h29

Ceci devrait donner le résultat attendu : la liste Modeles se limite aux modèles de la marque renseignée dans la liste Marques.

Cette liste s'actualise à chaque lecture d'enregistrement et à chaque modif de Marques.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Option Compare Database
Option Explicit
 
Private Sub Form_Current()
  Me.Modeles.RowSource = Me.Modeles.RowSource
End Sub
 
Private Sub Marques_AfterUpdate()
   Me.Modeles.RowSource = Me.Modeles.RowSource
End Sub

**zizou74** · 20/02/2014, 14h46

Merci à toi pour ce nouveau code sql mais malheureusement ça ne fonctionne toujours pas.

Je souhaite bien que les modèles de la seconde liste s'affichent en fonction de la marque, ça c'est ok.

Le seul problème est dans l'enregistrement, lorsque je clique sur Marques dans la seconde ligne il se trouve que le champ modèle ne reste pas en mémoire.

**ClaudeLELOUP** · 20/02/2014, 15h13

Si tu peux poster ta db en version Access2000, je regarderai sur pièce.
Sinon, je ne sais pas t'aider davantage.

**zizou74** · 20/02/2014, 15h41

Merci beaucoup pour ton support claudeLELOUP

Ci-joint mon fichier. Le problème se pose sur le formulaire SF-PARC MACHINES.

**ClaudeLELOUP** · 20/02/2014, 22h57

Ça ne fonctionne pas dans un formulaire continu : pour que tous les Modèles s’affichent dans tous les enregistrements, le contenu de sa zone de liste ne peut pas être limité.

Je te propose ceci.

En situation normale : pas de limitation

dans l’événement sur activation ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Private Sub Form_Current()
  ' sans limitation
  Me.Modeles.RowSource = "SELECT [T-MODELES].CodeModeles, [T-MODELES].Modeles,[T-MODELES].Marques " _
                            & "FROM [T-MODELES];"
End Sub

Dès l’instant où l’utilisateur a mis à jour CodeMarques, on pose la limite

dans l’événement après Mise à jour ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub Marques_AfterUpdate()
   'Avec limitation
   Me.Modeles.RowSource = "SELECT [T-MODELES].CodeModeles, [T-MODELES].Modeles,[T-MODELES].Marques " _
                            & "FROM [T-MODELES] " _
                            & "WHERE ((([T-MODELES].Marques)=[Formulaires]![SF-PARC MACHINES]![CodeMarques]));"
End Sub

Et pour éviter que l’utilisateur essaie de modifier le modèle sans modifier la marque (ce serait possible, puisque pas de limite en temps normal !)

dans l’événement avant Mise à jour ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Sub Modeles_BeforeUpdate(Cancel As Integer)
  'Vérifier la cohérence Marque/Modèle
  If Me.Modeles.Column(2) <> Nz(Me.CodeMarques, "") Then
       MsgBox "Incohérence Marque/Modèle"
       Cancel = True
       Me.Undo
  End If
End Sub

N.B. J'ai donc ajouté une 3e colonne. Modeles.Column(2) se réfère à cette 3e colonne (Access commence sa numérotation à zéro).

Soit dit en passant, ton modèle de données n'est pas top : tu as des doublons dans les marques et dans les modèles.

**zizou74** · 21/02/2014, 10h48

Bonjour ClaudeLELOUP,

Je ne sais comment te remercier pour ta solution car maintenant ça marche, tu es SUPER

Toutefois, dans ce sous formulaire j'ai encore 2 petits problèmes à régler qui sont :

1/ Quand j'intègre ce sous formulaire dans mon formulaire principal (F-SOCIETES), je clique sur la marque OK et quand je choisi le Modèle une fenêtre me demande d'entrer une valeur de paramètre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Formulaires!SF-PARC MACHINES!CodeMarques.

2/ Je souhaite que ma cellule Remarques de mon SF Parc machines s'affiche comme à l'écran excepté que lorsque je cliquerai sur la flèche en bout de cellule, je souhaite que ça ouvre le contenu de la cellule vers le bas sur une hauteur d'environ 5 cm pour faciliter la lecture, est-ce possible sachant que ce n'est pas vraiment une zone de liste ?

Merci d'avance encore pour ton aimable support

Zizou

**ClaudeLELOUP** · 21/02/2014, 11h47

Bonjour,

1/ Quand j'intègre ce sous formulaire dans mon formulaire principal (F-SOCIETES), je clique sur la marque OK et quand je choisi le Modèle une fenêtre me demande d'entrer une valeur de paramètre

L’explication est la suivante :
Pour le contenu de la zone de liste Modèles tu as ce SQL

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SELECT [T-MODELES].CodeModeles, [T-MODELES].Modeles,[T-MODELES].Marques FROM [T-MODELES] WHERE ((([T-MODELES].Marques)=[Formulaires]![SF-PARC MACHINES]![CodeMarques]));

C’est-à-dire que tu fais référence à un formulaire nommé « SF-PARC MACHINES » qui doit être ouvert.
Lorsque tu intègres un sous-formulaire dans un autre formulaire « principal », c’est le formulaire « principal » qui est « ouvert »

pour se référer au contenu d’un contrôle du sous-formulaire, il faut utiliser une syntaxe du genre

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Forms!LeNomDuPrincipal!LeNomDuConteneurDuSousFormulaire.Form!LeNomDuControle

2/ Je souhaite que ma cellule Remarques de mon SF Parc machines s'affiche comme à l'écran excepté que lorsque je cliquerai sur la flèche en bout de cellule, je souhaite que ça ouvre le contenu de la cellule vers le bas sur une hauteur d'environ 5 cm pour faciliter la lecture, est-ce possible sachant que ce n'est pas vraiment une zone de liste ?

À mon avis, ce n’est pas possible tel que tu le décris.
Par contre, tu pourrais atteindre ton but en ouvrant un autre formulaire indépendant donnant le détail et qui viendrait s’afficher à proximité du contrôle.
La mise en place n’est pas simple. Vois ce tutoriel qui traite ce sujet
http://claudeleloup.developpez.com/t...re-formulaire/

**zizou74** · 21/02/2014, 17h28

Claude,

désolé de ne pas t'avoir répondu plutôt mais le site était en maintenance.

Ci-dessous mon sql mais je ne sais pas où le placer précisément :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Expr1: [Formulaires]![F-1 SOCIETE]![PARC MACHINES].[Form]![Modeles]

Pour info, j'ai placé ce code dans la source du formulaire principal (F1-SOCIETE) mais cela ne fonctionne pas et ensuite j'ai essayé aussi dans le contenu de ma cellule Modeles mais idem.

Merci d'avance pour tes lumières.

Zizou

**ClaudeLELOUP** · 21/02/2014, 17h38

Reposte ta db, c'est dans le code du sous-formulaire que ça se passe.

**zizou74** · 21/02/2014, 19h05

Claude,

Ci-joint ma db, merci beaucoup pour ton aimable support

DB.zip

**ClaudeLELOUP** · 22/02/2014, 12h58

Bonjour Zizou,

Voici le module du formulaire SF-PARC MACHINES, pour que celui-ci puisse fonctionner de manière autonome ou bien en tant que sous-formulaire de n'importe quel autre.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
Option Compare Database
Option Explicit
  Dim sqlAvecLimite As String
  Dim sqlSansLimite As String
 
 
 
Private Sub Form_Open(Cancel As Integer)
  Dim NomParent As String
  On Error GoTo GestionErreurs
  'Construction du SQL sans limite
   sqlSansLimite = "SELECT [T-MODELES].CodeModeles, [T-MODELES].Modeles,[T-MODELES].Marques " _
                            & "FROM [T-MODELES];"
 
  'Construction du SQL de la zone de liste Modèle avec limite
  '                                                 selon un formulaire principal éventuel
  NomParent = Me.Parent.Name  'Cette instruction lève une erreur 2452 si pas de parent,
             '                                 on la récupère dans la gestion d'erreur.
    sqlAvecLimite = "SELECT [T-MODELES].CodeModeles, [T-MODELES].Modeles,[T-MODELES].Marques " _
                            & "FROM [T-MODELES] " _
                            & "WHERE ((([T-MODELES].Marques)=[Formulaires]![" & NomParent & "]![F-PARC MACHINES].[Formulaire]![Marques]));"
  Exit Sub
 
GestionErreurs:
  Select Case Err.Number
    Case 2452  'pas de parent
      sqlAvecLimite = "SELECT [T-MODELES].CodeModeles, [T-MODELES].Modeles,[T-MODELES].Marques " _
                            & "FROM [T-MODELES] " _
                            & "WHERE ((([T-MODELES].Marques)=[Formulaires]![SF-PARC MACHINES]![CodeMarques]));"
    Case Else
      MsgBox "Erreur dans Form_Open " & Err.Number & " " & Err.Description & " !"
  End Select
 
 
End Sub
Private Sub Form_Current()
  ' sans limitation
  Me.Modeles.RowSource = sqlSansLimite
End Sub
 
Private Sub Marques_AfterUpdate()
   'Avec limitation
   Me.Modeles.RowSource = sqlAvecLimite
End Sub
 
 
 
 
Private Sub Modeles_BeforeUpdate(Cancel As Integer)
  'Vérifier la cohérence Marque/Modèle
  If Me.Modeles.Column(2) <> Nz(Me.CodeMarques, "") Then
       MsgBox "Incohérence Marque/Modèle"
       Cancel = True
       Me.Undo
  End If
End Sub

Reviens-moi si les commentaires que j'ai inclus dans le code ne te permettent pas de comprendre comment j'ai fait.

**zizou74** · 24/02/2014, 15h51

Bonjour Claude,

Désolé pour ma réponse tardive mais j'étais en week-end.

Avant tout, je t'adresse un infiniment grand MERCI pour le temps que tu m'as accordé pour la résolution de mes problèmes, c'est super sympa de ta part car des personnes comme toi se font malheureusement rares de nos jours

J'ai créé mon module sur la base du tien mais maintenant je me retrouve devant la difficulté d'indiquer à mon formulaire SF-PARC MACHINES qu'il doit utiliser ce module. J'ai cherché dans mes sources comment rattacher le formulaire au module mais il est indiqué qu'il faut déclarer le module en public, alors ma question est comment faire ? Dois-je modifier toutes mes commandes Private Sub en Public Sub ?
Pour info, je n'ai rien modifié dans les propriétés de mon formulaire et je me suis contenté de créer uniquement le module.

Dans l'attente de tes lanternes, je te remercie vivement pour ton efficace support sans quoi je n'y serai jamais parvenu

Cordialement
Zizou