Discussion :

[davtypo3]

Bonjour,

Voici mon problème, j'ai dans un même classeur, deux feuilles, feuil1 et feuil2, je cherche à faire une recherche sur deux colonnes dans la feuille deux sur deux colonnes:
Donc en fait si le couple des deux valeurs depuis feuil1 existe dans feuil2 (sur deux colonnes également) alors j'affiche la valeur index 3 de la feuille deux.
Je n'ai pas beaucoup de lignes dans mes feuilles.

évidemment un =SIERREUR(RECHERCHEV(mavaleur; feuil2!A:B; 3; FAUX); "NA") ne fonctionne pas car il prend une valeur de recherche.

Un exemple de résultat attendu:


Dans feuil1:

mois nom résultat
10 TOTO 999
11 TITI 888
...

Dans feuil2:

mois nom poids
9 TUTU 125
10 TOTO 999
11 TITI 888
13 ...etc

Pour l'instant je rame avec index + equiv et le reste...
Merci de votre aide,

[Promethee25]

Bonjour,

Tu n'as pas posté dans la bonne section.

Formule matricielle à valider par Ctrl+Maj+Entrée (en supposant que tes données soient entre les lignes 2 et 100 de Feuil2):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDIRECT("Feuil2!C" & MAX(SI(1*(Feuil2!$A$2:$A$100=Feuil1!A2)*(Feuil2!$B$2:$B$100=Feuil1!B2); LIGNE(Feuil2!$B$2:$B$100); 0)))

Edit:
Autre possibilité sûrement meilleure en terme de perf (toujours à valider par Ctrl+Maj+Entrée):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX(Feuil2!$C$1:$C$100; EQUIV(A1 & "@" & B1; Feuil2!$A$1:$A$100 & "@" & Feuil2!$B$1:$B$100; 0))

[davtypo3]

Arghh, merci, merci, je suis sur ta deuxième solution, mais j'obtiens toujours un N/A, mais pourquoi donc? En PJ mon fichier si tu peux y jeter un œil test.xlsx.
En passant j'ai finalement besoin d'une recherche sur 3 colonnes...

Merci de ton aide je ne suis pas loin...
David

[Promethee25]

La formule renvoie N/A si elle ne trouve pas de solution.
Si tu veux du texte vide à la place, encapsule-la avec SIERREUR.

TOn erreur est de regarder dans la colonne D au lieu de la colonne C de ton 2ème onglet:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=INDEX(LAN2014AUTRE!$D$1:$D$35789; EQUIV(A2 & "@" & B2 & "@" & E2; LAN2014AUTRE!$A$1:$A$35789 & "@" & LAN2014AUTRE!$B$1:$B$35789 & "@" & LAN2014AUTRE!$C$1:$C$35789; 0))

[davtypo3]

Bon je vais aller me coucher, ça fonctionne et ok pour SIERREUR.
Merci encore.