Discussion :

[nickistudent]

Bonjour à tous!
J'aimerais calculer la proportion de chaque tranche d'âges dans un graphique "camembert". J'ai calculé mes données en VBA (ça, ça marche) et maintenant j'aimerais créer mon graphique à partir de celles-ci. Mais impossible d'y arriver, j'ai un message d'erreur "incompatibilité de type" qui apparaît.
Je l'ai fait en utilisant les graphiques Excel, là pas de souci mais vu que c'est un travail scolaire il faut absolument que toutes mes données soient programmées en VBA.
(mon graphique n'est pas obligé d'être en 3D tant que c'est un graphe "camembert")
Merci à vous!

[Daniel.C]

Bonjour,

Essaie et adapte :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub GraphiqueAge()
    ActiveSheet.Shapes.AddChart
    With ActiveSheet.ChartObjects(1).Chart
        .ChartType = xl3DPie
        .SeriesCollection.NewSeries
        With .SeriesCollection(1)
            .HasDataLabels = True
            .Values = Range("M1:M5").Value
            Var = .Values
            For i = 1 To UBound(Var)
                If Var(i) <> 0 Then .Points(i).DataLabel.Text = [N1].Offset(i - 1)
            Next i
        End With
    End With
End Sub

[nickistudent]

Merci beaucoup ça marche!
Je ne sais pas si vous savez comment introduire une légende sur le côté pour chaque secteur.. Pour le moment j'ai 1;2;3;4;5 et il me faudrait chacune des tranches d'âge
J'ai regardé sur le forum mais pas moyen de trouver comment définir le texte
Bonne journée

[Daniel.C]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub GraphiqueAge()
    Dim I As Integer, Var As Variant
    ActiveSheet.Shapes.AddChart
    With ActiveSheet.ChartObjects(1).Chart
        .ChartType = xl3DPie
        .SeriesCollection.NewSeries
        With .SeriesCollection(1)
            .HasDataLabels = True
            .Values = Range("M1:M5").Value
            Var = .Values
            .XValues = "=Feuil2!$N$1:$N$5"
            For I = 1 To UBound(Var)
                If Var(I) <> 0 Then
                    .Points(I).DataLabel.Text = [N1].Offset(I - 1)
 
                End If
            Next I
        End With
    End With
End Sub

[nickistudent]

Merci infiniment de votre aide! Ca ne fonctionnait pas totalement au début mais en chipotant légèrement ç'est nickel!
Bonne journée,
(Je mets le code ci-dessous au cas où ça peut servir à quelqu'un

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
Sub GraphiqueAge()
    'Ajout du graphique
    ActiveSheet.Shapes.AddChart
    'Spécification des détails du graphe (type,nouvelle série, titre, présence d'une légende)
    With ActiveSheet.ChartObjects(1).Chart
        .ChartType = xl3DPie
        .SeriesCollection.NewSeries
        .HasTitle = True
        .ChartTitle.Characters.Text = "Proportion des tranches d'âges des conducteurs"
        .HasLegend = True
        With .SeriesCollection(1)
            'présence d'étiquette des données
            .HasDataLabels = True
            'Valeurs de l'axe Y
            .Values = Range("M1:M5").Value
            'Valeurs de l'axe X
            .XValues = Range("N1:N5").Value
             Var = .Values
            'Boucle For qui va poser les valeur de y dans chaque secteur
            For i = 1 To UBound(Var)
                If Var(i) <> 0 Then .Points(i).DataLabel.Text = [M1].Offset(i - 1)
            Next i
        End With
    End With
End Sub