Discussion :

[delph_le]

Bonjour,

Je souhaite appliquer un format à une variable numérique (je ne souhaite pas utiliser de PROC SQL car mes tables sont très lourdes, et les formats sont plus performants dans mon cas de figure)
Mais pour certaines modalités, je n'ai pas de format. Je souhaiterais donc que la variable (variable FAMILLE dans mon exemple) soit vide.
Comment est-ce possible de faire ça ?

Voici mon code exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
DATA HISTO;
	INPUT ID_CLIENT ID_ART VOL;
	CARDS;
1 1 10
1 2 15
1 3 12
1 4 20
2 1 2
2 2 6
2 3 10
2 5 25
;
RUN;
 
DATA ARTICLES;
	INPUT PRODUIT FAMILLE $;
	CARDS;
1 EAU
2 BIERE
3 SOFT
5 JUS
;
RUN;
 
DATA FMT;
	RETAIN FMTNAME 'FMT_FAMILLE' TYPE 'N';
	SET ARTICLES (RENAME = (PRODUIT = START FAMILLE = LABEL));
RUN;
 
PROC FORMAT CNTLIN = FMT;
RUN;
 
DATA HISTO2;
	SET HISTO;
	FAMILLE = STRIP(PUTN(ID_ART,'FMT_FAMILLE.'));
RUN;

Merci de votre aide,

delph_le

[lelensois16]

Bjr,

Il faut utiliser la modalité OTHER du proc format.
Mais dans ton exemple, tu utilises une table pour créer ton format. donc il faut créer une variable HLO qui permet de "signaler" la modalité " " (vide) pour les autres formats.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
DATA FMT;
	RETAIN FMTNAME 'FMT_FAMILLE' TYPE 'N';
	SET ARTICLES (RENAME = (PRODUIT = START FAMILLE = LABEL)) end = fin ;
output;
if fin then do;
hlo = "O"; label = " ";
output;
end;
RUN;

Cordialement,

Rom

[delph_le]

Merci beaucoup, ça fonctionne très bien, c'est exactement ce que je voulais faire.

delph_le