Discussion :

[GADENSEB]

Bonjour,

J'ai un bdd et je souhaiterais créer des listes déroulantes au "CLICK" dans la cellule avec les données d'une colonne

Exemple :
Je clique sur la cellule c3 et un liste déroulante s'affiche avec toutes les données de la colonne C

Il faut que les données soit classées par ordre alpha et sans doublons.

Qqn à une idée ?

Merci Seb

[sebing]

Bsr,

Afin de pouvoir d aider, aurais tu un exemple?
Quand tu cliques sur la cellule tu pourrais appeler un formulaire avec une liste chargée des valeurs de ta colonne.
Mais sur quelle cellule, a quoi va servir cette liste?
Cdlt
Seb

[casefayere]

Bonjour,

Comme je ne sais pas si ta liste déroulante est une ListBox ou une ListView ou encore une liste de validation, ci-dessous un exemple avec une ListBox et l'évènement "Worksheet_SelectionChange" car je ne connais pas d'évènement sur simple Click

[GADENSEB]

Le concept de casefayer est nikel
C'est une liste de validation que je cherche.


comme si on faisais sous excel Données / validation / liste .....

[casefayere]

C'est une liste de validation que je cherche.

Ok mais cette ListBox pourrait te servir de liste de validation, même si je ne vois pas encore le but de ta demande, il suffira de cliquer sur un nom de la Listbox pour déclencher une macro quelconque. Quant à sa place, on peut l'adapter sans problème.

Bonne soirée

[GADENSEB]

Je veux faire entièrement mon fichier excel en macro sans formules ou listes de validation .......

Je vous donne un exemple

Colonne A
Baba
Bibi
Bobo

Avec une liste de validation, dans une autre feuille par exemple :
Baba
Bibi
Bobo
..... On fait Données / validation sur cette liste et du coup dans la colonne A on a des listes de choix sur :
Baba
Bibi
Bobo

Du coup, si je veux je peux remplacer Baba par Bobo par le biais de la liste de choix.

--> je veux faire ça par macro en :
- Bouclant sur toutes les données de la colonne A (la liste s'auto remplie et actualise)
- Classer par ordre alphanumérique
- sans doublon
- le clique sur la cellule fait apparaitre la liste de choix

Dans un userform j'ai remplie une combobox par
remplir.me........... qui fait mes besoins


Est-ce que l'on peu aller dans le mm sens ?

Bonne soirée

Seb

[casefayere]

Re,

Comme je ne comprends toujours, on va essayer d'y aller par étape, ci-dessous, la 1ère étape

Un tableau (avec doublons éventuels) en Feuil1
En lançant la macro, tu retrouves en Feuil2, une liste de noms sans doublon et triée avec un nom défini "CHOIX"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub essai2()
Dim DerLg As Range, Tbl, TblTri
With Sheets("Feuil1")
  Set DerLg = .Cells(.Rows.Count, "A").End(xlUp)
  Tbl = .Range("A2", DerLg) 'C1 pour le titre
  .Range("A2", DerLg).Sort key1:=.Range("A2"), order1:=xlAscending, Header:=xlNo
  .Range("A2", DerLg).RemoveDuplicates Columns:=1, Header:=xlNo
  TblTri = .Range("A2", DerLg)
  With Sheets("Feuil2")
    Set DerLg = .Cells(.Rows.Count, "A").End(xlUp)
    .Range("A2", DerLg).ClearContents
    .Range("A2").Resize(UBound(TblTri) - 1) = TblTri
    .Range("A2").Resize(UBound(TblTri) - 1).Name = "CHOIX"
  End With
  .Range("A2").Resize(UBound(Tbl)) = Tbl
End With
End Sub

Ensuite, avec le résultat obtenu en Feuil2, que veux-tu faire ? (sachant qu'on pourra intégrer cette procédure dans un évènement de Feuil1)

[GADENSEB]

.... je suis pas le roi des explications..
Je Fais un fichier d'exemples
je cherche faire une macro comme la colonne C

test.xlsx

je veux valider les données sur la même colonne...

[casefayere]

Est-ce que ce fichier repris sur le tien correspond à la demande, fait avec l'évènement "Change" de la feuille, donc quand tu changes la valeur de la cellule

[GADENSEB]

Au poil !!!!

Encore deux questions :
1) Est-ce que l'on peut faire en sorte que les listes soit classées par ordre alpha ?
2) Comme je dois adapter ce code à une base de données de 50 colonnes je suppose que l'on choisi les colonnes impactées avec cette partie du code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
If Target.Column = 2 Then Col = "B": essai
If Target.Column = 2 Then Col = "C": essai
.......
If Target.Column = 2 Then Col = "M": essai
......
If Target.Column = 2 Then Col = "AZ": essai

Merci encore bonne soirée
Seb

[casefayere]

A force, j'ai fait une bétise, change ce code comme ça, pour le tri :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub essai()
Dim DerLg As Range, Tbl, TblTri, Schoix As String, x As Integer
With Sheets("Feuil1")
  Set DerLg = .Cells(.Rows.Count, Col).End(xlUp)
  Tbl = .Range(.Cells(3, Col), DerLg)
  Application.EnableEvents = False
  .Range(.Cells(3, Col), DerLg).Sort key1:=.Cells(3, Col), order1:=xlAscending, Header:=xlNo
  .Range(.Cells(3, Col), DerLg).RemoveDuplicates Columns:=1, Header:=xlNo
  Set DerLg = .Cells(.Rows.Count, Col).End(xlUp)
  TblTri = .Range(.Cells(3, Col), DerLg)
  .Cells(3, Col).Resize(UBound(Tbl)) = Tbl
    .Cells(3, Col).Resize(UBound(TblTri)).Name = "CHOIX" & Col
  Application.EnableEvents = True
  Schoix = TblTri(1, 1)
  For x = 2 To UBound(TblTri)
    Schoix = Schoix & "," & TblTri(x, 1)
  Next x
  With .Range("CHOIX" & Col).Validation
    .Delete
    .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
        xlBetween, Formula1:=Schoix
    .IgnoreBlank = True
    .InCellDropdown = True
    .InputTitle = ""
    .ErrorTitle = ""
    .InputMessage = ""
    .ErrorMessage = ""
    .ShowInput = False
    .ShowError = False
  End With
End With
End Sub

[GADENSEB]

.... mmm erreur de ma part ça classe pas ....


Par contre je n'ais pas compris par quel partie du code tu choisis les colonnes ou la macro s'applique ...

[casefayere]

La fatigue, mes excuses, les deux codes

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
Sub essai()
Dim DerLg As Range, Tbl, TblTri, Schoix As String, x As Integer
With Sheets("Feuil1")
  Set DerLg = .Cells(.Rows.Count, Col).End(xlUp)
  Tbl = .Range(.Cells(3, Col), DerLg)
  Application.EnableEvents = False
  .Range(.Cells(3, Col), DerLg).Sort key1:=.Cells(3, Col), order1:=xlAscending, Header:=xlNo
  .Range(.Cells(3, Col), DerLg).RemoveDuplicates Columns:=1, Header:=xlNo
  Set DerLg = .Cells(.Rows.Count, Col).End(xlUp)
  TblTri = .Range(.Cells(3, Col), DerLg)
  .Cells(3, Col).Resize(UBound(Tbl)) = Tbl
  Set DerLg = .Cells(.Rows.Count, Col).End(xlUp)
  .Cells(3, Col).Resize(UBound(Tbl)).Name = "CHOIX" & Col
  Application.EnableEvents = True
  Schoix = ""
  Schoix = TblTri(1, 1)
  For x = 2 To UBound(TblTri)
    Schoix = Schoix & "," & TblTri(x, 1)
  Next x
  With .Range("CHOIX" & Col).Validation
    .Delete
    .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
        xlBetween, Formula1:=Schoix
    .IgnoreBlank = True
    .InCellDropdown = True
    .InputTitle = ""
    .ErrorTitle = ""
    .InputMessage = ""
    .ErrorMessage = ""
    .ShowInput = False
    .ShowError = False
  End With
End With
End Sub
 
Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Column = 2 Then Col = "B": essai
If Target.Column = 3 Then Col = "C": essai
 
End Sub

[mercatog]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
Option Explicit
 
Sub Test()
 
Validation 2
Validation 3
End Sub
 
Sub Validation(ByVal Col As Integer)
Dim LastLig As Long, i As Long, j As Long
Dim Tmp As String
Dim Tb() As String
 
With Worksheets("Feuil1")
    LastLig = .Cells(.Rows.Count, Col).End(xlUp).Row
    For i = 2 To LastLig
        If InStr(Tmp, .Cells(i, Col)) = 0 Then
            Tmp = Tmp & .Cells(i, Col) & "|"
            j = j + 1
            ReDim Preserve Tb(1 To j)
            Tb(j) = .Cells(i, Col)
        End If
    Next i
    TriRapide Tb, 1, j
    With .Cells(2, Col).Resize(LastLig).Validation
        .Delete
        .Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:=xlBetween, Formula1:=Join(Tb, ",")
    End With
End With
End Sub
 
 
Private Sub TriRapide(Tbl, ByVal Lo As Long, ByVal Hi As Long)
Dim Piv As String, Temp As Variant
Dim D As Long
Dim F As Long
 
D = Lo
F = Hi
Piv = UCase(Tbl((Lo + Hi) \ 2))
Do While D <= F
    Do While UCase(Tbl(D)) < Piv And D < Hi
        D = D + 1
    Loop
    Do While Piv < UCase(Tbl(F)) And F > Lo
        F = F - 1
    Loop
    If D <= F Then
        Temp = Tbl(D)
        Tbl(D) = Tbl(F)
        Tbl(F) = Temp
        D = D + 1
        F = F - 1
    End If
Loop
If Lo < F Then TriRapide Tbl, Lo, F
If D < Hi Then TriRapide Tbl, D, Hi
End Sub

[casefayere]

Bonsoir mercatog,

Heureusement que tu passes par là, perso je suis crevé et commence à faire des bétises, je n'ai même plus le courage d'analyser ton code (je le ferai demain), je ne suis plus dispo dans la tête

Bonne nuit

[GADENSEB]

Merci les gars !

@mercatog

tu ne renseignes pas les colonnes concernées ?
du coup cela s'applique à quelles colonnes §?

[mercatog]

La sub Validation prend comme argument le n° de colonne (j'aurai à la nommer autrement par Exemple MaValidation -1 pour moi)

Quand tu mets

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Call MaValidation(2)

Tu travailles avec la colonne 2

[GADENSEB]

je crois avoir compris
tu places ton code dans la feuille concernée ? ou dans un module ?

[mercatog]

n'importe

Mais tu peux l'appeler à partir de l'évènement SelectionChange de la feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Private Sub Worksheet_SelectionChange(ByVal Target As Range)
 
If Target.Row > 1 Then MaValidation Target.Column
End Sub

[GADENSEB]

Tout simplement génial !!

Thanks