Discussion :

[alain1949]

Bonjour à tous

utilisant une version adobe 10 j'ai récupéré le code suivant pour ouvrir un fichier PDF et cela fonctionnait parfaitement.

En installant mon fichier excel avec une version adobe 11.0, Adobe s'ouvre bien mais j'ai un message d'erreur "Fichier Introuvable".

En regardant sur le Web il semblerait que les codes en version 11 ne correspondent plus avec une version 10.

Quelqu'un peut il m'aider

Merci d'avance

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Private Sub Label100_Click()
'---- Déclaration des var
Dim WshShell As Object, PDFExec As Object
Dim CheminReader As String, CheminPDF As String
Dim numPage As String
'---- Indiquer le Numéro de page à rechercher
    numPage = 1
'---- Ouverture du fichier PDF
    CheminReader = Feuil7.Cells(1, 20) ' c:\program files (X86)\Adobe\Reader 10.0\Reader\acroRd32.exe  modifier Reader 11.0
    CheminPDF = Feuil7.Cells(2, 20) ' c:\gestion MVT\Gestion des Mouvements manuel utilisateur.pdf
    Set WshShell = CreateObject("WScript.Shell")
    Set PDFExec = WshShell.Exec(CheminReader & " /a page=" & numPage & "=OpenActions " & CheminPDF) ' fonctionne avec version 10 mais pas en V11 
    Set PDFExec = Nothing
    Set WshShell = Nothing
End Sub

[kiki29]

Salut, pour W7 et le Reader 11 : "C:\Program Files (x86)\Adobe\Reader 11.0\Reader\AcroRd32.exe"

Sinon via la base de registre : voir ici.

[alain1949]

Merci KyKy 29

pour avoir pris le temps de répondre.

Mais!!!! le problème n'est pas le chemin d'accès pour Reader, car il ouvre correctement Adobe , (voir commentaire sur ma ligne prog) mais l'ouverture du fichier PDF ou adobe affiche ' Msg Fichier introuvable'.

Je vais essayé d'autre solution.

Donc problème toujours en attente de résolution

[kiki29]

Re, à quoi ressemble la chaine dans

CheminPDF = Feuil7.Cells(2, 20)

?

[kiki29]

Re, que donne ceci ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
Option Explicit
 
Sub SelectionFichier()
Dim Fichier As Variant
    ChDir ThisWorkbook.Path & "\"
 
    Fichier = Application.GetOpenFilename("Fichier PDF (*.pdf), *.pdf")
    If Fichier <> False Then OuvrirPDF Fichier, 3 'Feuil1.Range("NumPage")
 
End Sub
 
Private Sub OuvrirPDF(ByVal sFichier As String, iNumPage As Long)
Dim WshShell As Object
Dim sCheminReader As String
    sCheminReader = LocaliserAcroReader
 
    If ExistenceFichier(sCheminReader) = False Then
        MsgBox "Le chemin d'Acrobat Reader est erroné ou" & vbCrLf & "Acrobat Reader n'est pas installé"
        Exit Sub
    End If
 
    Set WshShell = CreateObject("WScript.Shell")
    WshShell.Exec sCheminReader & " /a page=" & iNumPage & "=OpenActions " & sFichier
    Set WshShell = Nothing
End Sub
 
Private Function LocaliserAcroReader() As String
Dim FSO As Object
Dim Wsh As Object
Dim sCheminReader As String
 
    Set FSO = CreateObject("Scripting.FileSystemObject")
    Set Wsh = CreateObject("WScript.Shell")
 
    sCheminReader = Wsh.RegRead("HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths\AcroRd32.exe\")
 
    If Not IsNull(FSO.GetAbsolutePathName(sCheminReader)) Then
        LocaliserAcroReader = FSO.GetAbsolutePathName(sCheminReader)
    Else
        LocaliserAcroReader = ""
    End If
 
    Set Wsh = Nothing
    Set FSO = Nothing
End Function
 
Private Function ExistenceFichier(sFichier As String) As Boolean
    ExistenceFichier = Dir$(sFichier) <> ""
End Function