Discussion :

[ptiot70]

Bonjour,

J'utilise un fichier EXCEL pour l'engagement de mon personnel tout les jours en copiant la dernière feuille et j'aimerais pouvoir avoir l'auto complétion en plus de ma liste déroulante mais surtout pouvoir conserver mon message d'avertissement : exemple, avec une liste déroulante comprenant lundi, mardi, mercredi, jeudi, vendredi, samedi et dimanche, taper sur le clavier uniquement "L" dans une cellule (ou combobox???), puis "LUNDI" s'afficherait automatiquement. Il ne me resterait plus qu'à valider. D'après mes recherches, il en ressort que ca doit être possible mais en avec VBA, chose que je ne maitrise pas. J'ai même trouvé une vidéo sur le net, malheureusement en anglais et sur une version EXCEL que je ne connais pas du tout, mais qui reflète exactement ce que j'aimerais faire, hormis le message d'avertissement. Etant nouveau sur le forum et novice, je ne sais pas si je peux vous mettre le lien...Je suis donc à la recherche d'une personne qui pourra me guider pas à pas. J'ai le fichier en guise d'exemple si besoin.
Merci d'avance aux personnes qui me consacreront de leurs temps.

[had4789]

Bonjour,

Tu vas avoir un problème avec mercredi.

Pour moi le plus simple c'est de faire un worksheetchange.

Tu dis quand la valeur de ma cellule change si la valeur est L alors la nouvelle valeur de ma cellule est Lundi est tu fais ça jusque dimanche.

Tu peux faire la même chose avec 1 à 7.

http://silkyroad.developpez.com/VBA/EvenementsFeuille/

[Theze]

Bonjour,

teste ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
 
Private Sub Worksheet_Change(ByVal Target As Range)
 
    'ici, la cellule cible est C5, adapter...
    If Target.Address(0, 0) <> "B5" Then Exit Sub
 
    Application.EnableEvents = False
 
    'seuls mardi et mercredi demande deux lettres
    If Target.Value Like "l*" Then Target.Value = "lundi"
    If Target.Value Like "ma*" Then Target.Value = "mardi"
    If Target.Value Like "me*" Then Target.Value = "mercredi"
    If Target.Value Like "j*" Then Target.Value = "jeudi"
    If Target.Value Like "v*" Then Target.Value = "vendredi"
    If Target.Value Like "s*" Then Target.Value = "samedi"
    If Target.Value Like "d*" Then Target.Value = "dimanche"
 
    Application.EnableEvents = True
 
End Sub

Il faut bien évidemment que tu valide ta première ou deux premières lettres en sortant de la cellule (entrée ou tab ou autre) pour que l'évènement se déclenche et que le jour correspondant s'inscrive !

Hervé.

[ptiot70]

Bonjour,

Merci à vous deux pour ces éclaircissement mais je ne suis pas sûr que cela fonctionne pour mon fichier. Les jour de la semaine sont pour l'exemple, sur mon fichier, cela doit fonctionner avec des noms de famille, et sur plusieurs cellules (c'est un tableau d'engagement du personnel).
Ci joint ce fichier qui reflètera bien mieux mes explications, ainsi que la vidéo vu sur le net dont je parle dans mon premier message.

D'après vous, est ce possible sur excel 2010 (comme évoqué dans mon premier message, je ne connais pas la version utilisé)
Pour rappel, je suis novice dans excel par rapport à vous, mes compétences s'arrêtent aux macros et aux formules de calcul comme vous pourrez le voir sur mon fichier. Donc désolé si je vous pose des questions qui pour vous couleront de source...
Merci d'avance
Cordialement

[eriiic]

Bonjour,

Tu lui reproches quoi à ton fichier ?
L'autocomplétion fonctionne.
Ne démarre pas ta saisie par ' c'est tout. Si tu tapes ba il te propose BARDE

eric

[ptiot70]

Bonjour Éric,
Je ne lui reproche rien, je cherche juste a l améliorer afin que le nom s'inscrive directement dans la cellule (ou combo box)lorsque je tape au clavier B et A pour BARDE, uniquement G pour GABIN, etc... Comme vu à 2,05min sur la vidéo de mon précédent message. est ce possible sur excel 2010 et comment réaliser la procédure? Merci

Rebonjour,
En relisant les messages, la solution d Hervé me semble bonne mais le problème est que la liste n est pas des jours de la semaine mais des noms car c est un effectif. Ces noms changent constamment( au minimum un fois par mois un départ ou une arrivée intérim). La solution d Hervé ne pourrait elle pas s adapter en fonction de la liste de mon personnel en automatique plutôt que j ailles dans le code pour changer manuellement les données???
Merci d avance pour vos réponses
Cordialement

[eriiic]

Je ne lui reproche rien, je cherche juste a l améliorer afin que le nom s'inscrive directement dans la cellule (ou combo box)lorsque je tape au clavier B et A pour BARDE, uniquement G pour GABIN, etc...

Je ne comprend toujours pas. Il fonctionne exactement comme ça, que ce soit sur 2003 ou 2010.
C'est taper sur enter pour valider qui te gène ?
eric

[ptiot70]

Je suis d'accord avec toi, cela marche avec BARDE si tu l'inscris dans la colonne K puisqu'elle apparait déjà en K11. Mais si tu l'effaces de cette cellule ou si tu essayes dans les colonne M ou O, cela ne fonctionne pas.
Cordialement

[Theze]

Bonjour,

Dans ton premier post tu disais :

avec une liste déroulante comprenant lundi, mardi, mercredi, jeudi, vendredi, samedi et dimanche, taper sur le clavier uniquement "L" dans une cellule (ou combobox???), puis "LUNDI" s'afficherait automatiquement.

donc, je suis parti sur les jours de la semaine !
Maintenant, si tu veux avoir une liste qui est changeante et avoir un remplissage semi automatique teste ceci avec les noms en colonne A de A1 à Ax. Attention tout de même de vérifier la valeur qui est entrée car c'est la première trouvée en partant du haut qui sera inscrite donc, si deux noms commencent par les mêmes lettres il te faudra saisir jusqu'à la lettre qui les différencie :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Private Sub Worksheet_Change(ByVal Target As Range)
 
    Dim Plage As Range
    Dim Cel As Range
 
    'ici, la cellule cible est C5, adapter...
    If Target.Address(0, 0) <> "C5" Then Exit Sub
 
    'la plage des noms se trouve en colonne A de la feuille active, à adapter...
    With ActiveSheet
 
        Set Plage = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
    Application.EnableEvents = False
 
    Set Cel = Plage.Find(Target, , xlValues, xlPart)
 
    If Not Cel Is Nothing Then Target.Value = Cel.Value
 
    Application.EnableEvents = True
 
End Sub

Hervé.

[Invité]

Salut,

Sinon, dans la FAQ:
FAQ ( Taper AutoCompletion dans le champs Recherche) => Comment implémenter une auto-complétion sur un contrôle TextBox ?

Sur le Forum Contribuez : [Textbox] Autocomplétion

A voir si tu peux l'adapter sur un contrôle ActiveX de liste déroulante sur feuille de calcul. Je pense que ton exemple de Youtube ramène au même type d'autocomplétion que dans la FAQ.


A+

[ptiot70]

Bonjour,

Merci à vous deux pour ces codes mais étant novice, pouvez vous m indiquer la procédure pas a pas afin de coller ce code a l emplacement ou il doit y être.J ai essayé en tapant alt f11 mais étant novice, je suis arrive tel un extraterrestre sur une terre inconnue... Merci pour votre aide
Cordialement

[Theze]

Bonjour,

Donc, Alt + F11 là, tu es dans le VBE. A gauche et en haut tu as une fenêtre avec les noms des feuilles de ton classeur, cherche la feuille cible son nom Excel est entre parenthèses (l'autre étant le nom du module de la feuille), double clique dessus, à ce moment sur la droite une zone de texte s'affiche, là tu colle le code que je t'es posté puis tu retourne dans Excel et tu teste. Attention, pour le test j'ai pris une cellule cible au hasard :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
If Target.Address(0, 0) <> "C5" Then Exit Sub

Cette cellule est la C5 si ce n'est pas la bonne pour toi, change l'adresse entre les guillemets.

Hervé.

[ptiot70]

Bonjour

Je pense avoir suivi ta procédure, j'ai changé le cellule C5 par N3 pour l'essai, remis la liste en colonne A...Je pense que je vais commencer à devenir fou : ca ne fonctionne pas... Enfin si, seulement si le nom est déjà dans la colonne N comme par exemple HUMBER, LE ou RAMONDY... Peux tu jeter un coup d'œil au fichier ci joint STP? Si ça arrive à fonctionner, comment faire pour que ça s'applique à plusieurs cellules?? (comme pour une formule de calcul, exemple N3:N5;N7:N9;N11:N13 etc....)?
Merci infiniment

[Theze]

Bonjour,

Voici le code pour plusieurs cellules en colonne N :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
 
Private Sub Worksheet_Change(ByVal Target As Range)
 
    Dim Plage As Range
    Dim Cel As Range
 
    If Intersect(Target, Range("N3,N5,N7,N9,N11,N13")) Is Nothing Then Exit Sub
 
    'la plage des noms se trouve en colonne A de la feuille active, à adapter...
    With ActiveSheet
 
        Set Plage = .Range(.Cells(1, 1), .Cells(.Rows.Count, 1).End(xlUp))
 
    End With
 
    Application.EnableEvents = False
 
    Set Cel = Plage.Find(Target, , xlValues, xlPart)
 
    If Not Cel Is Nothing Then Target.Value = Cel.Value
 
    Application.EnableEvents = True
 
End Sub

Comme la comparaison est binaire, n3 et N3 sont différents donc comme les adresses de cellules sont retournées en majuscules il te faut indiquer les adresses en majuscules.
Pour que le système fonctionne, il ne faut pas qu'il y ai de liste de validation dans les cellules cibles car elles sont prioritaires sur la procédure évènementielle "Worksheet_Change".

Hervé.