Discussion :

[redojackson]

Bonjour

J'ai créé 2 tables :
Une table "T_Prestations" préremplie et dont les champs sont les suivants:
1-CodePrestation
2-PrixUnitaire (€)
3-Min_a_payer
4-Max_a_payer

Une table "T_Calcul" dont les champs sont les suivants:
1-Id_Number
2-NomClient
3-CodePrestation
4-Quantité (Tonne)
5-Montant (€)

Les 4 premiers champs sont introduits par l'utilisateur

J'aimerai bien à ce que le champ "Montant" de la table "T_Calcul" soit calculé automatiquement selon le "CodePrestation" en multipliant la valeur du champ "Quantité" de la table "T_Calcul" avec celle du champ "PrixUnitaire" de la table "T_Prestations" en tenant en compte des champ "Min_a_payer" et "Max_a_payer"

Exemple: Si
"PrixUnitaire" = 50
"Min_a_payer" = 300
"Max_a_payer" = 2000
Si "Quantité" multiplié par "PrixUnitaire" < "Min_a_payer" : Le "Montant" = 300
Si "Quantité" multiplié par "PrixUnitaire" > "Max_a_payer" : Le "Montant" = 2000

Merci pour votre aide

[jimbolion]

redojackson bonjour,

je pense que ce code inséré dans une procédure vba (evenement sur clic d'un bouton par exemple) devrait répondre à tes attentes :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
If Nz(Me.CodePrestation, "") = "" Then
    MsgBox "le code prestation n'a pas été renseigné"
    Exit Sub
End If
'
If Nz(Me.Quantite, 0) = 0 Then
    MsgBox "la quantité n'a pas été renseignée"
    Exit Sub
End If
'
Dim dblPrix As Single
Dim rst As DAO.Recordset
'
' Requêtepermettant d'extraire les champs servant aux calculs avec condition sur codeprestation
'
Set rst = CurrentDb.OpenRecordset( _
  "SELECT [PrixUnitaire],[Min_a_payer],[Max_a_payer] FROM [T_Prestations] WHERE [CodePrestation] = '" & Me.CodePrestation & "'", _
  dbOpenSnapshot)
dblPrix = rst("PrixUnitaire")
'
' application des règles de calcul
'
If dblPrix * Me.Quantite <= Val(rst("Min_a_payer")) Then
    Me.Montant = Val(rst("Min_a_payer"))
Else
    If dblPrix * Me.Quantite >= Val(rst("Max_a_payer")) Then
        Me.Montant = Val(rst("Max_a_payer"))
    Else
        Me.Montant = dblPrix * Me.Quantite        ' compris entre min et max on applique la formule de calcul
    End If
End If
'
rst.Close
 
Set rst = Nothing

Pour récupérer un seul champ, le code du Recordset est un peu long. Mais s’il faut lire plusieurs valeurs, les performances seront meilleures qu’avec une suite de DLookup. Dans notre cas trois valeurs sont à récupérer (prixunitaire, prixmin et prixmax).

La base exemple ici (le formulaire F_calculs permet de réaliser tes simulations) : prestations.zip

bonne continuation

jimbolion

[redojackson]

Merci infiniment jimbolion

Vous m'avez facilité la vie