Discussion :

[CaroBibb]

Bonjour,
Je cherche la solution la plus simple à mon problème et quoique certains cas ressemblent au mien, je ne trouve pas LA solution à mon problème.

Le contexte est le suivant :
Dans un premier onglet Sheets("Facture"), j'ai mon interface de facture.
Mon deuxième onglet Sheets("BD Facture) est comme le nom le dit, là où je veux cumuler les données relatives aux différentes factures créées.

J'ai une macro qui génère mon # automatique de chaque facture

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub NO_Facture()
                               'Va chercher le dernier numero de facture dans la BD Facture
                               'Additionne 1 à ce numero de facture
                               'Va inscrire ce numero dans l'onglet Facture dans la cellule appropriée
 
                       ProchaineCelluleVide = Sheets("BD Facture").Range("c1").End(xlDown).Value
                       ProchainNumero = ProchaineCelluleVide + 1
                       Sheets("Facture").Range("k2").Value = ProchainNumero
                        End Sub

BREF,
Maintenant, je veux que certaines cellules contenant de l'information importante (date, # client, montant facture, etc) soient «exportées» dans ma BD
Là où mon nouveau # de facture va avoir été créé.

J'avais utilisé la macro suivante, mais je réalise que si le # existe déjà, il va se doubler...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub RemplirChamp()
'Permet d'aller chercher tous les nouveaux champs de la facture et de remplir la BD
'En commençant par aller ajouter le # de facture utilisée (BD Facture : Colonne C)(Facture : k2)
Sheets("BD Facture").Range("c1").End(xlDown).Select
Selection.Offset(1, 0).Value = Sheets("Facture").Range("k2").Value
 
'Cellule # document (BD Facture : Colonne A)(Facture : K3)
Sheets("BD Facture").Range("a1").End(xlDown).Select
Selection.Offset(1, 0).Value = Sheets("Facture").Range("k3").Value
 
 
'Cellule # Client (BD Facture : Colonne B)(Facture : K1)
Sheets("BD Facture").Range("b1").End(xlDown).Select
Selection.Offset(1, 0).Value = Sheets("Facture").Range("k1").Value
 
'Cellure Date (BD Facture : Colonne D)(Facture : G5)
Sheets("BD Facture").Range("d1").End(xlDown).Select
Selection.Offset(1, 0).Value = Sheets("Facture").Range("g5").Value
 
' Cellule Montant avant taxes (BD Facture : Colonne E)(Facture : H26 )
Sheets("BD Facture").Range("e1").End(xlDown).Select
Selection.Offset(1, 0).Value = Sheets("Facture").Range("h26").Value
 
' Cellule TPS (BD Facture : Colonne F)(Facture : H27)
Sheets("BD Facture").Range("F1").End(xlDown).Select
Selection.Offset(1, 0).Value = Sheets("Facture").Range("h27").Value
 
' Cellule TVQ (BD Facture : Colonne G)(Facture : H28)
Sheets("BD Facture").Range("g1").End(xlDown).Select
Selection.Offset(1, 0).Value = Sheets("Facture").Range("h28").Value
 
' Cellule Montant après taxes (BD Facture : Colonne H)(Facture : H29)
Sheets("BD Facture").Range("h1").End(xlDown).Select
Selection.Offset(1, 0).Value = Sheets("Facture").Range("h29").Value
 
End Sub

Je pense donc inscrire dans la dernière cellule libre le # de facture que j'ai créée dans la macro NOFacture et j'aimerai que ma macro trouve ce # puis inscrive dans les bonnes cellules les valeurs de la facture...

Est-ce que je suis claire

Un gros merci !!

[Thautheme]

Bonsoir Carobibb, bonsoir le forum,

Pas sûr d'avoir bien compris, je verrais les choses comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
Private N As Long  'déclare la variable N (Numéro)
 
 
Sub NO_Facture()
N = Application.WorksheetFunction.Max(Sheets("BD Facture").Columns(3)) + 1 'définit le numéro N
Sheets("Facture").Range("k2").Value = N 'place le numéro N danws la cellule K2 de l'onglet "Facture"
End Sub
 
 
Sub RemplirChamp()
Dim F As Object 'déclare la variable F (onglet Facture)
Dim B As Object 'déclare la variable B (onglet BD Facture)
Dim R As Range 'déclare la variable R (Recherche)
Dim LI As Long 'déclare la variable LI (LIgne)
 
Set F = Sheets("Facture") 'définit l'onglet F
Set B = Sheets("BD Facture") 'définit l'onglet F
Set R = B.Columns(3).Find(N, , xlValues, xlWhole) 'définit la recherche R (recherche le numéro dans la colonne 3 de l'onglet B)
If Not R Is Nothing Then 'si il existe au moins une occurrence trouvée
    LI = R.Row 'définit la ligne Li (ligne de l'occurrence trouvée)
Else 'sinon
    'définit la ligne LI comme la première ligne vide de la colonne 3 (=C) de l'onglet B
    LI = B.Cells(Application.Rows, Count, 3).End(xlUp).Row + 1
End If
B.Cells(LI, 3).Value = F.Range("K2") 'numéro de facture
B.Cells(LI, 1).Value = F.Range("K3") 'document
B.Cells(LI, 2).Value = F.Range("K1") 'client
B.Cells(LI, 4).Value = F.Range("G5") 'date
B.Cells(LI, 5).Value = F.Range("H26") 'Montant avec taxes
B.Cells(LI, 6).Value = F.Range("H27") 'TPS
B.Cells(LI, 7).Value = F.Range("H28") 'TVQ
B.Cells(LI, 8).Value = F.Range("H29") 'Montant après taxe
End Sub

[CaroBibb]

Bonjour Thautheme,
Je n'arrive pas à saisir pourquoi, mais j'ai une erreur d'exécution ('450' nombre d'arguments incorrect ou affectation de propriété incorrect) qui apparaît à la ligne Else :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
LI = b.cells(application.rows,count,3).end(clip).row+1

J'ai beau relire le tout, je ne vois pas pourquoi.

Mais sinon, le code semble combler mon besoin!! C'était exactement ce que j'essayais de trouver, soit il trouve N, soit il ajoute une nouvelle ligne...

Merci !

[Philippe Tulliez]

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

LI = b.cells(application.rows,count,3).end(clip).row+1

Qu'elle est la valeur de Clip où as-tu été chercher cette variable ?
Habituellement on utilise l'un des constantes suivantes xlDown, xlUp, xlToRight ou xlToLeft

[Thautheme]

Bonjour le fil, bonjour le forum,

Tabernacle ! Clip ça doit être xlUp en canadien ...

[Marc-L]

Bonjour, bonjour !

Ligne en erreur (syntaxe !) : LI = b.cells(application.rows,count,3).end(clip).row+1

Correction : LI = B.Cells(Application.Rows.Count, 3).End(xlUp).Row + 1 …

Et oui, une virgule n'est pas un point …
A noter les initiales des instructions passant en majuscule une fois la ligne de code correcte, tabernacle !

__________________________________________________________________________________________

Merci de cliquer sur pour chaque message ayant aidé puis sur pour clore cette discussion …

[Thautheme]

Bonjour le fil, bonjour le forum,

Bien vu Marc ! Merci de me corriger, j'avions pas vu Tabernacle !

[CaroBibb]

Salut les mecs,
Je n'ai pas trop saisi pourquoi (xlUp) a converti en (Clip) lorsque j'ai ajouter la balise CODE, mais peu importe puisque dans mon document c'était tjrs (xlUp).

Alors un gros merci, spécialement à Thautheme et Marc, lorsque la virgule a été changée en point, tout fonctionna à merveille!

Je vais maintenant déplacer ma BD de document et complexifier un peu mes affaires.

Bonne journée à tous

Caro
xx