Saut de page après chaque groupe de cellules fusionnées

Invité · 21/03/2014, 22h18

Bonsoir,

Je récupère d'une BD des données par macro sur une feuille qui est aussi mise en forme par macro.

Au final, j'ai un tableau où des cellules de la colonne B sont fusionnées, je voudrais insérer des sauts de page après chaque groupe de cellules fusionnées.

Dans la mise en page , j'ai définit l'orientation à paysage et Les lignes 2 à 4 seront répétées sur chaque page.

Mon souci est comment définir par macro les sauts de page car cette plage est dynamique.

En vous remerciant.

Cordialement,

**clementmarcotte** · 22/03/2014, 00h36

Ouvre ton aide et cherche :

Range.MergeArea, propriété

Il a un exemple pour déterminer si une cellule est fusionnée ou non.

Ensuite, enregistre une macro en insérant un saut de page à la mitaine dans Excel.

Ensuite tu adaptes les résultats à ton besoin.

C'est comme cela que tous ceux qui font ton travail et les recherches à ta place ont commencé.

C'est bien beau de profiter de ce forum, mais il faudrait au moins que tu montres que tu fais des efforts.

Invité · 22/03/2014, 08h34

Bonjour clementmarcotte,

Je te remercie pour tes conseils, c'est gentil de m'avoir guidé pour trouver une solution.

C'est comme cela que tous ceux qui font ton travail et les recherches à ta place ont commencé.

Mais est-il nécessaire de vexer les autres?

Je ne suis pas inerte, j'ai effectué des recherches et fait des tests infructueux. Je n'ai pas voulu éditer un code qui ne fonctionne pas.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Sub Saut_Page()
With Sheets(1)
    For i = .Range("b65000").End(xlUp).Row To 2 Step -1
        If .Cells(i, 2).MergeCells = True Then .HPageBreaks.Add Before:=.Cells(i, 2).MergeCells
    Next
End With
End Sub

Comme tu peux le constater mon code est mauvais. Ne pense surtout pas que je n'ai pas consulté l'aide, c'est l'une des toutes premières choses que j'ai apprise.

Une petite question: étiez-vous tous brillant dans ta classe, il y a toujours eu des brillants, des moins bons et des nuls.

ça se passe comme ça aussi sur les Forums, S'il n'y avait pas des nulles comme moi, je ne pense qu'il n'y aurait autant de discussions.

Mais bon, nous sommes des êtres humains faillibles.

Je te remercie beaucoup pour tes conseils. Bonne journée.

Cordialement,

Invité · 22/03/2014, 17h39

Bonjour,

Comme je l'avais dit dans mon post#1, je récupère les données et fusionne les cellules par macro.

J'ai fait beaucoup d'efforts pour résoudre le problème avec mes maigres connaissances du vba et je n'y suis pas parvenu.

Grâce à un code de Boisgontier, que j'ai modifié pour mes besoins. Je suis arrivé à ce que je voulais. Côté célérité ce n'est pas le top.

Donc au lieu de fusionner et ensuite chercher à définir les sauts de page. J'ai fait l'inverse.

j'ai donc utilisé 2 macros qui sont appelées l'une après l'autre depuis un bouton.

J'aurai souhaité trouver la solution avec les cellules fusionnées. Apparemment, son sujet n'a pas intéressé grand monde.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Private Sub CommandButton1_Click()
SautPageGroupe
merge2
ActiveWindow.SelectedSheets.PrintPreview
End Sub
 
Sub SautPageGroupe()
   ActiveSheet.PageSetup.PrintTitleRows = "$2:$4"
   ActiveSheet.ResetAllPageBreaks ' raz
   For i = 5 To [B65000].End(xlUp).Row
     If Cells(i + 1, 2) <> Cells(i, 2) Then
        ActiveWindow.SelectedSheets.HPageBreaks.Add Before:=Cells(i + 1, 1)
        End If
   Next
 
End Sub
 
Sub merge2()
Dim i As Integer, m As Integer
  Application.DisplayAlerts = False
  i = 5
  Do While Cells(i, 2) <> ""
    m = i
    Do While Cells(i, 2) = Cells(m, 2)
      i = i + 1
    Loop
    Cells(m, 2).Resize(i - m).MergeCells = True
    Cells(m, 2).Resize(i - m).VerticalAlignment = xlCenter
  Loop
End Sub

Ce n'est pas le top, mais ça fonctionne.

Merci quand même, bon week-end à tous.

Cordialement,

Invité · 06/04/2014, 16h11

Boujour,

Est-ce quelqu'un peut me donner un coup de main pour définir des sauts de page à chaque groupe de cellules fusionnées.

J'ai trouvé une solution qui insère un saut de pages quand la cellule change de valeur (colonne B).

En vous remerciant beaucoup.

**clementmarcotte** · 06/04/2014, 20h30

Va voir là:

http://excel.developpez.com/cours/?page=prog

Ceux qui te répondent on tous commencés avec de faibles connaissances. Et puis, je pense que plusieurs sont tannés de se décarcasser pour toi et de se faire dire que tu as trouvé ta propre solution. Donc, tes "faibles connaissances" ne sont probablement pas si faibles que cela.

Invité · 07/04/2014, 08h28

Bonjour,

Avant merci pour ton lien, je suis sûr d'y trouver des choses intéressantes.

Et puis, je pense que plusieurs sont tannés de se décarcasser pour toi

Pourquoi de tels propos? Si tu as le sentiment que tu décarcasses pour les autres, il fallait tout simplement ignorer ma discussion.
Je pensais faire partie d'une communauté d'entraide et de partage. Fort heureusement, j'ai eu le plaisir de rencontrer des gens de très grandes valeurs qui m'ont aidé en toute humilité et à titre gracieux. Auxquels j'ai exprimé toute ma gratitude et ma reconnaissant.
Le Sieur qui m'a le plus marqué sur ce forum est le Grandissime Maestro MERCATOG. Pour sa gentillesse, son humilité, sa patience et ses compétences.

Mais bon, on est tous égaux et différents.

Je te remercie encore une fois.

Bonne journée.

Cordialement,

**casefayere** · 07/04/2014, 10h21

Bonjour,

essayes ce code qui fusionne les cellules et mets en place tes sauts de page, attention il fonctionne bien sur des cellules qui ne sont pas fusionnées à l'origine

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub SautPageGroupe()
Dim i As Integer, Dl As Range, Deb As Range, Fin As Range
With Sheets("Feuil2") 'à adapter au nom de la feuille
  .ResetAllPageBreaks ' raz
  Set Dl = .Range("B" & .Rows.Count).End(xlUp)
  Set Fin = Dl
  For i = Dl.Row To 5 Step -1
    If Trim(.Range("B" & i - 1)) <> Trim(.Range("B" & i)) Then
    Application.DisplayAlerts = False
      Set Deb = .Range("B" & i)
      .Range(Deb, Fin).MergeCells = True
      .Range(Deb, Fin).VerticalAlignment = xlCenter
      .Range(Deb, Fin).Orientation = 0
      .Range(Deb, Fin).AddIndent = False
      .Range(Deb, Fin).IndentLevel = 0
      .Range(Deb, Fin).ShrinkToFit = False
      .Range(Deb, Fin).ReadingOrder = xlContext
      .Range(Deb, Fin).VerticalAlignment = xlCenter
      .Range(Deb, Fin).WrapText = False
      ActiveWindow.SelectedSheets.HPageBreaks.Add Before:=Deb
      Set Fin = .Range("B" & i - 1)
    Application.DisplayAlerts = True
  End If
Next i
End With
End Sub

Invité · 07/04/2014, 11h11

Bonjour Casefayere,

Je te remercie pour ton code, il fonctionne bien comme tu me l'avais souligné sur des cellules non fusionnées.

J'avais trouvé une solution avec 2 macros, je préfère la tienne. Merci, pourrais-tu m'expliquer pourquoi tu as mis 5, car à priori je ne connais pas le nombre de lignes.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

For i = Dl.Row To 5 Step -1

J'aurais souhaité un code qui traite les cellules fusionnées pour au moins essayer de comprendre le pourquoi et le comment de la chose.

Mais il me semble que je vais me contenter de ta solution, car depuis l'ouverture de cette discussion, je n'ai pas eu beaucoup de réponse.

Merci beaucoup de m'avoir secouru.

Bonne journée.

Cordialement,

**casefayere** · 07/04/2014, 11h21

Re,
ci-dessous le (les) codes revus pour éliminer les fusions éventuelles avant de traiter

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub SautPageGroupe()
Dim i As Integer, Dl As Range, Deb As Range, Fin As Range
With Sheets("Feuil2") 'à adapter au nom de la feuille
  .ResetAllPageBreaks ' raz
  nonfusion
  Set Dl = .Range("B" & .Rows.Count).End(xlUp)
  Set Fin = Dl
  For i = Dl.Row To 5 Step -1
    If Trim(.Range("B" & i - 1)) <> Trim(.Range("B" & i)) Then
    Application.DisplayAlerts = False
      Set Deb = .Range("B" & i)
      .Range(Deb, Fin).MergeCells = True
      .Range(Deb, Fin).VerticalAlignment = xlCenter
      .Range(Deb, Fin).Orientation = 0
      .Range(Deb, Fin).AddIndent = False
      .Range(Deb, Fin).IndentLevel = 0
      .Range(Deb, Fin).ShrinkToFit = False
      .Range(Deb, Fin).ReadingOrder = xlContext
      .Range(Deb, Fin).VerticalAlignment = xlCenter
      .Range(Deb, Fin).WrapText = False
      ActiveWindow.SelectedSheets.HPageBreaks.Add Before:=Deb
      Set Fin = .Range("B" & i - 1)
    Application.DisplayAlerts = True
  End If
Next i
End With
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub nonfusion()
Dim Dl As Range, Deb As Range, cel As Range
With Sheets("Feuil2") 'à adapter au nom de la feuille
  .ResetAllPageBreaks ' raz
  Set Dl = .Range("B" & .Rows.Count).End(xlUp)
  For Each cel In .Range("B5", Dl)
    If cel.MergeCells = True Then
      Set Deb = .Range(cel.MergeArea.Address)
      cel.MergeCells = False
      Deb = .Range(Split(Deb.Address, ":")(0))
    End If
  Next cel
End With
 
End Sub

...pourquoi tu as mis 5, car à priori je ne connais pas le nombre de lignes.

parce que, apparemment tes données commencent en ligne 5 et, comme on remonte de la fin.....

Invité · 07/04/2014, 11h28

Re, Casefayere

Autant pour moi, je viens de comprendre le "5". Merci, c'est la 5ème ligne. C'est OK.

Je me donne une journée pour clôturer cette discussion. J'attends une éventuelle réponse pour des sauts de page par rapport à des cellules fusionnées.

Tous mes remerciements aux bénévoles.

Cordialement,

Cat

**casefayere** · 07/04/2014, 11h31

...J'attends une éventuelle réponse pour des sauts de page par rapport à des cellules fusionnées....

Il me semble que j'ai répondu à ta demande

Invité · 07/04/2014, 11h33

Oups! nos messages se sont entrecroisés.

Merci pour tout mon cher Casefayere.

Cordialement,

Cat

**casefayere** · 07/04/2014, 11h36

Je viens de m'apercevoir d'un petit problème car ta première page, avec mon code ne comporte que les entêtes.

voilà, c'est corigé :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub SautPageGroupe()
Dim i As Integer, Dl As Range, Deb As Range, Fin As Range
With Sheets("Feuil2") 'à adapter au nom de la feuille
  .ResetAllPageBreaks ' raz
  nonfusion
  Set Dl = .Range("B" & .Rows.Count).End(xlUp)
  Set Fin = Dl
  For i = Dl.Row To 5 Step -1
    If Trim(.Range("B" & i - 1)) <> Trim(.Range("B" & i)) Then
    Application.DisplayAlerts = False
      Set Deb = .Range("B" & i)
      .Range(Deb, Fin).MergeCells = True
      .Range(Deb, Fin).VerticalAlignment = xlCenter
      .Range(Deb, Fin).Orientation = 0
      .Range(Deb, Fin).AddIndent = False
      .Range(Deb, Fin).IndentLevel = 0
      .Range(Deb, Fin).ShrinkToFit = False
      .Range(Deb, Fin).ReadingOrder = xlContext
      .Range(Deb, Fin).VerticalAlignment = xlCenter
      .Range(Deb, Fin).WrapText = False
      If Deb.Row > 5 Then ActiveWindow.SelectedSheets.HPageBreaks.Add Before:=Deb
      Set Fin = .Range("B" & i - 1)
    Application.DisplayAlerts = True
  End If
Next i
End With
End Sub

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub nonfusion()
Dim Dl As Range, Deb As Range, cel As Range
With Sheets("Feuil2") 'à adapter au nom de la feuille
  .ResetAllPageBreaks ' raz
  Set Dl = .Range("B" & .Rows.Count).End(xlUp)
  For Each cel In .Range("B5", Dl)
    If cel.MergeCells = True Then
      Set Deb = .Range(cel.MergeArea.Address)
      cel.MergeCells = False
      Deb = .Range(Split(Deb.Address, ":")(0))
    End If
  Next cel
End With
 
End Sub

Invité · 07/04/2014, 11h44

Désolé, mais encore une fois nos réponses se sont entrecroisées.

J'ai bien appuyé sur

Je clôture cette discussion tout en continuant mes recherches pour trouver une solution qui traite
ces satanées cellules fusionnées source de bien des déboires aux "exceliens".

Et je reviendrai pour éditer la solution.

Cordialement,

Cat

**casefayere** · 07/04/2014, 13h30

J'ai l'impression que tu as tout de même loupé mes post 12 13 14 car il me semble que j'ai répondu à tous ces deux problèmes (fusion, saut de page)

**mercatog** · 07/04/2014, 14h07

Bonjour Cathodique, casefayere, clementmarcotte et le forum.

Une autre proposition

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub HP()
Dim LastLig As Long
Dim c As Range
 
Application.ScreenUpdating = False
With Worksheets("Feuil1")
    .PageSetup.PrintTitleRows = "$2:$4"
    .ResetAllPageBreaks
 
    LastLig = .Cells(.Rows.Count, "B").End(xlUp).Row
    Set c = .Range("B" & LastLig).MergeArea(1, 1)
    Do While c.Row > .Range("B4").MergeArea.Count + 4
        .HPageBreaks.Add Before:=c
        Set c = c.Offset(-1, 0).MergeArea
    Loop
    Set c = Nothing
End With
End Sub

EDIT: Valable même si un groupe contient une seule ligne (pas de fusion)

**casefayere** · 07/04/2014, 14h21

Bonjour mercatog,

Ta solution pour les sauts de page me plait (toujours aussi efficace), vois-tu une solution plus rationnelle que la mienne quant à créer les cellules fusionnées ?

Ce n'est pas pour moi mais ça instruit toujours,

Bonne journée

**mercatog** · 07/04/2014, 14h37

Bonjour Dominique

Pour fusionner et appliquer les sauts de pages, je ferai à la PCMan

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Fusion()
Dim LastLig As Long, i As Long
 
Application.ScreenUpdating = False
With Worksheets("Feuil1")
    LastLig = .Cells(.Rows.Count, "B").End(xlUp).Row
    For i = LastLig To 5 Step -1
        If .Range("B" & i) = .Range("B" & i - 1) Then
            .Range("B" & i - 1).ClearContents
            .Range("B" & i - 1 & ":B" & i).Merge
        Else
            If i > 5 Then .HPageBreaks.Add Before:=.Range("B" & i - 1)
        End If
    Next i
End With
End Sub

**casefayere** · 07/04/2014, 14h47

Merci,

sauf que j'ai remarqué, d'après le fichier envoyé par cathodique que tes sauts de page se retrouvent décalés, je corrigerais donc cette ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

            If i > 5 Then .HPageBreaks.Add Before:=.Range("B" & i)

Saut de page après chaque groupe de cellules fusionnées [XL-2007]

Macros et VBA Excel

Discussions similaires

Partager

Partager