Discussion :

[facteur]

Bonjour,
j'ai une tableau excel de 5 colonnes :
la colonne A intitulée Étiquettes de lignes : contient des dates format jj/mm/aaaa hh:mm
Les colonnes B à E contient des chiffres
la colonnes B intitulée LRD
la colonne C intitulée RJT
la colonne D intitulé TG1
la colonne E intitulée TG2

Je souhaiterais créer un petit code VBA qui permettrait de recuperer les données de la colonne D TG1 à partir de 03h00 ( c'est à dire jj/mm/aaaa 03:00)

Dans l'exemple du fichier test joint:le code vba m'afficherait la somme 3485 qui correspondrait à la somme de la cellule D25=3435 et D26=50
D25 et D26 correspondent bien à la valeur des cellules TG1 aprés 03:00


merci d'avance.

[Invité]

Bonjour,

Il doit sans doute manquer quelque chose dans vos conditions. Il y a beaucoup plus de lignes qui répondent à votre condition.

Vous pouvez récupérer les valeurs avec la fonction Heure :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(HEURE(A25)>=3;D25;0)

Cordialement.

[facteur]

Bonjour Erik
Merci pour ta réponse mais celle_ci ne correspond pas à mes attentes
En effet , le tableau n'est pas figé, d'une journée à l'autre les données recherchées ne se retrouveront pas à la même ligne.
Voici ce que j'ai pu faire..Ce n'est qu'un début :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub Position()
    Dim Cell As Range
    Range("A2").Select
    LigDeb = ActiveCell.Row
    LigFin = Range("A1").End(xlDown).Row
    
    
    
    For Each Cell In Range("A" & LigDeb & ":E" & LigFin)
        If Cell.Value = "contient 03:00" Then
            Cell.Select
            Exit For
        End If
    Next Cell
End Sub

Mon soucis se trouve à la ligne 11. je ne sais pas comment s'ecrit le code vba : ma cellule contient 03:00

[Invité]

Mon soucis se trouve à la ligne 11. je ne sais pas comment s'ecrit le code vba : ma cellule contient 03:00

Une proposition :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Sub Position()
 
Dim FeuilleCalcul As Worksheet
Dim AireCalcul As Range
Dim Cellule As Range
Dim LigneDeTitre As Long
Dim LigneFin As Long
Dim DerniereColonne As Long
 
'Dim TotalTG1 As Long
 
    'TotalTG1 = 0
 
    Set FeuilleCalcul = Sheets("Feuil1") ' A adapter
    With FeuilleCalcul
        LigneDeTitre = 1
        DerniereColonne = .Cells(LigneDeTitre, .Columns.Count).End(xlToLeft).Column
        LigneFin = .Cells(.Rows.Count, 1).End(xlUp).Row
 
        Set AireCalcul = .Range(.Cells(LigneDeTitre + 1, 1), .Cells(LigneFin, 1))
 
        For Each Cellule In AireCalcul
            If Hour(Cellule) >= 3 Then
               ' TotalTG1 = TotalTG1 + Cellule.Offset(0, 3)
                Cellule.Offset(0, DerniereColonne) = Cellule.Offset(0, 3)
            End If
        Next Cellule
        .Cells(1, DerniereColonne + 1).FormulaR1C1 = "=SUM(R[1]C:R[" & AireCalcul.Rows.Count & "]C)"
        Set AireCalcul = Nothing
 
    End With
 
   ' MsgBox TotalTG1
    Set FeuilleCalcul = Nothing
 
End Sub

Cordialement.

[facteur]

Bojour Erik,
Ton code fonctionne a merveille.mais effectivemet, lorsque tu as ecris :

Il doit sans doute manquer quelque chose dans vos conditions. Il y a beaucoup plus de lignes qui répondent à votre condition.

je me suis mal exprimer. Je souhaite recuperer les donnees superieur a 03h00 J+1.
Dans l exemple du tableau ci joint, les donnees a recuperer sont ceux superieur a la date du 24/09/2014 03:00

[facteur]

Bonjour Erik,
Je commence à avancer dans la réalisation de ce code et ce grace a toi..
Enfin de continuer dans ce code, comment pourrais je trouver un code qui me donnerait la cellule qui contient la date avec l'heure 03:00.
Si on reprend le tableau , le code me donnerait la valeur de la cellule A25 c 'est à dire 24/09/2014 03:00

[Invité]

Bonjour,

Essayez ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
Sub PositionV2()
 
Dim FeuilleCalcul As Worksheet
 
Dim AireCalcul As Range
Dim CelluleDateEnCours As Range
Dim CelluleDateJPlusUn As Range
 
Dim JourJPlusUn As Date
Dim JourTraite As Date
 
Dim LigneDeTitre As Long
Dim LigneFin As Long
Dim DerniereColonne As Long
 
    JourTraite = 0
    Set FeuilleCalcul = Sheets("Feuil1") ' A adapter
    With FeuilleCalcul
        LigneDeTitre = 1
        DerniereColonne = .Cells(LigneDeTitre, .Columns.Count).End(xlToLeft).Column
        LigneFin = .Cells(.Rows.Count, 1).End(xlUp).Row
 
        Set AireCalcul = .Range(.Cells(LigneDeTitre + 1, 1), .Cells(LigneFin, 1))
 
        For Each CelluleDateEnCours In AireCalcul
 
            JourJPlusUn = CDate(Fix(CelluleDateEnCours)) + 1
            For Each CelluleDateJPlusUn In AireCalcul
                 If Hour(CelluleDateJPlusUn) >= 3 And CDate(Fix(CelluleDateJPlusUn)) = JourJPlusUn And CDate(Fix(CelluleDateEnCours)) > JourTraite Then
                     CelluleDateJPlusUn.Offset(0, DerniereColonne) = CelluleDateJPlusUn.Offset(0, 3)
                 End If
            Next CelluleDateJPlusUn
            JourTraite = CDate(Fix(CelluleDateEnCours))
 
        Next CelluleDateEnCours
 
        .Cells(1, DerniereColonne + 1).FormulaR1C1 = "=SUM(R[1]C:R[" & AireCalcul.Rows.Count & "]C)"
        Set AireCalcul = Nothing
 
    End With
 
    Set FeuilleCalcul = Nothing
 
End Sub

Il faut une deuxième boucle pour détecter les cas à J+1.
Il ne faut pas qu'une autre valeur du même jour incrémente le compteur, d'où la variable JourTraite qui prend la valeur du jour à la fin de la deuxième boucle.

Cordialement.

[facteur]

Bonjour Erik
Je te dirais simplement
Merci encore pour ta patience