Discussion :

[Paulart]

Bonjour,

J'utilisais la formule ci-dessous mais depuis que j'ai changé des choses dans mon classeur elle ne fonctionne plus. Je l'utilisais pour changer la couleur de mon graphique en fontion des résultats. Qu'en pensez vous ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
 Sub FormatConditionnelGraphique()
 'Compte le nombre de séries
 For c = 1 To ActiveChart.SeriesCollection.Count
 'compte le nombre de points
 For d = 1 To ActiveChart.SeriesCollection(c).Points.Count
 'teste la présente des étiquettes sur le graphs
 If ActiveChart.SeriesCollection(c).Points(d).HasDataLabel = False Then Test = 1
 'affiche les étiquettes
 ActiveChart.SeriesCollection(c).Points(d).HasDataLabel = True
 'récupère les informations des étiquettes
 rep = ActiveChart.SeriesCollection(c).Points(d).DataLabel.Text
 'convertit l'étiquette en nombre et fais le test
 If CDbl(rep) > 7 Then
 'suivant le résultat, change la couleur
 ActiveChart.SeriesCollection(c).Points(d).Interior.ColorIndex = 43
 Else
 ActiveChart.SeriesCollection(c).Points(d).Interior.ColorIndex = 3
 End If
 'remets dans l'état initial le graphique
 If Test = 1 Then ActiveChart.SeriesCollection(c).Points(d).HasDataLabel = False
 Next d
 Next c
 End Sub

Merci à tous

[mercatog]

J'ai un peu modifié ton code et l'a rendu paramétré

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Private Sub FormatConditionnelGraphique(ByVal Ch As Chart)
Dim Ns As Integer, i As Integer
Dim Test As Boolean
Dim Pt As Point
 
With Ch
    'nombre de séries
    Ns = .SeriesCollection.Count
    For i = 1 To Ns
        'parcourts tous les points
        For Each Pt In .SeriesCollection(i).Points
            'teste la présente des étiquettes sur le graphs
            Test = Pt.HasDataLabel
            'affiche les étiquettes
            Pt.HasDataLabel = True
            'récupère les informations des étiquettes
            'convertit l'étiquette en nombre et fais le test
            'suivant le résultat, change la couleur
            Pt.Interior.ColorIndex = IIf(CDbl(Pt.DataLabel.Text) > 7, 43, 3)
            'remets dans l'état initial le graphique
            Pt.HasDataLabel = Test
        Next Pt
    Next i
End With
End Sub

On l'applique à l'objet graphique inséré dans la feuille Feuil1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Sub Test1()
 
FormatConditionnelGraphique Worksheets("Feuil1").ChartObjects(1).Chart
End Sub

Ou à la feuille graphique nommée Graph1

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Sub Test2()
 
FormatConditionnelGraphique Sheets("Graph1")
End Sub