Discussion :

[Genco928]

Bonjour, à tous

au sujet de cette discussion qui date un peu.
Je suis nouveau sur le forum et débutant dans le monde du VBA, merci d'avance pour votre indulgence si je ne m'exprime pas correctement....

J'ai presque trouvé dans cette discussion ce que je cherchais malheureusement, je ne parviens pas à appliquer la macro proposée pour XL2007 par Daniel.C.

J’ai copier/coller le code dans un module VBA de mon fichier excel et j'obtiens le message d'erreur suivant :
"Erreur de compilation : Référence incorrecte ou non qualifiée" et ".Rows" à la ligne 10 est surligné.

J'ai oublié de dire je suis sous seven et j'utilise la suite office 2013.

Dans l'idéal, je cherche une macro (que l'on lance à partir d'Outlook ou de excel) qui fasse les actions suivantes :
Si la macro est dans outlook :
- on sélectionne plusieurs mails dans outlook
- on clique sur le bouton de la macro
- les mails sélectionnés sont :
- sauvegardés dans l’explorateur windows à un endroit défini en .msg avec un numéro de chrono unique
- les infos du mail 1 sont copiées dans un fichier excel (récap_mail) sur la ligne 2:
- colonne C : date du mail
- colonne D : expéditeur du mail
- colonne E : objet du mail
- colonne F : destinataires du mail
- colonne G : nom des pièces jointes attachées au mail
- colonne H : tailles (en Ko) des pièces jointes attachées au mail
- colonne A : un numéro de chrono qui s’incrémente (chrono 0001 pour le premier mail)

- De même les infos du mail 2 sont copiées sur la ligne suivante (ici ligne 3)
- Et ainsi de suite pour les autres mails
- Si on relance la macro un autre jour avec une nouvelle sélection de mail que les infos se mette à la suite dans le même fichier excel avec un numéro de chrono qui s’incrémente sur le dernier
- l’idéal serait que le numéro de chrono créé dans la colonne A du fichier excel soit un lien hypertexte qui ouvre le mail stocké dans l’explorateur.

Si la macro est dans excel :
A peu près la même chose que décrit ci-dessus mais cela me parait plus difficile d’appliquer la macro sur la sélection de mail faite sur outlook.
Si vous avez des idées ou suggestions.

Je vous remercie par avance

[Daniel.C]

Bonjour,

"Erreur de compilation : Référence incorrecte ou non qualifiée" et ".Rows" à la ligne 10 est surligné.

Oui, c'est normal, honte sur moi ! il faut mettre cette ligne après l'actuelle ligne 11.

Pour le reste, mets cette macro dans un module standard :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Sub test()
    Dim OutApp As Object, Ligne As Long, Chrono As String, Desti, Lig As Long, Fich
    Application.ScreenUpdating = False
    Set OutApp = CreateObject("OutLook.Application")
    With Sheets("Feuil1")
        For Each Item In OutApp.ActiveExplorer.Selection
            Ligne = .Cells.Find("*", , , , xlByRows, xlPrevious).Row + 1
            Chrono = .[A:A].Find("*", , , , xlByRows, xlPrevious).Value
            If Not IsNumeric(Right(Chrono, 4)) Then
                .Cells(2, 1) = "Chrono0001"
            Else
                .Cells(Ligne, 1) = "Chrono" & Format(CInt(Right(Chrono, 4)) + 1, "0000")
            End If
            .Cells(Ligne, 3) = Item.ReceivedTime
            .Cells(Ligne, 4) = Item.Sender
            .Cells(Ligne, 5) = Item.Subject
            Lig = Ligne - 1
            For Each Desti In Item.Recipients
                Lig = Lig + 1
                .Cells(Lig, 6) = Desti.Address
            Next Desti
            Lig = Ligne - 1
            For Each Fich In Item.Attachments
                Lig = Lig + 1
                .Cells(Lig, 7) = Fich.Filename
                .Cells(Ligne, 8) = .Cells(Ligne, 8) + Fich.Size / 1024
            Next Fich
            Item.SaveAs "C:\temp\" & .Cells(Ligne, 1) & ".msg", olMSG
        Next Item
    End With
    Application.ScreenUpdating = True
End Sub

PJ : Genco928.xlsm
PS. Les messages sont enregistrés dans le dossier "C:\temp". Modifie-le à ton gré.

[Genco928]

Vraiment merci beaucoup, c'est exactement ce que je voulais faire !

Je suis très impressionné autant par la qualité de la réponse que par sa rapidité

mille fois merci Daniel

[Audrey95]

Bonjour,

Je déterre ce sujet qui correspond à 90% à ce dont j'ai besoin.

Je souhaiterai réaliser un tableau qui liste les mails contenu dans un dossier outlook (au besoin je peux les regrouper dans un dossier windows comme proposé dans la macro).
Les informations qui m'intéresse sont :
- l’expéditeur,
- l'objet,
- la date de réception
- la catégorie appliquée sur le mail (outlook nous permet de 'taguer' les mails selon des catégories)

La macro proposée répond donc en grande partie à mes besoins (même plus sur certain point!), mais il me manque l'information de la catégorie appliquée sur le mail (qui est la donnée principale qui va me permettre de faire des stats) savez-vous comment je peux l'ajouter?

J'ai essayé d'utiliser la macro depuis le fichier Genco928.xlsm. J'ai copié mes mails dans le dossier C:\Temp\THD et j'ai appliqué le changement dans la macro. Mais quand je fais Ajouter ou que je lance la macro il ne me remonte qu'un mail sur les 921. Il remonte toujours le même mail à chaque fois que je lance la macro.
Y-a-t-il d'autre action à faire pour que ça me remonte tous les mails?

Merci d'avance pour vos retours!!

[Daniel.C]

Bonjour,

Essaie :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub test()
    Dim OutApp As Object, Ligne As Long, Chrono As String, Desti, Lig As Long, Fich
    Application.ScreenUpdating = False
    Set OutApp = CreateObject("OutLook.Application")
    With Sheets("Feuil1")
        For Each Item In OutApp.ActiveExplorer.Selection
            Ligne = .Cells.Find("*", , , , xlByRows, xlPrevious).Row + 1
            .Cells(Ligne, 1) = Item.Sender
            .Cells(Ligne, 2) = Item.Subject
            .Cells(Ligne, 3) = Item.ReceivedTime
            .Cells(Ligne, 4) = Item.categories
'            Item.SaveAs "C:\temp\" & .Cells(Ligne, 1) & ".msg", olMSG
        Next Item
    End With
    Application.ScreenUpdating = True
End Sub

[Audrey95]

Bonjour Daniel,

Ça marche super bien : me suffit de sélectionner les mails concernés et les infos s'incrémentent dans le fichier excel!
Tu es trop fort!

Merci beaucoup pour ta réactivité et pour la qualité de tes scripts!
(les mails sont sur une boite générique depuis laquelle je ne peux pas utiliser l'outil d'export d'Outlook)

[Jojoo30]

Bonjour,

Je déterre ce sujet une décennie après.

Je travaille sur le même type de problème. Je reçois chaque semaine 20 à 30 mails à saisir sur Excel et toujours du même expéditeur.
Et sur Excel, j'ai 5 à 7 colonnes à remplir chaque fois.
Etant vraiment novice avec l'utilisation de VBA, je sollicite votre aide.

Merci

Cordialement Jojo

[Daniel.C]

Bonjour,

Quelles sont les éléments que vous souhaitez copier sur la feuille Excel et dans quelles colonnes ?

Cordialement.

Daniel