Discussion :

[ldubs]

Bonjour à tous,

Je suis confronté à un petit souci, et je me demandais s'il existait une solution simple en VBA:

Prenons en exemple un tableau de 20 lignes et plusieurs colonnes, dont la première colonne est composé des valeurs "ok" ou "ko". Je souhaite mettre en place un code permettant de supprimer toutes les lignes dont la 1ère colonne a la valeur "ko".

Pour cela, j'ai écrit le code suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
i = 20
Do While i <> 1
   If Range("A!" & i) = "no" Then
      Rows(i).Delete
   End If
    i = i - 1
Loop

En effet, je suis obligé de décrémenter car en incrémentant, cela sauterait des lignes. (si par exemple la ligne 3 comporte "ko" ; elle est effacée donc la ligne 4 devient 3 ; la macro passe à la ligne 4 et saute donc une valeur).
Cela fonctionne parfaitement ; néanmoins, dans le but d'optimiser la macro et la rendre plus rapide (les fichiers que je travaille comportement des milliers de lignes), j'aurais souhaité utiliser la fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
For Each Cell in Range("A:A")
   If Cell.Value = "ko" Then
      Cell.Rows.Delete
   End If
Next Cell

Le souci est que dans ce cas précis, on incrémente et des lignes sont donc sautés. Y a-t-il un moyen de résoudre ce souci?

Merci par avance,

[Philippe Tulliez]

Bonjour,
Tu peux utiliser un filtre simple ou élaboré et ensuite supprimer les lignes visibles.
Attention qu'en supprimant les cellules visibles tu supprimeras la ligne 1 contenant les étiquettes de colonnes. Donc il y aurait lieu d'utiliser la plage des cellules visibles en utilisant les propriétés Offset et Resize de l'objet Range.

[ldubs]

Bonjour Philippe,

Je te remercie beaucoup pour cette réponse rapide.

Je n'ai jamais utilisé de filtres dans mes macros. Quelle forme cela pourrait-il prendre? Pourrais-tu me donner un exemple de code?

[Philippe Tulliez]

Bonjour,
Exemple d'une procédure supprimant les lignes contenant en colonne I, le mot Appartement d'une liste de données dont la première cellule est en A1 et se trouve dans une feuille nommée [db] du classeur où se trouve le code VBA.
La première ligne de cette liste contient les étiquettes de colonnes.
La méthode utilisée pour filtrer les données est AdvancedFilter (Filtre avancés) et le filtre est un critère calculé et sa formule est

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=I2="Appartement"

Pour en savoir plus sur Les filtres avancés ou élaborés dans Excel
Code de la procédure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub RemoveFilteredRows()
 Dim rng As Range, rngVisible As Range, rngCriteria As Range
 Set rng = ThisWorkbook.Worksheets("db").Range("A1").CurrentRegion
 Set rngCriteria = rng.Offset(columnoffset:=rng.Columns.Count).Resize(2, 1) ' Zone des critères
 ' Insertion des critères
 With rngCriteria: .Item(1) = "fn": .Item(2) = "=I2=""Appartement""": End With
 ' Filtre avancé
 rng.AdvancedFilter xlFilterInPlace, rngCriteria
 ' Sélection des cellules visibles
 With rng
  Set rngVisible = .Offset(1).Resize(.Rows.Count - 1).SpecialCells(xlCellTypeVisible)
 End With
 rngVisible.EntireRow.Delete ' Supprime les lignes entières visibles
 rng.Worksheet.ShowAllData ' Affiche les données
 rngCriteria.Clear ' Supprime les critères
 Set rng = Nothing: Set rngCriteria = Nothing
End Sub

[ldubs]

Merci beaucoup ! Je vais me plonger dans cette question demain, et reviendrai sur le forum pour confirmer que ca a marché et clôre le sujet

[Philippe Tulliez]

Bonjour,
J'ai corrigé la dernière ligne de la fonction qui posait un problème (il manquait l'instruction Set) et j'ai également allégé la ligne d'attribution de la plage de la variable objet rngVisible
La correction est faite dans ma réponse précédente