Discussion :

[eviuss]

Bonjour,

Je desire inserer les valeurs d'une ligne (ex: B1:C1: D1...etc) dans ma comboBox
j'ai fouiner partout et essayer pas mal de choses mais sans succès
Fichier Test : TestDC.zip

je suis novice en VBA Word et très nul en VBA Excel...
j'ai suivi pas mal de petit Tuto, mais...je comprend pas
j'ai laisser une partie des commandes que j'ai essayé mais bon....

Vous pouvez m'aider Svp
Merci d'avance

[Kimy_Ire]

Bonjour eviuss,

Alors, voici ce que tu dois mettre dans ton UserForm_Initialize (et non pas UserForm1_Initialize puisque chaque UserForm possède sa propre méthode).

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub UserForm_Initialize()
Dim i As Integer
 
With Worksheets("Entree")
    Me.ComboBox1.Clear
 
    For i = 1 To .Rows(1).Find("*", , , , , xlPrevious).Column
        Me.ComboBox1.AddItem .Cells(1, i)
    Next i
End With
 
End Sub

Ca t'insère toutes les cellules de ta ligne 1 non vide.

Cela te convient-il ?

CONSEIL : ne met JAMAIS d'espace avant ou après le nom de tes onglets... J'ai mis 10 minutes à trouver l'erreur.

Cordialement,
Kimy

Aux plus experts : N'y a t-il pas un moyen d'insérer les items grâce à une range ? Il me semblait que c'était possible mais je n'ai ni trouvé ni réussi à les insérer du type ComboBox1.AddItem .Range("B1:M1") ?
RowSource ?
Autre ?

[rvtoulon]

Effectivement sans boucle avec la propriété list():

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Private Sub UserForm_Initialize()
With Sheets("Entree")
 
     'met dans une variable le numéro de la dernière colonne utilisée de la ligne1
     dercol = .Rows(1).Find("*", , , , , xlPrevious).Column
 
     'transpose la ligne B1:?1 en colonne dans ma liste
     maliste = WorksheetFunction.Transpose(.Range(.Cells(1, 2), .Cells(1, dercol)))
End With
 
 
'insère ma liste dans la combo 
Me.ComboBox1.List() = maliste
 
 
End Sub

[eviuss]

Genial !!!

Merci infiniment, ca marche très bien
merci du conseil concernant l'espace, je n'ai pas fais attention lorsque j'ai renommé l'onglet....
je pense que tout mes essais ne marcher pas a cause de ça....
j'ai perdu pas mal de cheveux :p

Merci encore