Code pour copier coller même feuille cible de chaque classeur

**aya_a89** · 26/06/2014, 10h15

Bonjour,
Je m'initie en VBA et je rencontre un problème, je n'arrive plus a avancer.
Ce que je veux c'est une macro qui récupère la même feuille sur plusieurs classeurs de ma liste et colle dans une même feuille. J'ai trouvé un code que j'ai changer donc ce code ouvre chaque classeurs mais ne me copie rien. Si quelqu'un peut m'éclairer ce sera super.
Je vous remercie d'avance

Voici le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
Sub Lili()
Dim ListP As Variant
Dim CL1 As Workbook, i As Byte
Dim FL1 As Worksheet
    Set CL1 = ThisWorkbook
 
    CL1.Sheets.Add
    CL1.ActiveSheet.Name = "Feuilyoyo"
    Set FL1 = CL1.ActiveSheet
 
 
    ListP = Array("S:\COMPTABILITE\moi\Yep\Ht2\Rt.xlsx")
 
    For i = 0 To UBound(ListP)
        Copie FL1, ListP(i)
    Next
End Sub
Sub Copie(FL1 As Worksheet, Fichier)
Dim CL2 As Workbook
Dim FL2 As Worksheet
Dim i As Byte, Rep$, NoLigne As Long
 
     Set CL2 = Workbooks.Open(Fichier)
 
 
        For Each FL2 In CL2.Worksheets
        If FL2.Name = PAD Then
        If IsEmpty("FL2") = False Then
 
            NoLigne = FL1.Range("A1").SpecialCells(xlCellTypeLastCell).Row + 1
 
           FL2.Cells.Copy = FL1.Range("A" & NoLigne)
 
            DoEvents
            Set FL2 = Nothing
        End If
        End If
        Next
 
 
        CL2.Close False
        DoEvents
        Set CL2 = Nothing
End Sub

**Theze** · 26/06/2014, 22h25

Bonsoir,

J'ai modifié ton code car dans l'état c'était impossible de le faire fonctionner !
Teste en lançant la proc "lili" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
 
Sub Lili()
 
    Dim Tbl() As String
    Dim I As Integer
    Dim FL1 As Worksheet
 
    'ajoute une feuille au classeur et la renomme
    Set FL1 = ThisWorkbook.Worksheets.Add
    FL1.Name = "Feuilyoyo"
 
    'récupère les fichiers contenus dans le dossier et stocke les chemins dans un tableau
    Tbl = EnumFichiers("S:\COMPTABILITE\moi\Yep\Ht2\")
 
    'lance la copie
    For I = 1 To UBound(Tbl)
 
       Copie FL1, Tbl(I)
 
    Next I
 
End Sub
 
Sub Copie(FL1 As Worksheet, Fichier)
 
    Dim CL2 As Workbook
    Dim FL2 As Worksheet
    Dim NoLigne As Long
 
    'ouvre le classeur en cours
    Set CL2 = Workbooks.Open(Fichier)
 
    'cherche la feuille "PAD"
    For Each FL2 In CL2.Worksheets
 
        If FL2.Name = "PAD" Then
 
            'défini la première ligne vide en colonne A
            NoLigne = FL1.Range("A1").SpecialCells(xlCellTypeLastCell).Row + 1
 
            'colle la partie utilisée de la feuille "PAD"
            FL2.UsedRange.Copy FL1.Range("A" & NoLigne)
 
        End If
 
    Next FL2
 
    'ferme le calsseur avant ouverture du suivant si il y a
    CL2.Close False
 
End Sub
 
Function EnumFichiers(Chemin As String) As String()
 
    Dim TableauFichiers() As String
    Dim Fichier As String
    Dim I As Integer
 
    'récupère les fichiers
    Fichier = Dir(Chemin)
 
    'boucle sur les fichiers du dossier
    Do While (Len(Fichier) > 0)
 
        I = I + 1
 
        ReDim Preserve TableauFichiers(1 To I)
 
        TableauFichiers(I) = Chemin & Fichier
 
        Fichier = Dir()
 
    Loop
 
    'retourne le tableau des noms de fichiers
    EnumFichiers = TableauFichiers()
 
End Function

Hervé.

**aya_a89** · 27/06/2014, 22h01

Merci beaucoup Hervé, mais au fait j'ai réussi à faire fonctionner le mien. Ceci fit, je vais tester le tien et je te donnerai des nouvelles.

( Btwn elle sert a quoi la dernière fonction que t'as ajouter dans ton code)
Aussi, j'aimerai bien que mon code ne me copie plus les3 premières lignes a partir du deuxième classeur, si quelqu'un a une idée, je suis preneuse!

Merci d'avance!

Ah ok pour la fonction, j'ai compris! J'ai pas fait attention en lisant !

Autre problématique qui s'est posé à moi, je voudrais extraire les données d'un tableau et les restituer dans un autre qui n'est pas de même format(ce derniers à deux fois plus de colonnes). Du coup, je veux une macro qui me retranscrit les données du premier classeurs dans les cases correspondantes du classeurs qui va les recevoir. Je pensais à une condition sur les noms des cellules mais je ne vois pas comment faire.

Any help please?