Discussion :

[graphikris]

Bonjour,

J'ai créé une macro qui :
extrait dans un nouveau classeur des données de ma base de données puis qui l'imprime en PDF.

Mon problème est le suivant :
Dans mon entreprise nous travaillons sur un serveur unique sur lequel nous avons des imprimantes en réseau.
Ce réseau nous mais par défaut l'imprimante X au démarrage des ordis.

Lorsque j'ai crée ma macro, j'ai sélectionné l'imprimante virtuelle "PDF Creator" me permettant d'avoir mon extraction en version PDF.
Cette instruction n'apparait pas dans la macro.

Je voudrais donc forcer "excel" à imprimer en PDF sans que j'aille mettre cette imprimante par défaut ou si cela n'est pas possible, avoir une boite de dialogue me proposant de choisir l'imprimante sur le serveur, en l'occurrence PDF Creator

Slts

[parmi]

Bonjour,

Tu pourrais essayer ceci.
Ici, nous sommes en réseau et j'ai besoin de me brancher à l'imprimante "Microsoft XPS Document Writer" pour accélérer le processus de mise en page.
Ça devrait donc fonctionner pour toi moyennant peut-être quelques modifications

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
    Dim sActivePrinter As String
 
    sActivePrinter = Application.ActivePrinter
    Application.ActivePrinter = FindPrinter("PDF Creator")
    'traitement
    Application.ActivePrinter = sActivePrinter
 
'Written: November 28, 2009
'Author:  Leith Ross
'Summary: Finds a printer by name and returns the printer name and port number.
 
Function FindPrinter(ByVal PrinterName As String) As String
 
 'This works with Windows 2000 and up
 
    Dim Arr As Variant
    Dim Device As Variant
    Dim Devices As Variant
    Dim Printer As String
    Dim RegObj As Object
    Dim RegValue As String
 
    Const HKEY_CURRENT_USER = &H80000001
 
    Set RegObj = GetObject("winmgmts:{impersonationLevel=impersonate}!\\.\root\default:StdRegProv")
    RegObj.enumvalues HKEY_CURRENT_USER, "Software\Microsoft\Windows NT\CurrentVersion\Devices", Devices, Arr
 
    For Each Device In Devices
        RegObj.getstringvalue HKEY_CURRENT_USER, "Software\Microsoft\Windows NT\CurrentVersion\Devices", Device, RegValue
 
        If Application.International(xlCountrySetting) = 33 Then
            Printer = Device & " sur " & Split(RegValue, ",")(1)
        Else
            Printer = Device & " on " & Split(RegValue, ",")(1)
        End If
 
        If InStr(1, Printer, PrinterName, vbTextCompare) > 0 Then
            FindPrinter = Printer
            Exit Function
        End If
    Next
 
End Function

[graphikris]

Merci PARMI pour ta réponse,
mais là, c'est hors de mes compétence de pouvoir modifier ce code surtout que je vois qu'il y a des modif de base de registre et que cela est impossible car notre systeme d'exploitation est vérouillé (aucune modif possible)

En espérant d'autres réponses des membres du forum

Encore merci PARMI

[parmi]

Ce ne sont pas des modifs de base de registre, mais des clefs pour la lecture de celle-ci.
Ici aussi je suis en réseau, et très protégé...
Je n'ai aucunement accès à la base de registre.