Discussion :

[bol45]

Bonjour à tous,

Je ne suis pas parvenu à faire ce que je souhaitais en code SAS.

En regardant l'illustration ci-dessous, je voudrais, pour chaque ligne où first_date est vide, remplacer ce vide par la dernière valeur connue de first_date.
Ainsi, je voudrais remplacer les 3 première cellules vides par la date 21 décembre 2012 et les 3 dernières celulles vides par la date du 09 janvier 2013.



J'ai essayé de faire ça avec un RETAIN et un LAG mais je n'y suis pas parvenu.
Avez-vous une idée de la manière dont je pourrais procéder ?

Merci d'avance.

Cordialement.

[m.brahim]

Bonjour,

je te propose cette solution:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
data exemple ;
input id date ddmmyy8.  ;
format date ddmmyy8. ;
cards ;
1 25/01/14
1 25/01/14
1 .
1 .
1 .
2 16/01/14
2 16/01/14
2 .
2 .
2 .
2 .
3 17/01/14
3 .
3 17/01/14
3 .
run ;
 
data exemple1 (drop=temp lag_date);
format lag_date ddmmyy8.;
set exemple;
retain temp;
by id;
lag_date=lag(date);
if date =. and lag_date ne . then temp=lag_date;
if date=. then date=temp;
run;

Cordialement

[RemiBousquet]

Je me demande si tu ne te compliques pas la vie en utilisant conjointement du "lag" et du "retain".
Voici une solution uniquement basée sur le retain, où je remplace date par date_retain (qu'on pourrait renommer en date si besoin)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
data exemple1 (drop = date);   
    format date_retain ddmmyy8. ;
    set exemple ;
    by id ;         
    retain date_retain ;
    if not missing(date) then date_retain = date ;
run ;

[hossward]

Une solution plus courte avec UPDATE :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 
data exemple;
infile datalines;
input GMT_Offset$  first_date ddmmyy10.;
format first_date ddmmyy10.;
datalines;
+0 21/12/2012
+0 21/12/2012
+0 21/12/2012
+0 21/12/2012
+0 .		 
+0 .		 
+0 .		 
+0 .		 
-5 09/01/2013
-5 09/01/2013
-5 09/01/2013
-5 09/01/2013
-5 .		 
-5 .		 
-5 .		 
-5 .		 
;	
 
data exemple_1;
   update exemple (obs=0) exemple ;
   by GMT_Offset;
   output;
run;

Cordialement
Ward

[bol45]

Merci pour vos réponses, ça répond à mon besoin

Bonne journée à tous.