Discussion :

[j0joo]

Bonjour,

Débutant en vba je souhaite automatiser certaines taches sur Excel.

J'ai un fichier de 8000 lignes, ce que j'aimerai faire c'est supprimer toutes les lignes qui ne contiennent pas la valeur 12 dans la colonne AP.

J'ai essayé ce code. Mais il me supprime les en-tête de colonne et prend énormément de temps.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub Supprime()
    For Each cellule In Range("AP1:AP8000")
        If cellule.Value <> "12" Then Rows(cellule.Row).Delete
    Next
End Sub

Je suis sur qu'il y a un autre moyen pour supprimer les lignes.

Merci de votre aide.

[Gado2600]

Bonjour,
As-tu essayé avec :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Sub Supprime()
For i = 1 to Range("AP65536").end(xlup).row
      If cellule.Value <> "12" Then Rows(i & ":" & i).Delete shift:=xlUp
Next
End Sub

?

Cordialement,

[casefayere]

Bonjour,
quand on supprime des lignes dans une boucle, on commence par la fin

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Supprime()
Dim Dl As Range, i As Long
With Sheets("Feuil1")  'a remplacer par le nom de feuille
  Set Dl = .Range("AP" & .Rows.Count).End(xlUp)
  For i = Dl.Row To 2 Step -1
      If .Range("AP" & i) <> "12" Then Rows(i).EntireRow.Delete
  Next i
End With
End Sub

mais ça ne résoudra pas le problème de rapidité, peut-être faut'il passer par un tableau !

Autre solution :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub Supprime()
Dim Dl As Range
With Sheets("Feuil1")  'a remplacer par le nom de feuille
  Set Dl = .Range("AP" & .Rows.Count).End(xlUp)
    .Range("AP2", Dl).AutoFilter Field:=1, Criteria1:="<>12", _
        Operator:=xlAnd
    .Range("AP2", Dl).SpecialCells(xlCellTypeVisible).EntireRow.Delete
    .AutoFilterMode = False
End With
End Sub

[Gado2600]

Yes ! Exact ! J'ai oublié ce détails sur la boucle !

[casefayere]

Yes ! Exact ! J'ai oublié ce détails sur la boucle !

re,
De toutes façon, je pense que ma dernière proposition gagne énormément en rapidité

Bonne journée

[j0joo]

Merci à tous les deux pour vos réponses;

Casefayere, la 1ère macro que tu m'as proposé fonctionne bien et je comprends a peu prés le code. Juste une question pourquoi allons nous jusque 2 dans la boucle For i = Dl.Row To 2

Le deuxième fonctionne et gagne en rapidité mais à vrai dire je ne comprends pas vraiment le code...

Autre solution :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub Supprime()
Dim Dl As Range
With Sheets("Feuil1")  'a remplacer par le nom de feuille
  Set Dl = .Range("AP" & .Rows.Count).End(xlUp)
    .Range("AP2", Dl).AutoFilter Field:=1, Criteria1:="<>12", _
        Operator:=xlAnd
    .Range("AP2", Dl).SpecialCells(xlCellTypeVisible).EntireRow.Delete
    .AutoFilterMode = False
End With
End Sub

Bonne journée.

[casefayere]

...Juste une question pourquoi allons nous jusque 2 dans la boucle For i = Dl.Row To 2

Parce que j'imagine que la 1ère ligne est réservée aux titres de colonne

Le deuxième fonctionne et gagne en rapidité mais à vrai dire je ne comprends pas vraiment le code...

je passe par un filtre qui sélectionne les lignes non désirées, les supprime et j'enlève le filtre. Si tu fais le code en mode "pas à pas", tu pourras voir ce qui se passe au fur et à mesure, sinon je te renvoie le code avec explications

[j0joo]

Merci pour les infos, je vois à peu prés. Il faut que je familiarise avec les expressions.

[casefayere]

Quelques explications, n'hésites pas à utiliser l'aide en sélectionnant le ou les mots clé que tu ne comprends pas et en cliquant sur F1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Sub Supprime()
Dim Dl As Range 'variable objet qui stockera la cellule recherchée (la dernière dans notre cas)
With Sheets("Feuil1")  'a remplacer par le nom de feuille, pour With, voir dans l'aide
  Set Dl = .Range("AP" & .Rows.Count).End(xlUp) 'on recherche donc la dernière cellule en col "AP" que l'on stocke en Dl
    .Range("AP2", Dl).AutoFilter Field:=1, Criteria1:="<>12", _
        Operator:=xlAnd 'je lance un filtre qui sélectionne les cellules <> 12
    .Range("AP2", Dl).SpecialCells(xlCellTypeVisible).EntireRow.Delete 'je supprime toutes les lignes visibles
    .AutoFilterMode = False 'et j'enlève le filtre
End With
End Sub

[j0joo]

Merci pour les explications je vais potasser les fonctions.

En tout cas j'y vois plus clair.