Fonction pour formater une Textbox (Date)

**JapethTheGoat** · 18/03/2015, 10h38

Bonjour à tous,

Voilà mon problème : je cherche à réaliser une fonction qui me permette de formater une textbox en format Date, car ayant une multitude de formulaires avec des saisies de date, cela devient lourd de réécrire le code pour chaque textbox.

J'ai donc réussi pour le moment à réaliser la chose de cette manière (le code fonctionne) :

- Code de ma fonction (dans un module nommé MaFonction) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Public DateSaisie As Control
 
Public Function FormaterDate()
 
If IsNumeric(DateSaisie) Then
 
    If Len(DateSaisie) = 1 Then
 
    DateSaisie = "0" & DateSaisie & "/" & Format(Date, "mm") & "/" & Format(Date, "yyyy")
 
        ElseIf Len(DateSaisie) = 2 Then
        DateSaisie = DateSaisie & "/" & Format(Date, "mm") & "/" & Format(Date, "yyyy")
 
        ElseIf Len(DateSaisie) = 4 Then
        DateSaisie = Left(DateSaisie, 2) & "/" & Right(DateSaisie, 2) & "/" & Format(Date, "yyyy")
 
        ElseIf Len(DateSaisie) = 6 Then
        DateSaisie = Left(DateSaisie, 2) & "/" & Mid(DateSaisie, 3, 2) & "/" & Right(DateSaisie, 2)
 
        ElseIf Len(DateSaisie) = 8 Then
        DateSaisie = Left(DateSaisie, 2) & "/" & Mid(DateSaisie, 3, 2) & "/" & Right(DateSaisie, 4)
 
    End If
 
End If
 
End Function

- Code de mon UserForm1 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
Private Sub UserForm_Initialize()
 
TextBox1.Value = Date
Label2.Caption = WorksheetFunction.Proper(Format(TextBox1.Value, "dddd d mmmm yyyy"))
TextBox1.SelStart = 0
TextBox1.SelLength = Len(TextBox1.Text)
 
End Sub
 
Private Sub TextBox1_Enter()
 
        TextBox1.Tag = TextBox1
 
End Sub
 
Private Sub TextBox1_BeforeUpdate(ByVal Cancel As MSForms.ReturnBoolean)
 
Set DateSaisie = TextBox1
 
MaFonction.FormaterDate
 
If Not IsDate(DateSaisie) Then
 
    MsgBox "Format de date incorrect", vbCritical + vbOKOnly, "Erreur de saisie"
    DateSaisie = DateSaisie.Tag
    Cancel = True
    DateSaisie.SelStart = 0
    DateSaisie.SelLength = Len(DateSaisie.Text)
 
End If
 
End Sub
 
Private Sub TextBox1_AfterUpdate()
 
TextBox1.Value = Format(TextBox1.Value, "dd/mm/yyyy")
Label2.Caption = WorksheetFunction.Proper(Format(TextBox1.Value, "dddd d mmmm yyyy"))
 
End Sub
Private Sub CommandButton1_Click()
 
Range("C4") = TextBox1
Range("C6") = TextBox2
 
Unload Me
 
End Sub
 
Private Sub CommandButton2_Click()
 
Unload Me
 
End Sub

Maintenant, ce que je souhaiterais, c'est que ce bout de code vienne à la suite de ma fonction et non pas dans l'évènement TextBox1_BeforeUpdate, car cela m'oblige à réécrire le code pour chaque textbox à formater :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
If Not IsDate(DateSaisie) Then
 
    MsgBox "Format de date incorrect", vbCritical + vbOKOnly, "Erreur de saisie"
    DateSaisie = DateSaisie.Tag
    Cancel = True
    DateSaisie.SelStart = 0
    DateSaisie.SelLength = Len(DateSaisie.Text)
 
End If

Or, si j'ajoute ce code dans ma fonction, je n'obtiens pas l'effet escompté. C'est à dire que les propriétés "Cancel", "SelStart" et "SelLength" ne s'appliquent pas (alors que la msgbox s'affiche et le tag fonctionne), et je perds le focus de ma Textbox1 en cas d'erreur de saisie

Ma question est donc la suivante : Est-il possible d'intégrer ce bout de code à ma fonction ? Ou suis-je obligé de le laisser dans l'évènement BeforeUpdate ?

J'espère que je me suis fait comprendre et merci d'avance à tous ceux qui liront ce post.

Japeth

**Kimy_Ire** · 18/03/2015, 11h06

Bonjour JapethTheGoat,

J'avais réalisé ce bout de code il y a quelque temps :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Private Sub TextBoxDate_Change()
Dim strFormat As String
Dim jour As Integer
Dim mois As Integer
Dim annee As Integer
 
strFormat = "##/##/####"
 
If Me.TextBoxDate Like strFormat Then
 
    jour = Left(Me.TextBoxDate, 2)
    mois = Mid(Me.TextBoxDate.Value, 4, 2)
    annee = Right(Me.TextBoxDate, 4)
 
    If IsDate(Me.TextBoxDate) Then
        With Worksheets("ma_feuille")
             'je fais ce que je veux
        End With
    End If
 
End If
 
End Sub

Je ne sais pas si ça peut servir, mais a tout hasard, ça n'a pas l'air très loin de ce que tu veux faire.

En fait ici, je suis dans le TextBoxDate_Change qui est donc appelé à chaque fois que tu changes ta TextBox (dès que tu insères ou supprimes un caractère quoi !

).
L'idée de cette fonction, c'est que tu ne passes dans la condition qu'au moment où tu as une date du type "jj/mm/aaaa".

Voila, n'hésite pas à revenir vers moi !

Cordialement,
Kimy

**JapethTheGoat** · 18/03/2015, 11h25

Bonjour Kimy,

Merci pour ta réponse.

En fait pour le moment mon code fonctionne et répond à mes attentes, le but étant formater la date sans avoir à la saisir dans sa totalité
(ex : Si tu tapes 15, le contenu de la textbox devient automatiquement 15/03/2015).

Ce que je souhaite, c'est plutôt que de devoir retaper le code dans chaque Textbox devant être formatée de la sorte (je dois en avoir au minimum une dizaines !), c'est de passer par une fonction en dehors du code de mon userform.

J'espère que je me fais comprendre, c'est pas forcément évident !

Invité · 18/03/2015, 11h29

Bonjour,
je comprends pas bien, tu veux valider un textbox pour pour définir si ces une date True/False?

hors IsDate(1235) retourne true oui c'est un date! If isdate(12345)=true and instr(1,"12345","/")<>0 then msgbox "Oui c'est une date" là ça te dit si c'es vraiment une date.

et tu parle de format! quel format? le format date dans un contrôle de ton UserForm? ou un format valide pour un cellule Excel? là c'es pas la même chose.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub test()
If ValideDate(1235) = False Then MsgBox "ERR"
If ValideDate("01/01/2015") = False Then MsgBox "ERR"
If ValideDate("01/01/2015", "yyyy-mm-dd") = False Then MsgBox "ERR" 'Format date pour une cellule Excel!
End Sub
Function ValideDate(d, Optional Forma As String = "dd/mm/yyyy")
    If IsDate(d) = True And InStr(1, d, "/") <> 0 Then ValideDate = Format(d, Forma): Exit Function
    ValideDate = False
End Function

**JapethTheGoat** · 18/03/2015, 12h41

Bonjour rdurupt,

Merci de t'intéresser à mon problème.

En fait j'ai sûrement embrouiller tout le monde avec mes histoires de dates, car à ce niveau là, mon code fonctionne.

Ce que je souhaite, c'est qu'en cas d'erreur de saisie, le focus reste dans ma textbox. Donc que le bout de code suivant soit intégré à ma fonction, et pas dans le code de mon userform (car il marche parfaitement dans le Userform):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
If Not IsDate(DateSaisie) Then' Ici Isdate mais ça pourrait tout aussi bien être une autre condition
 
    MsgBox "Format de date incorrect", vbCritical + vbOKOnly, "Erreur de saisie"
    DateSaisie = DateSaisie.Tag
    Cancel = True
    DateSaisie.SelStart = 0
    DateSaisie.SelLength = Len(DateSaisie.Text)
 
End If

Le problème, c'est que lorsque j'ajoute ce code à ma fonction, il me retourne bien une erreur "Format de date incorrect" en cas d'erreur, il reprend bien le tag du Textbox_Enter, mais perd le focus (comme si les instructions Cancel, SelStart, et SelLenght étaient ignorées) !

Je peux joindre un fichier si besoin.

Merci en tout cas pour vos recherches !

Invité · 18/03/2015, 12h51

Cancel vas annuler la saisie pas redonner le focus a ton contrôle.

de plus, tu ne peux pas données le focus à un contrôle au moment ou tu choisie dans sortir! tu ne peux pas faire demi-tour dans l'embrasure de la porte.

fais ta validation sur le bouton validé et redonne le focus à ton contrôle contrevenant! me.textbox1.focus

**JapethTheGoat** · 18/03/2015, 13h31

Effectivement c'est ce que j'avais fait au début, contrôler la saisie avec le bouton OK du formulaire.
Je voulais le faire directement pendant la saisie pour une question d'ergonomie.

Néanmoins, j'ai quand même du mal à comprendre pourquoi le code fonctionne lorsqu'il est directement exécuté dans l'évènement TextBox1_BeforeUpdate, et pas dans ma fonction, qui pourtant est bien appelée dans ce même évènement.

Je me laisse encore quelques jours de recherche avant de clôturer ce topic, j'y crois encore !

Invité · 18/03/2015, 13h46

la propriété cancel appartient à la méthode de ton formulaire pas a ta fonction.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub TextBox1_BeforeUpdate(ByVal Cancel As MSForms.ReturnBoolean)
test Cancel
End Sub
 
Sub test(ByRef Cancel As MSForms.ReturnBoolean)
Cancel = True
End Sub

en revanche si tu ne donne pas le choix à l'utisateur!
http://www.developpez.net/forums/d15...l/#post8173458

**Docmarti** · 18/03/2015, 14h48

Bonjour JapethTheGoat; rdurupt

Le problème est probablement causé par le MsgBox qui enlève le focus, ce qui mélange les cartes.

Solution 1 : Supprimer le MsgBox et mettre le message dans un Label.

Solution 2 : Garder le MsgBox, et remettre le focus après une seconde en utilisant la commande OnTime.

**JapethTheGoat** · 18/03/2015, 17h43

Merci à tous pour vos réponses,

Je pense avoir fait le tour de la question ! Soit je laisse comme avant, soit je change le fonctionnement !
Je vais y réfléchir...

Je considère mon problème résolu, encore merci et à bientôt !

Invité · 18/03/2015, 18h06

Regardes ma proposition du poste #8 (le lien) il solutionne le problème! Puisque l'utilisateur ne peut que saisir une date valide

**JapethTheGoat** · 18/03/2015, 18h43

Oui en effet le calendrier c'est pas mal non plus (et niveau code, c'est vraiment balèze !!!). Je garde cette solution sous le coude

Merci encore pour vos retours et votre implication

**kiki29** · 18/03/2015, 18h53

Salut, à voir également avant de tomber dans un syndrome d'usine à gaz (... à gags)

**JapethTheGoat** · 18/03/2015, 18h57

Salut kiki29,

C'était ma solution de départ. J'avais commencé avec ça chez moi, et arrivé au boulot, macro plantée ! La référence n'y était pas et impossible de l'installer (c'est un grand groupe je ne suis pas administrateur) ! C'est pourquoi je m'étais rabattu sur un calendrier (comme me l'a proposé rdurupt), et finalement je suis resté sur une simple textbox !

Invité · 18/03/2015, 19h05

Si usine à gaz il y a, c'est transparent Pour le développeur, tout est dans le userform.

Ouvres mon fichier et le tien, maintiens le click gauche de la souris sur le UF calendar et fait le glisser sur to projet.

Pour l'utilisation voir l'exemple.

J'ai créé ce calendrier pour qq1 du forum qui ne pouvait pas utiliser un dtpicker.

**kiki29** · 18/03/2015, 19h37

Salut, je ne parlais pas de ton calendrier comme d'une usine à gaz mais du code de la Textbox, ton calendrier qui est autonome et LA solution dans ce cas.

Invité · 18/03/2015, 19h53

Envoyé par kiki29

Salut, je ne parlais pas de ton calendrier comme d'une usine à gaz mais du code de la Textbox, ton calendrier qui est autonome et LA solution dans ce cas.

T'inquiète faut bien au je face mes actions commerciales j'ai des objectifs à tenir

**patricktoulon** · 18/03/2015, 22h06

Bonjour
On le dira jamais assez mais avant de poster regarder la faq et les contributions

ca se passe ici par exemple :

**patricktoulon** · 19/03/2015, 11h38

re
tiens et ca c'est pour tout le monde

puisque que usine a gaz te fait peur donc pas la peine de parler de module (classe)

une simple gestion sur le (keyup) du ou des textbox fera l'affaire

la fonction gere:
1° les touche valides a taper (soit rien que le pavé numérique
2°les symboles "/" pour les dates ou les espaces pour les numéros de téléphone qui ce placent tout seul
3°en sortie formatage de la date au format souhaité soit ("dddd dd mm yyyy")
4° en cas d'erreur de ta part sur une touche du pavé numérique tu peut taper sur les touche (delete ou suppr) ca t'efface le textbox
5° en cas de date tapée non valide l'ors de la mise en forme souhaité ,un msgbox t'en averti et efface ce que tu viens de taper
et tout ca en de 25 lignes de code

on fait appel a cette fonction comme ceci dans le keyup du textbox
pour un numéro de telephonne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub TextBox1_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
TextBox1 = ForMattexT(TextBox1.Text, tel, KeyCode)
End Sub

Pour une date

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub TextBox2_KeyUp(ByVal KeyCode As MSForms.ReturnInteger, ByVal Shift As Integer)
TextBox2 = ForMattexT(TextBox2.Text, mYdAte, KeyCode)
End Sub

et enfin la fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Public Const tel = "telephonne"
Public Const mYdAte = "mydate"
Public Function ForMattexT(ctrl, formats, key) As String
    Dim contenu As String
    contenu = ctrl
    If key < 96 Then contenu = Mid(contenu, 1, Len(contenu) - 1)
    Select Case formats
    Case "telephonne"
        Select Case Len(contenu)
          Case 2, 5, 8, 11: contenu = contenu & " "
        Case Is > 14:  contenu = Mid(contenu, 1, 14)
        End Select
    Case "mydate"
         Select Case Len(contenu)
        Case 2, 5: contenu = contenu & "/"
        Case 10
        contenu = Format(contenu, "dddd d mmmm yyyy")
            If Not IsDate(contenu) Then
                contenu = ""
                MsgBox "cette date n'est pas valide "
            End If
        End Select
    End Select
    If key = 8 Or key = 46 Then contenu = ""
    ForMattexT = contenu
End Function