Discussion :

[ClaudeLELOUP]

Bonjour,

Je suis donc prêt pour la suite

OK.

Imagine que tu as encodé, au fil du temps, quelques centaines d'enregistrements avec le formulaire fRapport (poste une BdD avec quelques dizaines de cas typiques réels qui nous serviront d'exemple pour la suite des développements).

Le formulaire s'affiche donc avec des centaines de lignes, dans l'ordre où tu les as encodées.

Essaie de me dire sur la base de quels critères tu voudrais limiter temporairement ce nombre de lignes, par exemple pour corriger une erreur, ou simplement vérifier une donnée.
Exemples de réponses : pour telle équipe, de telle date à telle date...

[Saumon80]

En fait ,j'aimerai savoir si il était possible d'avoir jus[S]te la ligne active de saisie du formulaire qui apparaitrait dans une fenêtre au dessus du formulaire de cette manière cela simplifierait la saisie de l'utilisateur qui remplirait donc les champs directement puis appuierait sur un bouton ok ou valider et cela passerait à la ligne suivante (donc avec les champs équipe et date pré remplit) afin de saisir plus vite mais sans rien changer au formulaire.
Juste la ligne active de saisie dans une fenêtre comme sa quand l'utilisateur à saisie sa quinzaine de ligne il ferme la petite fenetre et peut voir le formulaire que tu as réalisé et revérifier et modifier si besoin a même le formulaire

Concernant les critères que j'aimerai pouvoir vérifier se serait :

-Par mois donc voir les inventaires sur un mois
-Idem par semaine
-Idem par jour
-Voir les inventaires par équipe
-Par adresse
-Par référence
-Et avoir une requête pour ne montrer que les lignes ou il y des écarts

Après je souhaiterai également rajouter un calcul, dont il faut que je récupère le détail mais grosso modo c'est le taux de fiabilité sur un mois cad le nombre de lignes ou il y a des écarts sur le nombre total de lignes du mois.Et donc se serait bien que je puisse l'avoir en temps réel sur le mois même si le mois n'est pas fini.

Je rentre plusieurs dizaines d'enregistrements dans la base comme tu m'as demandé et dés que j'ai fini j'envoie cela.

[Saumon80]

Bonjour

Voila j'ai ajouté 40 enregistrements pour la base de données ,si ce n'est pas suffisant dis moi le et j'en rajouterais plus

[ClaudeLELOUP]

Bonjour,

Quand tu ouvres l’application, tu reçois ce formulaire.



Nous y ajouterons d’autres boutons au fur et à mesure du développement.
Un clic sur le bouton « Encoder des rapports » déclenche ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Option Compare Database
Option Explicit
 
Private Sub btRapport_Click()
  DoCmd.OpenForm "fRapport"
  DoCmd.GoToRecord acDataForm, "fRapport", acNewRec
End Sub

On ouvre le formulaire rapport et on se positionne sur un nouvel enregistrement :



… et l’utilisateur peut encoder ses rapports comme décrit dans les précédents billets.

Ce formulaire est devenu une espèce de couteau suisse : on peut encoder, modifier, supprimer et consulter de manière sélective ou non.
Si on clique sur le bouton « Supprimer les filtres », tous les enregistrements s’affichent dans l’ordre où ils ont été encodés



Si on coche la case « N’afficher que s’il y a une différence, la liste se réduit :




On peut encore affiner la sélection des enregistrements affichés en sélectionnant des valeurs de filtres, par exemple, voici la liste des enregistrements
- depuis le début jusqu’au 30/11/14 inclus,
- à l’adresse 51E4,
- avec une différence



Le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
Option Compare Database
Option Explicit
 
Public Sub MaJ()
'Sub appelée à chaque mise à jour d'un filtre
  Dim sSql As String
  Dim q As QueryDef
  Dim t() As String
    'si la case "avec différence" n'est pas cochée, on choisit rFiltreRapports comme source
  If Me.ccDifference = 0 Then
      Me.RecordSource = "rFiltreRapports"
    'si elle est cochée, on corrige le SQL de cette requête pour ne reprendre que les différences <> 0
    Else
      Set q = CurrentDb.QueryDefs("rFiltreRapports")
      t = Split(q.SQL, " Or ([QPysique]-[QLog]<>0)=No));")
      sSql = t(0) & "));"
      Me.RecordSource = sSql
      Set q = Nothing
  End If
  Me.Requery
End Sub
 
Private Sub Form_Open(Cancel As Integer)
  Me.RecordSource = "rFiltreRapports"
End Sub
 
Private Sub CboAdresse_AfterUpdate()
  Me.CboAdresse.DefaultValue = Me.CboAdresse
End Sub
 
Private Sub cboEquipe_AfterUpdate()
  Me.cboEquipe.DefaultValue = Me.cboEquipe
End Sub
 
Private Sub txtRapDate_AfterUpdate()
  Me.txtRapDate.DefaultValue = "#" & Format(Me.txtRapDate, "mm/dd/yy") & "#"
End Sub
Private Sub BtTout_Click()
  Dim ctl As Control
  For Each ctl In Me.Controls
    If Left(ctl.Name, 6) = "filtre" Then
        Me(ctl.Name) = Null
    End If
  Next ctl
  Call MaJ
End Sub
 
Private Sub filtreDu_BeforeUpdate(Cancel As Integer)
  'Contrôle de cohérence Du Au
  If Not IsNull(Me.FiltreAu) And Me.FiltreAu < Me.FiltreDu Then
    MsgBox "Période incohérente !", vbCritical
    Cancel = True
    Me.Undo
  End If
End Sub
 
Private Sub filtreAu_BeforeUpdate(Cancel As Integer)
  'Contrôle de cohérence Du Au
  If Not IsNull(Me.FiltreDu) And Me.FiltreAu < Me.FiltreDu Then
    MsgBox "Période incohérente !", vbCritical
    Cancel = True
    Me.Undo
  End If
End Sub
 
Private Sub FiltreDu_AfterUpdate()
  Call MaJ
End Sub
 
Private Sub FiltreAu_AfterUpdate()
  Call MaJ
End Sub
 
Private Sub FiltreAdresse_AfterUpdate()
  Call MaJ
End Sub
 
Private Sub FiltreEquipe_AfterUpdate()
  Call MaJ
End Sub
 
Private Sub FiltreReference_AfterUpdate()
  Call MaJ
End Sub
Private Sub ccDifference_AfterUpdate()
  Call MaJ
End Sub

La technique est, pour l’essentiel , décrite dans ce tutoriel : http://claudeleloup.developpez.com/t...-multicritere/
(Sauf pour l’affichage des enregistrements avec une différence, que je reviendrai expliquer quand le formulaire sera au point.)

La base de données est mise à jour ici : http://claudeleloup.developpez.com/&...0/Saumon80.mdb

[Saumon80]

Bonjour

Vraiment encore merci énormément ,en tout cas c'est génial et bien plus pratique d'avoir tout sous la main qu'avec des requêtes,pas besoin de cliquer sur chaque requête pour avoir accès à ce que l'on veut on gagne un temps fou
Cela me resservira cette manière de faire même si je dois avouer que les codes VBA utilisés sont encore un peu flou pour moi mais je vais bien les étudier et utiliser F1 et les tutos pour parfaitement les maitriser,je vais bien lire le tuto que tu m'a donné

Je souhaiterai juste savoir s'il sera possible de rajouter une ligne pour les rapports pour avoir les rapports de telle semaine,par exemple je tape 41 et cela me sort tous les rapports de la semaine 41 sinon mis à part cela c'est archi complet

Il faut juste que je t'envoie le calcul de fiabilité ,le problème c'est que le calcul actuel est super compliqué donc d'ici demain je vais tacher de le simplifier le plus possible afin de pouvoir l'intégrer dans le formulaire

[Saumon80]

Et je voulait juste savoir si a la fin de la saisie d'une ligne se serait possible quand je tabule ou que je met entrée de passer à la ligne suivante car la cela revient au début de la ligne

[ClaudeLELOUP]

Bonjour,

Je souhaiterais juste savoir s'il sera possible de rajouter une ligne pour les rapports pour avoir les rapports de telle semaine

Par exemple, tu complètes cette nouvelle case



il vient ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub txtSemaine_AfterUpdate()
  If Me.txtSemaine Like "*/*" Then
      Me.FiltreDu = DebutSemaine(Me.txtSemaine)
      Me.FiltreAu = Me.FiltreDu + 6
      Call MaJ
  End If
End Sub

et la fonction DebutSemaine pour obtenir le lundi qui commence une semaine donnée :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Option Compare Database
Option Explicit
 
Public Function DebutSemaine(Semaine As String) As Date
'        ? DebutSemaine("49/14") pour 49e semaine de 2014 => lundi 1er décembre
  Dim i As Integer
  Dim iSem As Integer 'N° de la semaine du 1er lundi
  Dim t() As String
  t = Split(Semaine, "/")
  For i = 1 To 7
    If Weekday(DateSerial(t(1), 1, i), vbMonday) = 1 Then Exit For
  Next i
  'i/1/t(1) = date du 1er lundi de l'année
  'dans quelle semaine se trouve ce 1er lundi ?
  iSem = DatePart("ww", DateSerial(t(1), 1, i), vbMonday, vbFirstFourDays)
  'rechercher la date de la semaine demandée
  DebutSemaine = DateSerial(t(1), 1, i) + 7 * (t(0) - iSem)
End Function

-----------

Passer automatiquement à l’enregistrement suivant :

Base de données à jour : htp://claudeleloup.developpez.com/&99/20141125SSaumon80/Saumon80.mdb

[Saumon80]

Super!Merci c'est bien sa que je voulais et pour l'enregistrement ok je saurait la prochaine fois
Par contre si je fait par exemple un formulaire par année je pourrait n'avoir à saisir que le numéro de la semaine sans le /Année ou bien ce n'est pas possible?

Du coup je pourrait adapter ce code pour les semaines à n'importe quel formulaire après c'est bien sa?

Toujours est-il qu'il a bien avancé le formulaire ,j’attends toujours la formule de calcul mieux vaut attendre que je l'ai pour poursuivre ou on pourra le rajouter plus tard?

[ClaudeLELOUP]

Par contre si je fais par exemple un formulaire par année je pourrais n'avoir à saisir que le numéro de la semaine sans le /Année ou bien ce n'est pas possible?

C'est évidemment possible, mais ce n'est sans doute pas une bonne idée de créer des bases de données pour chaque année. Tôt ou tard, tu voudras les refusionner pour obtenir des comparaisons, des évolutions, des statistiques de tous genres...

À la limite, si c'est le « /14 » qui te semble si lourd à encoder, le programme pourrait ajouter « /année courante » par défaut si tu introduis seulement le N° de semaine.
Comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub txtSemaine_AfterUpdate()
  If Me.txtSemaine Like "*/*" Then
      Me.FiltreDu = DebutSemaine(Me.txtSemaine)
      Me.FiltreAu = Me.FiltreDu + 6
      Call MaJ
    Else
      If Me.txtSemaine >= 0 And Me.txtSemaine <= 53 Then
        Me.txtSemaine = Me.txtSemaine & "/" & Format(Date, "yy")
        Call txtSemaine_AfterUpdate
      End If
  End If
End Sub

Base de données mofifiée.

[Saumon80]

C'est évidemment possible, mais ce n'est sans doute pas une bonne idée de créer des bases de données pour chaque année. Tôt ou tard, tu voudras les refusionner pour obtenir des comparaisons, des évolutions, des statistiques de tous genres...

Ok c'est parce qu'avec les fichiers Excel on en faisait un chaque année car le fichier devenait terriblement lourd mais c'est vrai qu'avec Access il n'y aura pas ce souci et cela évitera de devoir vider la base chaque année pour refaire un fichier c'est plus fiable

À la limite, si c'est le « /14 » qui te semble si lourd à encoder, le programme pourrait ajouter « /année courante » par défaut si tu introduis seulement le N° de semaine.
Comme ceci :

Oui super c'est exactement cela que je voulais ,ce sera je pense moins lourd pour l'utilisateur qui fera des recherches merci beaucoup C'est en effet beaucoup mieux que de refaire une base pour chaque année

Je prend bien note du cheminement que tu m'explique pour l'assimiler

[Saumon80]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.txtSemaine = Me.txtSemaine & "/" & Format(Date, "yy")

D'accord donc ici Me.txtSemaine = Numéro de la semaine
& "/" = le format d 'affichage
& Format(Date, "yy") le format du second membre si j'ai bien comprit?

[ClaudeLELOUP]

Traduction française du code dans le billet 29

6 : on arrive ici si on n’a pas une structure N°/année
7 : on demande si on a un nbre compris dans l’intervalle [0 ; 53]
8 : si oui, on ajoute « / » et les 2 chiffres de l’année de la date d’aujourd’hui
9 : on réexécute la sub, cette fois, on passe dans 3 à 5 (le cas normal).

[Saumon80]

Bonjour,

D'accord ,merci pour l'explication maintenant c'est plus clair

Ensuite je voudrait ajouter ce que l'on appelle le SRA (Stock Record Accuracy) et pouvoir donc en indiquant le numéro de la semaine pouvoir avoir son pourcentage
En fait il est calculé 2 fois

La première fois avant correction donc sur les données que l'on a actuellement et la seconde fois après correction donc sur qui viendra aprés

Pour calculer cela la formule est horriblement compliqué sur excel car calculé sur une case puis sur une autre case puis sur une autre,Etc...

Donc concrètement :

1.Ce calcul se fait semaine par semaine : S46/47,...

2.On additionne la quantité obtenue chaque fois qu'une valeur à été compté physiquement et informatiquement



Par exemple : La réf D09102500 à une valeur de 115 en comptage physique et de 118 informatiquement au cours de cette semaine

3.Ensuite on calcule l'écart entre le physique et l'informatique en %
La formule actuellement utilisé est : Si le nombre compté réellement est différent de zéro alors en valeur absolue on a (Nbre log - Nbre physique)/Nbre physique
Ici par exemple : ( 118 - 115 ) / 115 = 2,6 %
Si le nombre compté = 0 alors le taux sera de 0%

4.On prend ensuite le nombre de fois ou la référence à été compté dans la semaine avec le calcul suivant
1/Nombre de fois ou la réf à été comptée
Ici par ex:1/3 = 0,333333

5.Ensuite on a l'indice référence de la semaine= Si le taux d'écart calculé en 3. est strictement supérieur à 5% alors l'indice = 0 ,sinon l'indice = le taux en 4.
Ici l'indice étant inférieur à 5% il sera égal à 0,33333


6.Puis au final on calcul donc le SRA :
J’additionne la somme de ma colonne indice semaine (5.) pour toutes mes réf donc avec les chiffres pour toute la semaine que je divise par la somme du (4.) pour toutes les réf également

Ici il n'y a qu'une référence mais cela donnerait Indice = 0,33 / (4.) 0,33 = 1
Donc on aurait ici un taux de 100 %

En réalité ce qui fait descendre le taux sont les références dont l'écart est supérieur à 5% c'est ceci qui pénalise le taux


Et à part on calcul sur une semaine le nombre de ligne ou il y a un écart en %
Donc si sur 100 ligne on a 10 ligne avec un écart ce taux sera de 10% de ligne en écart

Voila désolé le calcul est assez complexe et je ne sait pas comment le modéliser sur access même si je pense que c'est possible
Pour info je met le fichier excel actuellement utilisé mais c'est assez brouillon

[ClaudeLELOUP]

Bonjour,

Imagine que ceci soit le relevé des rapports d’une semaine



Peux-tu vérifier que j’ai bien compris la démarche pour calculer le SRA.




Le SRA serait :

[Saumon80]

Bonjour

Voila c'est tout à fait cela hormis pour l'indice réf 5 en fait la seule nuance c'est que quand le taux 3 est strictement supérieur à 5% alors la valeur de l'indice réf 5 sera automatiquement zéro c'est la seule chose à changer
Si il est égal ou inférieur à 5% il sera comme tu l'a mis égal au taux 4

De cette manière le SRA sera au mieux de 100% et donc affiché en pourcentage

[ClaudeLELOUP]

OK. Comme ceci donc :

[Saumon80]

Voila c'est tout à fait sa

[ClaudeLELOUP]

OK.

Je verrais un formulaire dans lequel tu saisirais le N° semaine/année et qui afficherait alors le SRA.

Essaie d'expliquer comment tu réagis lorsque ce SRA te semble bizarre et que tu dois investiguer.
Pourrais-tu trouver l'origine de l'anomalie facilement en ne te servant que de fRapport ou as-tu besoin d'autres outils ?

Si tu pouvais créer un jeu de données de test, ça nous aiderait à mettre au point.

[Saumon80]

Je verrais un formulaire dans lequel tu saisirais le N° semaine/année et qui afficherait alors le SRA.

Oui c'est ce qui me parait aussi le plus adéquat

En fait il s'agit surtout d'un indicateur pour avoir une vue a l'instant T sur la fiabilité des stocks ,l'action directe qui est entreprise en regardant ce sra est de regarder toutes les case ou il y a des écarts et d'essayer de les corriger donc la case que tu as mise de n'afficher que les cases avec écart est suffisante

Donc ensuite c'est de regarder les case avec des écarts ,ensuite si on peut le corriger on saisit ensuite dans les cases qui seront rajouté plus tard l’éventuelle action que l'on a mené le nbr physique et informatique après correction et l'écart qui en découle et qui sera réduit ou passera à zero



Dans certains cas on aura réussi à corriger et dans d'autre non donc aprés on aura un autre SRA qui sera le SRA aprés écart et il peut donc subsister des écarts si on à pas réussi à les corriger

On aura donc un SRA avant celui qui correspond a la saisie initiale et un SRA aprés qui correspond au nombre aprés correction

Et ce qui serait bien serait d'avoir un bouton SRA avant correction et un bouton SRA aprés correction
Le premier nous indique quel était l'état initial et vu que des saisies ont lieu toute la semaine il évolue tout les jours et le second l'état final et sa permet aussi de voir en temps réel ce qui à été fait si vendredi je clik sur le SRA initial qui était de 95% et ensuite sur le SRA final qui est de 98% je peut constater que des actions ont été menés

Je peut saisir des données de test pour pouvoir travailler dessus se serait peut etre bien d'ajouter le bouton SRA pour voir comment sa évolue ?

[ClaudeLELOUP]

OK. On va y aller pas à pas.

Encode dans la DB des cas de test et poste-la.