Discussion :

[la perdue]

bonjour a tous,

depuis plusieurs jours j essaye de résoudre un casse tête (pour moi), je voulais savoir comment afficher des données dans une listbox suivant la valeur d'une cellule,
c'est a dire par exemple : si j ai "oui" dans la cellule I9 ,a l ouverture de l'USF cela m affiche les données de la ligne 9 .

j'ai réussi avec des textbox (non sans mal..),mais une listbox c est une autre histoire....

pouvais vous m aidez s il vous plait , merci.

je vous joint un "morceau" de mon fichier

[Philippe Tulliez]

Bonjour,
La méthode AddItem après une structure décisionnelle comme If ou Select Case permet d'alimenter une liste dans un contrôle ListBox ou ComboBox suivant conditions.

Voir un cas similaire dans cette réponse. Il y a tout l'explication ainsi qu'un classeur de démonstration à télécharger.

[la perdue]

merci de votre attention

j avais déjà vu ce post ,mais je n arrive pas a l adapter pour mon fichier.....

je ne sais pas comment faire ....

merci

[Philippe Tulliez]

Bonjour,

j avais déjà vu ce post ,mais je n arrive pas a l adapter pour mon fichier.....
je ne sais pas comment faire ....

Quel est le problème ?
L'utilisation de la méthode AddItem du contrôle ListBox ?
Je te conseille la lecture du chapitre II-G. ListBox du tutoriel Utiliser les contrôles dans un UserForm, en VBA Excel

[la perdue]

voici ce que j essaye de faire mais rien ne s affiche dans la listbox

pouvez vous m aider sil vous plait?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Option Explicit
 
Dim rng As Range
Private Sub UserForm1_Initialize()
 'Set rng = ActiveSheet.Range("A1").CurrentRegion
 ' Redimensionnement de la plage des données pour ne pas prendre en compte la première ligne
 With rng:  Set rng = .Offset(1).Resize(.Rows.Count - 1): End With
 
 ' Initialisation des contrôles
 
 InitlstWithAddItem "oui" ' Initialisation lstWithAddItem avec filtre sur les donées du groupe oui
End Sub
 
Sub InitlstWithAddItem(Filtre As String)
 ' Initialisation de la liste des données de ListBox dépendant de l'argument Filtre
 Dim r As Long, c As Integer
 With lstWithAddItem
 .ColumnCount = 6: .ColumnWidths = "20;50;60;13;13;15"
  For r = 1 To rng.Rows.Count
   If rng.Cells(r, 7) = Filtre Then
      .AddItem r ' 1er élément de la liste = N° de igne de la liste des données
      For c = 2 To rng.Columns.Count
      .List(.ListCount - 1, c - 1) = rng.Cells(r, c)
      Next c
   End If
  Next r
 End With
End Sub

merci de votre aide

[Philippe Tulliez]

Bonjour,
J'ai adapté la procédure que j'avais écrite pour le test.
C'est maintenant une fonction qui renvoie False si LabelName n'est pas trouvé. Idéalement il faudrait contrôler d'autres choses dans la fonction mais c'est une procédure de test
Ce qui est en rouge dans le code doit être vérifié et éventuellement corrigé (le nom du contrôle ici ListBox1 et les valeurs de la propriété ColumnWidths du même contrôle.
La variable objet rng, présente dans cette procédure est une variable objet qui doit être déclarée en tête de module du UserForm

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim rng As Range

Procédure Function : Elle a deux arguments à lui passer. Filtre (dans l'exemple "oui") et LableName qui est le nom de l'étiquette de colonnes (dans l'exemple Affichage)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Private Function InitlstWithAddItem(Filtre As String, LabelName As String) As Boolean
 ' Arguments
 ' Filtre : la chaîne critère
 ' LabelName : Nom de l'étiquette de colonne à filtrer
 ' Initialisation de la liste des données de ListBox dépendant de l'argument Filtre
 ' La fonction renvoie une valeur Booléenne si False il y a un problème
 InitlstWithAddItem = True
 Dim r As Long, c As Integer, NumCol As Integer
 With rng
  On Error Resume Next
  NumCol = Application.Match(LabelName, .Rows(1).Cells, 0)
  If Err.Number Then InitlstWithAddItem = False: Exit Function
  On Error GoTo 0
 End With
 With Me.ListBox1 ' Nom du contrôle ListBox
 .ColumnCount = rng.Columns.Count: .ColumnWidths = "20;50;60;13;13;15"
  For r = 1 To rng.Rows.Count
   If rng.Cells(r, NumCol) = Filtre Then
      .AddItem r ' 1er élément de la liste = N° de ligne de la liste des données
      For c = 2 To rng.Columns.Count
      .List(.ListCount - 1, c - 1) = rng.Cells(r, c)
      Next c
   End If
  Next r
 End With
End Function

Code de la procédure appelante (ce qui est en rouge doit être éventuellement modifié : Le nom de la feuille (ici Feuil1), l'adresse de la première cellule de la liste (ici A1)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Private Sub UserForm_Initialize()
 Set rng = ThisWorkbook.Worksheets("Feuil1").Range("A1").CurrentRegion
 If InitlstWithAddItem("oui", "affichage") = False Then
  MsgBox "Problème d'alimentation ListBox"
  Set rng = Nothing:  Exit Sub
 End If
 Set rng = Nothing
End Sub

[la perdue]

merci de votre aide

j ai donc fait quelque ajustement pour convenir a mes besoins, mais j ai un petit souci je n'arrive pas a avoir le nom de mes étiquettes (je sais qu' il faut utiliser ".ColumnHeads = True " mais ou le placer? et comment?)

[Marc-L]

Bonjour,

impossible avec la technique employée, uniquement en alimentant la ListBox via sa propriété RowSource …




__________________________________________________________________________________________________
Tous unis, tous Charlie

[Philippe Tulliez]

Bonjour,

j ai donc fait quelque ajustement pour convenir a mes besoins, mais j ai un petit souci je n'arrive pas a avoir le nom de mes étiquettes (je sais qu' il faut utiliser ".ColumnHeads = True " mais ou le placer? et comment?)

Comme l'a précisé Marc que je salue au passage, la propriété ColumnHeads des contrôles ListBox et ComboBox n'est active qu'en combinaison avec la propriété RowSource ce qui dans ton cas n'est pas possible puisqu'en souhaitant n'afficher que certaines lignes de la liste des données on est obligé d'utiliser la méthode AddItem.
Cela est illustré d'ailleurs dans le classeur exemple qui se trouve dans le lien que je t'ai donné dans ma première réponse.

[la perdue]

merci de votre aide

j ai trouvé une autre solution

[Philippe Tulliez]

Bonjour,

merci de votre aide
j ai trouvé une autre solution

Un forum est en principe un endroit où l'on partage. Je suis convaincu que la solution que tu as trouvée pourrait en intéresser plus d'un

[la perdue]

bonjour
oui tu as raison et j'en suis désolée

en fait pour palier a mon problème d'en-tête, j'ai tout simplement mis des labels avec le nom des colonnes.