Discussion :

[yassine0077]

Bonjour tout le monde,

La lecture du forum m'a aidé plein de fois, mais malheureusement je n'ai pas pu trouver une solution à mon problème

Mon code sert à sélectionner les lignes d'un tableau suivant une condition sur une cellule. (Le but est de supprimer l'ensemble des lignes sélectionnées en une seule fois)
Tout fonctionne correctement sauf qu'il me sélectionne systématiquement la ligne 2 de mon tableau que la condition soit remplie ou non.
Pouvez-vous jeter un coup d’œil sur mon code?

Merci par avance


Voici le code:
Exemple.xlsm

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
Function DCInventoryDel()
 Sheets("DCInventory").Activate
 Dim z As Range, cel As Range
 Set z = [DCInventoryTable].Columns(19).Find("*", LookIn:=xlValues)
 If z Is Nothing Then Exit Function
 For Each cel In [DCInventoryTable].Columns(19).Cells
  If cel.Value = 0 Then Set z = Union(cel, z)
  Next
 Intersect([DCInventoryTable[[Year]:[Handling Cost ($MXN/year)]]], z.EntireRow).Select
 Selection.Delete
End Function

Pièce jointe 168634

[Kimy_Ire]

Bonjour yassine0077,

Je pense que ceci vient du fait que tu n'as pas de valeur en S2.
Donc, voici ce que je te propose :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub DCInventoryDel()
Dim z As Range
Dim Rng_suppr As Range
Dim i As Integer
 
With Worksheets("Feuil3")
    Set z = .Range("S1")
    Set Rng_suppr = Nothing
    For i = 2 To .Columns(19).Find("*", , , , , xlPrevious).Row - 2
        If z.Offset(i, 0) = 0 Then
            If Not Rng_suppr Is Nothing Then
                Set Rng_suppr = Union(Rng_suppr, .Range(.Cells(i + 1, 1), .Cells(i + 1, 19)))
            Else
                Set Rng_suppr = .Range(.Cells(i + 1, 1), .Cells(i + 1, 19))
            End If
        End If
    Next i
    Rng_suppr.Delete shift:=xlUp
End With
 
End Sub

Ceci supprime les lignes (de A à S) où tu n'as pas de valeur (ou 0) en colonne S.
C'est ce que j'ai compris de ta macro.
N'hésite pas à revenir vers moi !

Cordialement,
Kimy

[Aposto]

Bonjour a tous,

il y une autre solution avec la méthode autofilter:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Function DCInventoryDel()
 Sheets("DCInventory").Activate
 
ActiveSheet.ListObjects("DCInventoryTable").Range.AutoFilter 'enlève les filtres existants
ActiveSheet.ListObjects("DCInventoryTable").Range.AutoFilter 18, "0,00" ' filtre la colonne S qui contiennent la valeur 0,00
 
'décale la plage pour ne pas prendre la ligne d'entêtes
'reduit la plage d'une ligne pour compenser le décalage
'efface les lignes restantes et qui sont visibles
ActiveSheet.ListObjects("DCInventoryTable").Range.Offset(1). _
Resize(ActiveSheet.ListObjects("DCInventoryTable").Range.Rows.Count - 1). _
SpecialCells(xlCellTypeVisible).Delete
 
'revient à un affichage normal
ActiveSheet.ListObjects("DCInventoryTable").Range.AutoFilter
 
End Function

en espérant que cela puisse s'appliquer à ton code.

[geogeo70]

....qu'il me sélectionne systématiquement la ligne 2 de mon tableau que la condition soit remplie ou non....

Bonjour,

En regardant votre code je vois que vous "unionnez" des cellules en laissant la première de test dans z, voilà pourquoi vous avez une ligne en trop!

Donc en 1er "vider" z puis prendre la 1ere en z et ensuite unir les autres voilà mon code et il fonctionne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub DCInventoryDel()
 Sheets("DCInventory").Activate
 Dim z As Range, cel As Range
 Set z = [DCInventoryTable].Columns(18).Find("*", LookIn:=xlValues)
 If z Is Nothing Then Exit Sub
 Set z = Nothing       'Penser à initialiser la plage
 
 For Each cel In [DCInventoryTable].Columns(18).Cells
    If z Is Nothing Then
        If cel.Value = 0 Then Set z = cel              'Première cellule
                    Else
        If cel.Value = 0 Then Set z = Union(cel, z) 'Cellules suivantes....
    End If
 
Next cel
 Intersect([DCInventoryTable[[Year]:[Average Sales (Ton/year)]]], z.EntireRow).Select
 ' Selection.Delete
 ' Cells(3, 2).Select
End Sub

On aurait pu utiliser d'autres algorithmes...

PS : J'ai oublié de dire que c'est une procédure et non une fonction : une fonction rend une valeur et ne doit normalement pas être utilisée pour les "Effets de bords"!...
a++
Exemplecor.xlsm
geogeo70

[yassine0077]

Super merci les gars, j'ai essayé tous vos algorithmes et ils fonctionnent tous.
Je garde une préférence pour le mien (Bien évidement corrigé) pour la simple raison que je trouve qu'il est beaucoup plus rapide, car j'ai des dizaine de milliers de lignes (m'enfin peut être que je me trompe, je suis un débutant en VBA.
Je prends en compte toutes vos remarques et je vous remercie tous de votre aide. Vous déchirez

[Kimy_Ire]

Bonjour yassine0077,

Dans la signature.

- - - - - - - - - - - -