Discussion :

[RobertThi]

Bonjour,

Est-il possible d'extraire des valeurs (une colonne) d'un tableau vers un autre tableau avec des critères.
Quand j'utilise la fonction suivante: =INDEX((tblPays[Personne]);EQUIV("France";tblPays[Pays];0)) cela me retourne toujours la même valeur,

N'étant pas un expert en Excel comment faire.

Dans le fichier en attaché j'ai un exemple.

Dans le fichier d'origine les 2 tableaux contiennent plusieurs colonnes...

J'aimerais le faire avec des fonctions Excel

Merci de votre collaboration

[patrice084]

En mettant 4 fois la même formule, il semble normal d'obtenir 4 fois la même chose. Concernant votre demande, je n'ai pas compris ce que vous vouliez extraire. Donnez un exemple plus concret.

[RobertThi]

Merci Patrice

Je veux extraire les noms des personnes dont le pays répond au critère du tableau A vers un le tableau B.
Avec index equiv: =INDEX((tblPays[Personne]);EQUIV("France";tblPays[Pays];0)) La validation a été fait par ctrl shift enter

Je demande de me retourner les personnes du tableau tblPays dont le pays est égale à la France. Toutes les personnes de la France doivent apparaître dans le tableau
tblPersonne:

Tableau source
Personne Pays
André Benoit France
Marc Laberge France
Joe Frazier Bretagne
Rodrigo Marques France
Walter Peper Bretagne
Walter Peper Bretagne

Tableau destiné
Personne
André Benoit
Marc Laberge
Rodrigo Marques

Cela doit passer par une fonction excel.

Merci pour vos suggestions,

[papouclo]

Bonjour,
Ecrire en E2 la formule matricielle

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(INDEX((tblPays[Personne]);PETITE.VALEUR(SI((tblPays[Pays]="France");LIGNE(tblPays[Pays])-1;"");LIGNE()-1));"")

à valider par Ctrl + Maj + Entrée.
Mais il est si simple de filtrer le tableau sur la valeur France du champ Pays.
Cordialement
Claude

[RobertThi]

Un sincère merci pour votre support et votre générosité.

Merci Claude pour ta solution qui est exactement ce que je voulais.

Claude si tu peux m'éclairer avec la formule pour bien la comprendre.

SIERREUR( -- on met à blanc
INDEX((tblPays[Personne]); -- Colonne que je avoir les données
PETITE.VALEUR(SI((tblPays[Pays]="France");LIGNE(tblPays[Pays])-1;"") --valide la condition mais point de départ l'entête car c'est un tableau
;LIGNE()-1)); --pourquoi cette partie est-ce à cause du tableau ?
"")

Merci encore à tous,

[papouclo]

Bonjour,
La formule EQUIV("France";tblPays[Pays]) qui était employée dans la première version ne renvoie que la première occurrence de la valeur France dans le champ Pays.
Lorsque l'on veut obtenir toutes les occurrences d'une valeur dans une plage, un des moyens de les obtenir est d'utiliser la fonction PETITE.VALEUR (ou GRANDE.VALEUR) à
condition de travailler sur une plage numérique et donc de remplacer ici les noms du champ PAYS par des nombres d'où la partie de la formule :
SI((tblPays[Pays]="France");LIGNE(tblPays[Pays])-1;"")
Si à une ligne de la colonne B, la cellule contient "France" alors on prend le rang de l'occurrence dans le champ PAYS du tableau obtenu par LIGNE() - 1 ( LIGNE() donnant le rang de cette occurrence dans la colonne B
et non pas dans la plage $B$2:$B$7 ). Si ce n'est pas le cas, on mettra une "valeur vide".
On obtient à la place du France de B2 en mémoire virtuelle la valeur 1; à la place du France de B3 la valeur 2 ; rien à la place du Bretagne de B3 ...
Cette plage numérique virtuelle 1 ; 2 ; ; 4 ; ; (en réalité, il vaudrait mieux l'imaginer en colonne mais je l'écris en ligne pour un gain de place) étant créée, la fonction PETITE.VALEUR
utilise la syntaxe : PETITE.VALEUR (plage numérique ; rang) et dans la cellule B2 , LIGNE() - 1 permet d'obtenir la première valeur la plus petite ; dans la cellule B3, LIGNE()-1 donne
le rang 2 et permet d'obtenir la deuxième valeur dans l'ordre croissant.
Or, ces valeurs sont aussi les rangs des cellules contenant la valeur France dans le champ Pays et , avec la fonction INDEX, elles permettent donc de récupérer les personnes correspondantes.
Cordialement
Claude