Discussion :

[badege3378]

Bonjour,
Je cherche désespérément à inscrire une variable dans la zone de critère d'un filtre Criteria1:=Array(MaVariable) mais cela ne fonctionne pas.
En fait, j'ai des codes dans une colonne (un code par ligne). Je regroupe ces codes pour obtenir ma variable dans le même format que l'écriture du critère sans variable.
Mon filtre fonctionne parfaitement avec les codes inscrit directement mais ne fonctionne pas avec ma variable.
Voici l'extrait de mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
For Each cel In Range("BA2:BA" & Range("BA65536").End(xlUp).Row)
If MaPlage = "" Then
MaPlage = """" & cel.Value & """, "
Else
MaPlage = MaPlage & """" & cel.Value & """, "
End If
Next cel
MaPlage = Left(MaPlage, Len(MaPlage) - 3)
MaPlage = Right(MaPlage, Len(MaPlage) - 1)
    ActiveSheet.Range("$A$32:$AI$703").AutoFilter field:=5, Criteria1:=Array(MaPlage), Operator:=xlFilterValues

Quelqu'un pourrait-il m'aider ? J'ai longuement cherché sur le net et sur les forums mais je n'ai jamais obtenu de résultats.
A l'aide, à l'aide

Merci par avance

Nadège

[Marc-L]

Bonjour,

faire l'opération manuellement en ayant déclenché préalablement le Générateur de macros puis comparer les codes …

[badege3378]

Bonjour,

J'ai fait ça aussi. J'obtiens la réponse ci-dessous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
ActiveSheet.Range("$A$32:$AI$703").AutoFilter field:=5, Criteria1:=Array("100", "756", "757", "900"), Operator:=xlFilterValues

ce qui correspond exactement à ma variable.

[mercatog]

Directement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub MonFiltre()
Dim LastLig As Long
Dim Tb
 
With Worksheets("Feuil1")                        'à adapter (feuille contenant les codes)
    LastLig = .Cells(.Rows.Count, "BA").End(xlUp).Row
    If LastLig >= 2 Then
        Tb = Application.Transpose(.Range("BA2:BA" & LastLig))
 
        With Worksheets("Feuil2")                'à adapter (feuille à filtrer. si elle est identique à la feuille des code, supprimer ce With/End with)
            .Range("E32:E703").AutoFilter Field:=1, Criteria1:=Tb, Operator:=xlFilterValues
        End With
    End If
End With
End Sub

[badege3378]

Bonjour Mercatog,
Je viens de tester et j'obtiens la même chose qu'avec mon code, c'est-à-dire que le filtre ne remonte aucune valeur alors que la colonne en contient.
Je ne comprends pas pourquoi cela ne fonctionne pas avec une variable.

[mercatog]

Si tes valeurs sont numériques

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub MonFiltre()
Dim LastLig As Long, i As Long
Dim Tb
 
With Worksheets("Feuil1")                        'à adapter (feuille contenant les codes)
    LastLig = .Cells(.Rows.Count, "BA").End(xlUp).Row
    If LastLig > 2 Then
        Tb = Application.Transpose(.Range("BA2:BA" & LastLig))
 
        For i = 1 To LastLig - 1
            Tb(i) = CStr(Tb(i))
        Next i
 
        With Worksheets("Feuil2")                'à adapter (feuille à filtrer. si elle est identique à la feuille des code, supprimer ce With/End with)
            .Range("E32:E703").AutoFilter Field:=1, Criteria1:=Tb, Operator:=xlFilterValues
        End With
    End If
End With
End Sub

[badege3378]

Ca marche c'est fabuleux.Un énorme merci Mercatog.
Mes données sont effectivement numériques, ça fonctionne parfaitement bien.
Bonne fin de journée et bon week-end

Nadège