Discussion :

[bbcancer]

Bonjour le Forum

J'ai une formule qui me calcule les dimanches travaillés qui marchent très bien. A cette formule, je souhaiterai ajouter les jours fériés. Mais cette formule ne fonctionne que pour un type de donnée.
Je vous mets un fichier en exemple.

J'ai travail sur le mois de mai
En X3, il y a la formule du dimanche qui marche.
En X4, j’ai essayé de travaillé la formule avec les jours fériés mais seulement un critère marche. Y a-t-il moyen de faire une formule dans le même style que le dimanche?

Si quelqu'un peut m'aider.

Merci

[papouclo]

Bonjour,
Dans le classeur joint, la feuille d'origine Primes sans aucune transformation a été renommée Ex Primes.
Dans la feuille Primes (2), une formule possible pour décompter les dimanches et jours fériés travaillés pendant le mois de mai par le premir agent, donc à écrire en X3, peut être :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD(((JOURSEM(Matin!$DU$3:$EY$3)=1)+(JOURSEM(Matin!$DU$3:$EY$3)<>1)*ESTNUM(EQUIV(Matin!$DU$3:$EY$3;Fériés;0)))*(Matin!$DU4:$EY4={0,5;"CHA";"ENS";"ROV";"VIC";"SAU";"DIV";"HC9";"HEN";"HRV";"HVI";"HSA"}))

L'utilisation des références semi absolues $DU4:$EY4 au lieu des références absolues comme dans les recherches permet au moins de recopier cette formule vers le bas sansavoir à les réécrire à chaque ligne.
Mais il faut modifier cette formule lorsque l'on passe d'un mois à l'autre.
Ce travail imposé et aussi le fait de modifier manuellement un certain nombre de contenus si l'on veut utiliser le fichier une autre année m'a fait modifier la feuille pour obtenir
la feuille Primes.
Les principales modifications de la feuille sont :
- le remplacement à la ligne 1 des textes des cellules E1(Janvier 2014), I1, M1... par des dates : 01/01/2014 entrée manuellement en E1, 01/02/2014 calculée par formule en I1,...
(la présentation de la feuille ne s'en ressentant pas avec le format personnalisé mmmm aaaa ). La cellule I1 contient la formule :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= MOIS.DECALER(E1;1)

copiée et collée dans les cellules M1 , Q1 , U1 , Y1 ...
- la définition de trois noms pour la feuille : moistraité , joursMois , PrésencesAgent
moistraité défini par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= INDIRECT(ADRESSE(1;4*QUOTIENT(COLONNE()-1;4)+1))

joursMois défini par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= DECALER(Matin!$D$3;0;EQUIV(moistraité;Matin!$E$3:$NE$3;0);1;JOUR(FIN.MOIS(moistraité;0)))

PrésencesAgent défini par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER(Matin!$D$3;EQUIV(Primes!$C1;Matin!$D$4:$D$6;0);EQUIV(moistraité;Matin!$E$3:$GC$3;0);1;JOUR(FIN.MOIS(moistraité;0)))

- Avec ceci il suffit de définir pour le mois de janvier deux formules en plus des deux formules simples des colonnes Prime et Prime dimanche
En J3, la formule est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= SOMMEPROD(ESTNUM(EQUIV(PrésencesAgent;{0,5;"CHA";"ENS";"ROV";"VIC";"SAU";"DIV";"HC9";"HEN";"HRV";"HVI";"HSA"};0))*1)

En L3, la formule est :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

= SOMMEPROD(((JOURSEM(joursMois)=1)+(JOURSEM(joursMois)<>1)*ESTNUM(EQUIV(joursMois;Fériés;0)))*ESTNUM(EQUIV(PrésencesAgent;{0,5;"CHA";"ENS";"ROV";"VIC";"SAU";"DIV";"HC9";"HEN";"HRV";"HVI";"HSA"};0)))

Sélectionner la plage E3 : H3 et tirer vers le bas pour recopier les formules dans toute la plage E3 : H5.
Sélectionner cette plage ; copier puis coller pour les plages des autres mois.
Cordialement
Claude