Discussion :

[lomig29]

Bonjour à tous,
Je suis en cour de création d'un outils qui me permet de remplir de façon automatique un certain nombre de document sur la base d'une feuille exel de renseignements.
Grâce à cette feuille les autres feuilles du classeurs se pré-remplissent automatiquement, jusque la tout va bien.
La ou ça ce complique, c'est que j'ai fait une macro pour ouvrir un fichier word, et via un publipostage il se pré-remplie automatiquement et s'imprime, cela marche très bien également.

Mon problème est que ma macro intègre des liens fixes pour aller chercher ces fichiers et que le but du fichier exel et de ses fichiers word liés est qu'il soit copier et coller pour étre dupliqué.

Y-a-il une solution dans l’écriture du code ou autre pour permet une mise à jour automatique des lien du code?

Ci dessous le code utilisé:

Sub ARCAFFAIRE_Bouton1_Cliquer()
'Nécessite d'activer la référence "Microsoft Word xx.x Object Library"
Dim docWord As Word.Document
Dim appWord As Word.Application
Dim NomBase As String

NomBase = "C:\Users\XXX\Desktop\affaire\Gestion de chantier V2.xlsm"

Application.ScreenUpdating = False
Set appWord = New Word.Application
appWord.Visible = True
'Ouverture du document principal Word
Set docWord = appWord.Documents.Open("C:\Users\XXX\Desktop\affaire\documents associé\Modèle lettre AR commande client XXX v2.doc")

'fonctionnalité de publipostage pour le document spécifié
With docWord.MailMerge
'Ouvre la base de données
.OpenDataSource Name:=NomBase, _
Connection:="Driver={Microsoft Excel Driver (*.xls)};" & _
"DBQ=" & NomBase & "; ReadOnly=True;", _
SQLStatement:="SELECT * FROM [Feuil1$]"
'Spécifie la fusion vers l'imprimante
.Destination = wdSendToPrinter
.SuppressBlankLines = True
'Prend en compte l'ensemble des enregistrements
With .DataSource
.FirstRecord = wdDefaultFirstRecord
.LastRecord = wdDefaultLastRecord
End With
'Exécute l'opération de publipostage
.Execute Pause:=False
End With

Application.ScreenUpdating = True

'Fermeture du document Word
docWord.Close False
appWord.Quit
End Sub


Je vous remercie par avance.

[Daniel.C]

Bonjour,

Mon problème est que ma macro intègre des liens fixes pour aller chercher ces fichiers et que le but du fichier exel et de ses fichiers word liés est qu'il soit copier et coller pour étre dupliqué.

Y-a-il une solution dans l’écriture du code ou autre pour permet une mise à jour automatique des lien du code?

J'ai du mal à comprendre... Est-ce tu peux expliquer davantage, avec un exemple si possible ? J'aime bien les exemples...

[lomig29]

Désolé si je me suis mal expliqué.

pour faire simple, j'ai créé ma feuille exel et ses fichiers annexes dans un dossier sur mon bureau et quand je coupe ce dossier pour le déplacer à un autre endroit, ma macro ne fonctionnement plus. L'erreur est fichier introuvable, car le lien vers le fichier annexe (Word pour le publipostage) est resté celui de l'ancien emplacement.

Et malheureusement le but de ce petit outil est d’être dupliqué (de façon manuel)

Pour exemple:

L’outil avec ses fichiers sources (word) seront stocker mes documents.

A chaque nouveau projet (car l'outil permet la gestion de projet), je copie les fichiers depuis mes documents et le colle dans un dossier portant le nom du nouveau projet sur un serveur, et j'aimerai préservé la fonctionnalité de la macro après déplacement.

[Daniel.C]

Si tous les fichiers sont dans le même dossier que le classeur Excel, tu peux adresser le dossier avec la méthode "ThisWorkbook.Path".

[lomig29]

Merci par contre je suis débutant dans le vba, pouvez-vous me dire ou l'intégré dans le code.

Je vous remercie d'avance

[Daniel.C]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Sub ARCAFFAIRE_Bouton1_Cliquer()
'Nécessite d'activer la référence "Microsoft Word xx.x Object Library"
Dim docWord As Word.Document
Dim appWord As Word.Application
Dim NomBase As String
 
NomBase = ThisWorkbook.Path & "\Gestion de chantier V2.xlsm"
 
Application.ScreenUpdating = False
Set appWord = New Word.Application
appWord.Visible = True
'Ouverture du document principal Word
Set docWord = appWord.Documents.Open(ThisWorkbook.Path & "\documents associé\Modèle lettre AR commande client XXX v2.doc")
 
'fonctionnalité de publipostage pour le document spécifié
With docWord.MailMerge
'Ouvre la base de données
.OpenDataSource Name:=NomBase, _
Connection:="Driver={Microsoft Excel Driver (*.xls)};" & _
"DBQ=" & NomBase & "; ReadOnly=True;", _
SQLStatement:="SELECT * FROM [Feuil1$]"
'Spécifie la fusion vers l'imprimante
.Destination = wdSendToPrinter
.SuppressBlankLines = True
'Prend en compte l'ensemble des enregistrements
With .DataSource
.FirstRecord = wdDefaultFirstRecord
.LastRecord = wdDefaultLastRecord
End With
'Exécute l'opération de publipostage
.Execute Pause:=False
End With
 
Application.ScreenUpdating = True
 
'Fermeture du document Word
docWord.Close False
appWord.Quit
End Sub

[lomig29]

Merci beaucoup mon problème est résolue