Discussion :

[DJOUFOU]

bonjour chers compagnons de tous les jours,
j'ai un nouveau probleme ce matin. je travail sur l'interface utilisateur de mon application access. je veux ajouter un bouton "Gestion des stocks" de telle sorte que lorsqu'on clic dessus, un sous menu se déplie et affiche les boutons suivants "Entrée de m/ses" , "Sortie de m/ses", "transfert de Stock". j'ai chercher en vain. j'avais abordé ce sujet sur ce même forum il y'a assez longtemps, une personne m'avais demandé d'aller voir sur un lien, mais malheureusement ce lien traitait que du 2003 et aucune indication ne repondais a ma question. j'avais donc abandonné mais avec ma nouvelle application de gestion des stocks, je me rend compte qu'il me faut vraiment sa sinon mon interface utilisateur sera trop surchargée.

Dans visual basic 2010 express, j'arrive à le faire et ils appel ça "toolstrip menu item". mais je ne suis pas encore prêt ou du moins je n'ai pas encore le niveau pour lier ma base access à une interface faite sous visual basic. je veux bien connaitre access d'abord, pouvoir concevoir une application complète sous access avant de me lancer profondément dans le visual basic.

je ne sais si j'ai pu me faire comprendre mais je suis disposé a éclaircir d'avantage ceux qui voudront bien se pencher sur mon probleme.
merci d'avance à tous et agréable journée.

[Frank]

Bonjour,

je rajouterais plutôt un menu : http://warin.developpez.com/access/tutorielcontext1/

[DJOUFOU]

Merci à Frank, mais je travail sous access 2013 et / ou 2010 et après avoir jeté un œil sur ton lien, je crains que ce tuto ne puisse pas repondre a mes besoins car je ne retrouve presque pas les fenêtres et les onglets dont ils parlent dans. je continu de chercher mais n'y aurait il pas un tuto pour 2013 ou 2010?
merci.

[Didier L]

Bonjour,

est-ce cela que tu veux réaliser ?



Affichage d'un menu contextuel personalisé, sur clic droit de la souris, sur un bouton, avec Access 2010 ?

Ou tout simplement l'affichage d'un formulaire en mode boite de dialogue, avec tes boutons en guise de sous menu ?

[DJOUFOU]

Didier L, je pense que c'est la première méthode( Affichage d'un menu contextuel personalisé, sur clic droit de la souris, sur un bouton, avec Access 2010) qui est proche de ce que je veux. Mais dans mon cas sa sera sur clic gauche et non droit. Ce que je veux est un peu comme lorsque tu clic par exemple sur l'onglet "Office" de la page du site développer.com, tu constate qu'un sous menu affiche Word, Excel, access etc. C'est un truc pareil ke je veux.

[Didier L]

Voila code suivant qui fonctionnera avec le clic droit ou gauche de la souris, selon si c'est dans les propriété du bouton d'Access que l'on fera le lien avec le menu contextuel ou dans la procédure "sur click"

Dans un module copie le code suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub DeleteSimpleShortcutMenu()
    CommandBars("MonSousMenu").Delete
End Sub
 
Sub CreateSimpleShortcutMenu()
Dim cmbShortcutMenu As Office.CommandBar
Dim cmbControl As Office.CommandBarControl
    Set cmbShortcutMenu = CommandBars.Add("MonSousMenu", msoBarPopup, False, True)
    Set cmbControl = cmbShortcutMenu.Controls.Add(msoControlButton)
    With cmbControl
        .Caption = "Action1"
        .OnAction = "Mafonction1"
    End With
    Set cmbControl = cmbShortcutMenu.Controls.Add(msoControlButton)
    With cmbControl
        .Caption = "Action2"
        .OnAction = "Mafonction2"
    End With
    Set cmbControl = Nothing
    Set cmbShortcutMenu = Nothing
End Sub
 
Function Mafonction1()
    MsgBox "1"
End Function
 
Function Mafonction2()
    MsgBox "2"
End Function

La procédure "CreateSimpleShortcutMenu" te permet de créer une fois ton menu contextuel. Si tu veux le modifier ou l'enrichir au cours de ton développement, pense éventuellement à le supprimer avant avec la procédure "DeleteSimpleShortcutMenu"

Les fonctions "Mafonction1" et "Mafonction2" sont la en exemple pour exécuter ce que tu veux faire faire à ton sous menu

Ensuite, il te suffit sur les propriétés de ton bouton, dans ton formulaire, de choisir dans la liste le menu contextuel que tu viens de créer


Ou alors de placer le code suivant sur clic de ton bouton :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub Commande12_Click()
    CommandBars("MonSousMenu").ShowPopup
End Sub

Attention la création du menu contextuel doit être faite a chaque ouverture de la base car ce menu est "virtuel"

Bonne continuation.

[DJOUFOU]

Merci Didier L. Jvais essayer et à bientôt pour la réponse.