Discussion :

[auracle68]

Bonjour amis Exceliens,

Voilà depuis quelques jours que je tourne en rond, en effet, j'utilise un code pioché sur internet, et c'est nickel, il correspond exactement à mon besoin, mais j'arrive pas à lui faire dire d'aller chercher la liste des destinataires (env. 50 personnes), ça marche super bien avec 1 destinataires, mais dés qu'il faut chercher, en créant un objet, ou une variable sur la ligne Item To : paff.... ça bloque.

Si quelqu'un a une idée je suis preneur.... là je sèche... Merci par avance de votre aide précieuse.

Voici le code en question.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
dim destinataires as object
destinataires=sheets("Destinataires").range("A1:A55")

ActiveSheet.Range("A1:J50").Select 
ActiveWorkbook.EnvelopeVisible = True
 
With ActiveSheet.MailEnvelope
    .Item.To = destinataires
    .Item.Subject = "Recap du moi"
    .Item.Send
End With
End Sub

[pgz]

Bonjour.

As-tu déclaré la variable destinataire ? Quel est son type ?
Tu dois transformer ton tableau "A1:A55") en une seule chaîne de caractères contenant toutes les adresses mail séparées par des ";".

Cordialement,

PGZ

[auracle68]

Bonjour PGZ,

Tout d'abord merci d'avoir répondu à mon SOS.

Oui j'ai nommé ma variable comme object, donc si je comprends ce que tu me dis, je dois concatener l'ensemble des adresses mail dans une seule cellule. Ok, moi ça me va, par contre, pour que la ligne Item To: fonctionne, tu crois que le fait de déclarer la variable comme "dim destinataires as object" est une bonne idée ??

MErci encore de ton aide.

[pgz]

Auracle68,

Il faut bien faire attention au type de variable. Pour alimenter la propriété To, il te faut une variable de type chaîne.
Ton code pourrait ressembler à ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub subEnvoiEmail()
'...
Dim vDestinataire As Variant, i As Integer
Dim sDestinataire As String
 
'...
 
vDestinataire = ThisWorkbook.Worksheets("Destinataires").Range("A1:A55")
 
For i = 1 To 55
    If Not IsEmpty(vDestinataire(i, 1)) Then sDestinataire = sDestinataire & ";" & vDestinataire(i, 1)
Next i
 
If sDestinataire <> vbNullString Then
    sDestinataire = Mid$(sDestinataire, 2)
    '...
 
    With ActiveSheet.MailEnvelope
        .Item.To = sDestinataire
        '...
    End With
End If
 
'...
 
End Sub

La boucle For... Next sert à créer à créer la chaîne de caractères à partir de la liste des adresses. On ne peut pas utiliser Join car même si tu n'as qu'une colonne, une plage a toujours 2 dimensions, et vDestinataire aussi.

Cordialement,

PGZ

[Daniel.C]

Bonjour,

En complément, tu peux utiliser ".Item.Recipients.Add" au lieu de ".Item.To" :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Dim C As Range
With ActiveSheet.MailEnvelope
    For Each C In Sheets("Destinataires").Range("A1:A55")
        If C.Value <> "" Then .Item.Recipients.Add C.Value
    Next C
'...

[auracle68]

Merci a vous 2 pour votre aide précieuse. Merci encore