Discussion :

[Invité]

Bonsoir,

une textbox doit recevoir un code (1lettre+10chiffres), mais je voudrai que cette textbox garde le focus si le code est erroné.

Je me suis inspiré d'un code de Mercatog (que je salue chaleureusement), j'arrive à avoir le message mais le focus passe à la textbox suivante.

SVP, une aide salutaire. Merci.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
 
Private Sub TextBox11_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
Select Case Len(Me.TextBox11.Value)
Case 0  '1er caractere*
If (KeyAscii < 65 Or KeyAscii > 90) And (KeyAscii < 97 Or KeyAscii > 122) Then KeyAscii = 8: beep
Case 1 To 9 'cas 9 caractères
If KeyAscii < 48 Or KeyAscii > 57 Then KeyAscii = 8: beep
End Select
End Sub
 
Private Sub TextBox11_Exit(ByVal Cancel As MSForms.ReturnBoolean)
If TextBox11 <> "" Then
If Len(Me.TextBox11.Value) < 10 Then
Cancel = False
TextBox11 = ""
TextBox11.SetFocus
MsgBox "code erroné"
End If
End If

[casefayere]

Bonsoir,

tu peux contourner le problème, si ta textbox suivante se nomme, par exemple "TextBox12", tu lui donnes le code, évenement "Enter"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub TextBox12_Enter()
If TextBox11 <> "" Then
  If Len(Me.TextBox11.Value) < 10 Then
    TextBox11 = ""
    MsgBox "code erroné"
    TextBox11.SetFocus
  End If
End If
 
End Sub

[Invité]

Bonsoir,
Par définition exit veux dire sortir on peut pas faire un focus sur la perte de focus!

Faits ton test sur le bouton validé.

Comme je dis souvent ce que saisi l'utilisateur ce n'est pas ton problème mais si tu laisses valider ca devient ton problème!

[Invité]

Bonsoir,

Je vous remercie pour le retour et vos conseils.

@casefayere: merci, c'est une bonne astuce de contournement mais ça donne le même résultat qu'avec mon code initial. Avec le tien le focus passe à la dernière textbox, la 13.

@rdurupt: passer par un bouton de validation, je suis d'accord avec toi. Sauf que le dernier utilisateur c'est moi-même.
C'est juste pour apprendre et d'après ce que j'ai lu sur ce forum, il parait qu'on pouvait pratiquement tout faire en vba.
Je découvre aussi qu'il faut avoir une bonne base théorique et pratique pour être efficace.

Tout novice que je suis, pour moi normalement je mets textbox1.setfocus et le focus se met dans cette textbox et non une autre. Pourquoi?

Je me prends peut-être le tête pour si peu, mais je voudrais comprendre le "pourquoi" et le "comment".

[casefayere]

essaies comme ça

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
If TextBox11 <> "" Then
  If Len(Me.TextBox11.Value) < 10 Then
    TextBox11 = ""
    MsgBox "code erroné"
    TextBox11.SetFocus
    Cancel = True'c'est true et non false
  End If
End If

Et il est même inutile de mettre cette ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

TextBox11.SetFocus

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
If TextBox11 <> "" Then
  If Len(Me.TextBox11.Value) < 10 Then
    TextBox11 = ""
    MsgBox "code erroné"
    Cancel = True'c'est true et non false
  End If
End If

[Invité]

Re,

je te remercie. j'ai essayé tes 2 propositions sans succès

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Private Sub TextBox12_Enter() 'test 1
If TextBox11 <> "" Then
  If Len(Me.TextBox11.Value) < 10 Then
    TextBox11 = ""
    MsgBox "code erroné"
    TextBox11.SetFocus
    cancel = True 'c'est true et non false
  End If
End If
End Sub
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Private Sub TextBox11_Exit(ByVal Cancel As MSForms.ReturnBoolean) 'test 2
If TextBox11 <> "" Then
  If Len(Me.TextBox11.Value) < 10 Then
    TextBox11 = ""
    MsgBox "code erroné"
    TextBox11.SetFocus
    cancel = True 'c'est true et non false
  End If
End If
End Sub
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Private Sub TextBox11_Exit(ByVal Cancel As MSForms.ReturnBoolean) 'test 3
If TextBox11 <> "" Then
  If Len(Me.TextBox11.Value) < 10 Then
    TextBox11 = ""
    MsgBox "code erroné"
    cancel = True 'c'est true et non false
  End If
End If
End Sub

[casefayere]

et pourtant, j'ai testé sur un Usf simple avec 3 textbox et le focus est bien repris par le TextBox11. Don je suis surpris, lis ceci http://silkyroad.developpez.com/VBA/...serForm/#LII-E avec ce code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub TextBox1_Exit(ByVal Cancel As MSForms.ReturnBoolean) 
	If TextBox1.Value = "" Then Cancel = True 
End Sub

et avec cet évènement

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub TextBox11_BeforeUpdate(ByVal Cancel As MSForms.ReturnBoolean)
If TextBox11 <> "" Then
  If Len(Me.TextBox11.Value) < 10 Then
    TextBox11 = ""
    MsgBox "code erroné"
    Cancel = True
  End If
End If
 
End Sub

[Invité]

Re,

je te remercie infiniment. J'ai téléchargé il y a un bon bout de temps le document en pdf. je les ai tous.

je viens de tester et c'est niet. je n'y comprends rien de rien. Bon pour ce soir, je jette l'éponge, je suis trop fatigué.

Bonne fin de soirée.

[kiki29]

Salut, plus à titre documentaire qu'autre chose voir ici

[Invité]

Bonjour,

Kiki29 merci beaucoup pour le lien. je m'y mets de suite, ça m’intéresse.

Bon week-end à tous!

[Invité]

Bonjour, Bonjour,

Après une lecture matinale du fil que Kiki29 m'a proposé. J'ai testé le code d'Ucfoutu et celui de Maxime Hubiche (j'ai testé sur un nouveau classeur), ça fonctionne bien. Les 2 exemples traitent des numériques uniquement, dans mon cas c'est code Alpha-Numérique.

Dans la continuité de ce fil , pour ajouter une machine je clique sur un bouton radio, cette action vide les 13 textboxs et met le focus sur la textbox1 pour saisir le n° machine. Pour la textbox13, elle reçoit un code interne (1 lettre au début suivi de 9 chiffre sans espace (ex:F123456789)). J'ai mis 10 pour la propriété MaxLength pour limiter la saisie. Maintenant, le problème est le cas où le nombre de caractères est inférieur à 10, je voudrais que la textbox garde le focus et un message signale que le code est erroné.

Pour le format, c'est bon les tests sont concluant. Le gros c'est le focus.

[clementmarcotte]

bonjour,

Bonjour, Bonjour,


Pour le format, c'est bon les tests sont concluant. Le gros c'est le focus.

Ouvre ton aide de VBA et cherche SetFocus. Il y a même des exemples.

Bien souvent un petit effort de recherche dans l'aide, c'est plus rapide que le forum.

Et puis, l'intellisence t'aurait probablement aiguillé sur SetFocus

Et c'est la même chose pour un banal clic sue TextBox et

Quand je pense que l'on perd 3 éternités à s'énerver qu'il n'y pas encore de réponse sur le forum et que 2 ou 3 actions élémentaires avec l'aide intégrée auraient donné la solution en un tournemain, cela me décourage.

En passant, une bonne résolution pour le Jour de l'An : Je vais utiliser l'aide plus souvent.

[Invité]

Bonsoir Clementmarcotte,

En fait, l'aide c'est par là que j'ai commencé et je ne suis pas parvenu à comprendre pourquoi ça ne fonctionnait pas.

J'ai poursuivi mes recherches et tests. J'ai une solution

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub TextBox11_Exit(ByVal Cancel As MSForms.ReturnBoolean)
    If Len(TextBox11) < 10 Then
        MsgBox "code erroné"
        SendKeys "+{TAB}", False   'TextBox11.SetFocus ne fonctionne pas, le focus passe à textbox12
    End If
End Sub

Meilleurs vœux par anticipation.

[mercatog]

Cathodique bonjour

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Private Sub TextBox11_KeyPress(ByVal KeyAscii As MSForms.ReturnInteger)
 
Select Case Me.TextBox11.SelStart
Case 0                                                '1er caractere*
    If (KeyAscii < 65 Or KeyAscii > 90) And (KeyAscii < 97 Or KeyAscii > 122) Then KeyAscii = 0: Beep
Case 1 To 9                                           'cas 9 caractères
    If KeyAscii < 48 Or KeyAscii > 57 Then KeyAscii = 0: Beep
End Select
End Sub
 
Private Sub TextBox11_Exit(ByVal Cancel As MSForms.ReturnBoolean)
 
If Len(Me.TextBox11.Value) < 10 Then
    Cancel = True
    MsgBox "Code Erroné"
End If
End Sub

Cancel à True permet d'annuler l'Exit

PS. remarque le changement dans le KeyPress

[Invité]

Bonsoir Mercatog,

C'est avec un réel plaisir que je lis tes interventions. Comme à l'accoutumée, très efficace, ton code répond exactement à mes attentes.

Tous mes remerciements. Je ne rate pas l'occasion de te présenter, bien qu'ils un tout petit peu en avances, mes meilleurs vœux.

Cordialement,

Cathodique