Discussion :

[imadeus]

Voilà, je suis débutant et après avoir cherché sur internet, je n'arrive pas à résoudre mon problème.

Le voici : je tente de récupérer la valeur des lignes "C" "E" et "W" de ma feuille donnée en fonction de la valeur d'une combobox (ici la variable : Valeur_société). La combobox récupère le nom d'une société qui se trouve en colonne "F" de la feuille "données". Si le nom de la société est trouvé, alors on reprend les infos de la cellule "C" "E" et "W" et on les copie dans une autre feuille.

Voici le code actuel

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Private Sub CommandButton1_Click()
Dim plage As Range, cel As Range
Dim Num_Ligne As Integer
 
Application.ScreenUpdating = False
 
'on se positionne sur la colonne ou se trouve la valeur de la société et on définit la plage à analyser pour comparer la valeur de la combobox
With Worksheets("Données")
        derlig = .Range("F" & Rows.Count).End(xlUp).Row
        Set plage = .Range("F4:F" & derlig)
 End With
 
 
 
'on parcours la plage définie plus haut
For Each cel In plage
        'si la valeur de la cellule correspond à la valeur de la combobox (ici Valeur_societe) alors on récupère la donnée de la cellule C-E-W de la ligne sur laquelle on se trouve (feuille données)
        If cel = Valeur_societe Then
            Sheets("Données").Select
            Range("C" & ActiveCell.Row & ",E" & ActiveCell.Row & ",W" & ActiveCell.Row).Select
            Range("C" & ActiveCell.Row & ",E" & ActiveCell.Row & ",W" & ActiveCell.Row).Copy
            'on se place sur la feuille Inasti et on colle la valeur 
            Sheets("Inasti").Select
            Worksheets("Inasti").Range("A4").Select
            ActiveSheet.Paste
            Selection.Insert Shift:=xlDown
        End If
    Next cel
 
    Application.ScreenUpdating = True
End Sub

Le problème est que la macro renvoie bien le nombre de ligne correspondant (ex société 1 :19 lignes, société 2 : 17 lignes) mais ne renvoie pas la bonne valeur. J'ai toujours le même nom qui s'affiche
comme si Range("C" & ActiveCell.Row) était toujours identique.

Merci d'avance pour votre aide .

Nb : il me reste une option c'est d'aller voir si je peux faire un copier d'une cellule genre cel.Copy avec offset dedans...

[Igloobel]

Salut

d'abord petite remarque quand on met au point du code il est bon d'avoir les message qui s'affiche.
Met en commentaire tes lignes sur : Application.ScreenUpdating de façon à avoir les messages d'erreur si il y a.
Deuxièmement

tu dis

Voilà, je suis débutant ...

Et j'aurais pas utiliser si vite un for each qui est quand plus difficile à appéhender que le reste.
J'aurais à ta place utiliser la boucle : DO ... LOOP WHILE(Condition)

Du coup :
-recupérer la valeur de ta combobox
-boucler sur les lignes en compararant les noms de société jusqu'a trouver le bon
-on s'arrête sur la bonne ligne (dès que c'est = )
-on récupère les valeurs qui vont bien et on les copie où c'est nécessaire

cela me parrait plus simple à faire (en tout cas surtout quand on débute)

Je parle en connaissance de cause puisque j'ai été débutant moi aussi

dis si tu as besoin d'aide

à bienôt

[imadeus]

Merci Igloobel pour tes remarques.

Ce qu'il se passe, c'est que la fonction marche très bien.

Si je fais "cel.EntireRow.Copy" ca fonctionne parfaitement, ca me copie toutes les lignes relatives à la société voulue dans la combobox.
Mais je ne désire pas copier toute la ligne, je désire juste copier certaine colonne.
Je sais faire par exemple : cel(0, 0).Copy mais je ne sais pas comment en copier plusieurs d'un coup.

Je persévère et je testerai ta méthode si je n'y arrive pas (même si je pense être bloqué au même endroit c'est-à-dire :
on récupère les valeurs qui vont bien)

[mercatog]

il est temps de regarder du coté de la méthode Range.Find (cf aide vba). pas la peine de faire des boucles quand ce n'est pas nécessaire, Elle ne font que consommer du temps précieux.

Exemple pour ton cas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub CommandButton1_Click()
Dim Societe As String
Dim c As Range
 
Application.ScreenUpdating = False
If Valeur_societe.ListIndex > -1 Then
    Societe = Valeur_societe.Value
    With Worksheets("Données")
        Set c = .Range("F:F").Find(Societe, LookIn:=xlValues, lookat:=xlWhole)
        If Not c Is Nothing Then
            Worksheets("Inasti").Range("A4").Resize(, 3) = Array(.Range("C" & c.Row), .Range("E" & c.Row), .Range("W" & c.Row))
            Set c = Nothing
            Worksheets("Inasti").Rows(4).Insert Shift:=xlDown
        End If
    End With
End If
End Sub

Code identique au précédent pour un débutant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Private Sub CommandButton1_Click()
Dim Societe As String
Dim c As Range
 
Application.ScreenUpdating = False
If Valeur_societe.ListIndex > -1 Then
    Societe = Valeur_societe.Value
    With Worksheets("Données")
        Set c = .Range("F:F").Find(Societe, LookIn:=xlValues, lookat:=xlWhole)
        If Not c Is Nothing Then
            Worksheets("Inasti").Range("A4") = .Range("C" & c.Row)
            Worksheets("Inasti").Range("B4") = .Range("E" & c.Row)
            Worksheets("Inasti").Range("C4") = .Range("W" & c.Row)
            Set c = Nothing
            Worksheets("Inasti").Rows(4).Insert Shift:=xlDown
        End If
    End With
End If
End Sub

[imadeus]

Merci Mercatog,
Ta solution marche à merveille et (mais) renvoie une seule valeur.
Je dois utiliser un tableau car le nom de la société est présent plusieurs fois.

Ceci dit, je pense que j'ai les éléments à présent pour avancer .
Je laisse ouvert le post au cas ou.

[mercatog]

As tu regardé l'aide vba de Find

Tu as là un exemple concret d'utilisation de la méthode pour récupérer plusieurs valeurs

Si tu n'arrives pas à l'adapter, fais nous signe

[imadeus]

Non je n'ai pas encore eu le temps mais je vais m'y pencher. Au pire demain !
Je vous tiens au courant.

Et bien sur merci pour votre aide

[mercatog]

En attendant, voilà le code si tu me promet que tu vas adapter l'aide de vba sur Range.Find à ton cas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Private Sub CommandButton1_Click()
Dim Societe As String, Prm As String
Dim c As Range
 
Application.ScreenUpdating = False
If Valeur_societe.ListIndex > -1 Then
    Societe = Valeur_societe.Value
    With Worksheets("Données")
        Set c = .Range("F:F").Find(Societe, LookIn:=xlValues, lookat:=xlWhole)
        If Not c Is Nothing Then
            Prm = c.Address
            Do
                Worksheets("Inasti").Range("A4").Resize(, 3) = Array(.Range("C" & c.Row), .Range("E" & c.Row), .Range("W" & c.Row))
                Worksheets("Inasti").Rows(4).Insert Shift:=xlDown
                Set c = .Range("F:F").FindNext(c)
            Loop While Not c Is Nothing And c.Address <> Prm
        End If
    End With
End If
End Sub

[imadeus]

Merci, ça fonctionne parfaitement.

J'étais effectivement parti sur un do... while avec la fonction FindNext

Un grand merci à toi :-). Ca va me servir énormément pour les fichiers que je dois préparer.