Discussion :

[lemsv]

Bonjour à tous,

J'ai découvert récemment les tableaux dans Excel. Je trouve cet outil fort utile mais j'ai quelques soucis avec sa manipulation avec VBA.

J'ai donc un tableau dont j'aimerai renvoyer les valeurs d'une certaine ligne. J'y arrive sans soucis mais j'aimerai aussi renvoyer les valeurs des titres des colonnes et c'est là mon problème.
Même après recherche sur le net, je ne parviens pas à trouver la propriété qui me renverrait ces valeurs.

Merci d'avance

[casefayere]

Bonjour,

Je ne sais pas si c'est ce que tu cherches, mais voici une idée entre autres :

Cet exemple de code sert à retrouver les numéros de colonne (qui peuvent être déplacées pour X raisons) des titres

Attention, les variables "Public" sont déclarées en tête de module !

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Public CNom_Prenom as Integer, Couvrant_Droit as integer, CPosition as Integer
 Sub maj()
dim derlg as long, nbcol as long
With Sheets("Feuil1") 'à adapter
  derlg = .Range("b" & .Rows.Count).End(xlUp).Row
  nbcol = .Cells(1, .Columns.Count).End(xlToLeft).Column
  '**********************************************************
  CNom_Prenom = .Rows(1).Find("NOM PRENOM", .Cells(1, nbcol)).Column
  Couvrant_Droit = .Rows(1).Find("ouvrant_droit", .Cells(1, nbcol)).Column
  CPosition = .Rows(1).Find("POSITION", .Cells(1, nbcol)).Column
End With
 '.......
'....
End Sub

[Invité]

Salut,

Un exemple:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub Test()
    Const MA_FEUILLE = "Feuil1"
    Const MA_TABLE = "Tableau1"
    Static MonTableau As ListObject
    Static MaFeuille As Worksheet
    Dim i As Long
 
    Set MaFeuille = ThisWorkbook.Worksheets(MA_FEUILLE)
    Set MonTableau = MaFeuille.ListObjects(MA_TABLE)
 
    For i = 1 To MonTableau.ListColumns.Count
        MsgBox MonTableau.ListColumns(i).Name
        If i > 5 Then Exit For 'Au cas où il y ai trop de colonne dans le tableau
    Next
End Sub

EDIT:
ou plus simplement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Sub Test2()
    Dim i As Long
 
    With ThisWorkbook.Worksheets("Feuil1").ListObjects("Tableau1").ListColumns
        For i = 1 To .Count
            MsgBox .Item(i).Name
            If i > 5 Then Exit For 'Au cas où il y ai trop de colonne dans le tableau
        Next
    End With
 
End Sub

[lemsv]

Bonjour à vous,

Un grand merci pour vos réponses. J'ai appliqué la solution de Nouveau2 car plus simple à utiliser dans mon code.
Mon erreur venait du fait d'utiliser la méthode "range(MonTableau)" qui fonctionne pour certaines propriétés comme par exemple avec

Range(MonTableau).Columns.Count qui renvoie bien le nombre de colonnes.

Je vous souhaite une excellente journée

[Invité]

Il y a plus simple d'ailleurs.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Test3()
 
    Dim Index
 
    For Each Index In ThisWorkbook.Worksheets("Feuil1").ListObjects("Tableau1").HeaderRowRange.Value
        Debug.Print Index
    Next
 
End Sub

HeaderRowRange te fourni directement le nom des entêtes de chaque colonne dans un Tableau à 2 dimensions:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Sub Test4()
    Dim Tb(): Tb = ThisWorkbook.Worksheets("Feuil1").ListObjects("Tableau1").HeaderRowRange.Value
    MsgBox Tb(1, 3)
End Sub

Le 1er indice est celui de la ligne (toujours à 1 ici).

DataBodyRange est pour les données.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
Sub Test5()
 
    Dim Entete(), Data()
 
    With ThisWorkbook.Worksheets("Feuil1").ListObjects("Tableau1")
        Entete = .HeaderRowRange.Value
        Data = .DataBodyRange.Value
    End With
 
    MsgBox Entete(1, 3)
    MsgBox Data(1, 3)
 
End Sub

[lemsv]

Oui j'ai bien trouvé la propriété "HeaderRowRange"
Encore une fois, le problème venait de l'utilisation du "range" et non du ".ListObjects"

Vraiment un grand merci car j'étais bloqué dans mon projet

[Invité]

Ah Ok,

Et de rien.
A+