Discussion :

[celinepug]

Bonjour à tous,

J'espère que vous pourrez m'aider, voici mon problème : j'ai une colonne A d'énoncés et une colonne B de données, il n'y a pas forcément de données dans tous les énoncés, voir ci-dessous :

colonne A colonne B

poires 500
pommes "cellule vide"
carottes 350
patates "cellule vide"
navets "cellule vide"

J'aimerai dans une autre colonne récupérer uniquement les énoncés contenant des valeurs, comme ceci :

Colonne C
poires
carottes

J'ai trouvé une formule pour récupérer la première valeur soit "poires" voilà la formule que j'ai mis dans la première cellule de la colonne C :
=index(A1:A10;equiv(vrai;B1:B10<>"";0)) en formule matricielle

mais je n'arrive pas à l'adapter pour que la ligne suivante récupère la seconde valeur non vide puis la suivante la troisième etc etc ....

si quelqu'un connaît la solution ça m'aiderai bien

Merci de m'aider
Céline

[Promethee25]

Bonjour,

A supposer que tu n'aies pas d'entête de colonne, copie en ligne 1 (ex: en D1):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(INDEX($A$1:$A$10; PETITE.VALEUR(SI(ESTVIDE($B$1:$B$10); 10000000;LIGNE($A$1:$A$10)); LIGNE())); "")

A valider par Ctrl+Maj+Entrée (formule matricielle).

A supposer que tu aies un entête de colonne en D1, copie en D2:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(INDEX($A$1:$A$10; PETITE.VALEUR(SI(ESTVIDE($B$1:$B$10); 10000000;LIGNE($A$1:$A$10)); LIGNE()-LIGNE($D$1))); "")

A valider aussi par Ctrl+Maj+Entrée.

[celinepug]

Bonjour Promethée je te remercie beaucoup pour ta réponse mais ça ne fonctionne pas ça me donne la valeur vide partout (le retour de valeur si erreur) j'ai vérifié plusieurs fois et n'ai pas l'impression d'avoir mal recopié ta formule.....

Celine

[Promethee25]

Bonjour,

Cela fonctionne parfaitement chez moi; j'ai retesté dans un fichier tout neuf.

- As-tu bien validé par Ctrl+Maj+Entrée?
- Si formule copiée en dessous d'un entête, as-tu bien pris la 2ème formule proposée où l'on soustrait la ligne de l'entête?

[celinepug]

Je ne comprends rien, j'ai créé un nouveau fichier et ai copié mon exemple la formule fonctionne très bien, mais sur mon fichier de travail ça ne fonctionne pas, j'ai pourtant copié la formule et juste modifié les plages, comprends rien ..... mystère

[celinepug]

J'ai trouvé, je viens de déplacer mes colonnes sur mon fichier d'exemple et là ça ne fonctionne plus, la formule ne fonctionne que pour une plage au départ de A1, sur mon fichier de travail ce n'est pas le cas, as-tu une idée pour l'adaptation de la formule ?

[Promethee25]

Oui.
A supposer que tu aies des entêtes de colonnes (ou en tout cas que tes données commencent en A2) et que tu copies la 1ère formule en D2:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(INDEX($A$2:$A$11; PETITE.VALEUR(SI(ESTVIDE($B$2:$B$11); 10000000;LIGNE($A$2:$A$11)-LIGNE($A$1)); LIGNE()-LIGNE($D$1))); "")

A adapter selon la position que tu souhaites tant que les données ne commencent pas en ligne 1.

[celinepug]

Merci, merci beaucoup Promethee, j'ai fini par réussir, désolée j'ai été un peu longue !!! voici ce que ça donne sur mon fichier de travail :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(INDEX($O$17:$O$29;PETITE.VALEUR(SI(($Q$17:$Q$29)="";10000000;LIGNE($O$17:$O$29)-LIGNES($O$1:$O$16));LIGNE()-LIGNES($Q$1:$Q$16)));"")

Ma table commençant en "O17" il me fallait une plage de ligne à la place d'une ligne d'en-tête, aussi le "ESTVIDE" ne fonctionne pas s'il y a une formule dans la cellule j'ai donc remplacé par ="".

Encore merci beaucoup c'est trop top

Céline