Discussion :

[stagière]

Bonjour,

Je dispose d'un dossier dans mes documents comportant de nombreux fichiers excel. Tous les fichiers que je souhaite importer commence par "49" (Si cela peut faciliter dans la sélection). Je souhaite importer ces fichier sous SAS en une seule macro si possible.

Merci de me venir en aide, je bloque la-dessus depuis une bonne partie de ma matinée.

[cmy_keyrus]

Bonjour,

Vous pouvez utiliser la fonction SAS "DOPEN".

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
data MATABLE;
  rc = filename("mydir","C:\Temp");
  did=dopen("mydir");
 
  if did > 0 then do;
 
    numobj = dnum(did);
    do i = 1 to numobj;
 
      name = dread(did,i);
      if substr(name,1,2) = '49' then output;
 
    end;
    rc = dclose(did);
 
  end;
run;

En sortie la table contient les noms de fichiers qui commencent par 49.
Il est possible de faire une étape "DATA _NULL_" et générer des macro variables.

Attention, avec ma condition si un fichier porte le numéro "490", il sera également admis dans la condition.

Si vos fichiers portent le nom "49_", il serait préférable de tester ces 3 caractères.

Cordialement

[tdiallo]

Bonjour,

Une suite au programme de cmy_keyrus pour que tu puisses importer tes fichiers excel.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
 
%macro bcl;
 
/* nbre de fichiers dans ta table matable */
proc sql;
		create table nb_fic as
		select distinct(name)
		from matable
	;
	select count(*) into : nb_fic
	from nb_fic
	;
quit;
 
%do i=1 %to &nb_fic;
	data _null_;
		position=&i;
		set nb_fic point=position;
		call symput("nom_fic", substr(name,1,index(name,".")-1)); /** récupérer le nom du fichier à importer **/
	stop;
	run;
 
proc import out=table_&i
	 datafile ="C:\Temp\&nom_fic..xlsx"
	 dbms=xlsx
     replace;
	 getnames=yes;
run;
 
%end;
%mend;
%bcl;