Discussion :

[gilles171]

Bonjour,

quelqu'un connait un autre moyen d'exprimer mon copier coller ci dessous ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Range("D1").Copy Destination:=Range("K1")

Car il ne marche qu'une fois sur deux ( sur plus de 200 fichiers c 'est embêtant )

Merci beaucoup

[joe.levrai]

Bonjour,

si tu faisais référence explicitement aux plages que tu copies et aux plages où tu colles, ça n'irait pas mieux ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Workbooks("Nom Du Classeur").Worksheets("Nom De La Feuille").Range("D1").Copy Destination:=Workbooks("Nom Du Classeur").Worksheets("Nom De La Feuille").Range("K1")

[gilles171]

Merci pour la réponse, mais non car ma macro principale appel de nombreux classeurs :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
 
Option Explicit
Sub Test()
Dim Plage As Range, InpRng As Range
Dim Cel As Range
'On Error GoTo Err_Read
Dim Derl As Long
Derl = ThisWorkbook.Worksheets("Feuil1").Range("A" & Cells.Rows.Count).End(xlUp).Row
Set InpRng = ThisWorkbook.Worksheets("Feuil1").Range("A2:A" & Derl)
Debug.Print InpRng.Address, InpRng.Cells.Count
For Each Cel In InpRng
    If Trim("" & Cel) <> "" Then Histo CStr(Cel) Else MsgBox Cel.Address & " invalide"
Next
End Sub
Sub Histo(Fichier As String)
Dim Sh As Worksheet
Dim wb As Workbook
Application.DisplayAlerts = False
Set wb = Workbooks.Open(Fichier)
Application.DisplayAlerts = True
For Each Sh In wb.Sheets
    TraitementSheet Sh
Next
wb.Save
wb.Close
End Sub
Sub TraitementSheet(Sh As Worksheet)
Dim Plage As Range
Dim Cel As Range
If UCase(Left(Sh.Name, 5)) <> UCase("Valor") Then Exit Sub
   Range("D1").Copy Destination:=Range("K1")

[joe.levrai]

tu utilises déjà des variables pour tes classeurs dans ton code !
Wb,Sh

tu utilises mêmes des arguments Sh dans certaines procédures

alors il est tout à fait possible, en quelques lignes, d'intégrer la référence au classeur

d'ailleurs, tes Sub Histo et Traitements peuvent très bien s'intégrer dans ta Sub Test, ce qui facilitera encore plus la manipulation de tes variables

[gilles171]

Je ne sais pas du tout faire...

[joe.levrai]

Voici un code qui réunis tes trois procédure et où chaque range est bien rattaché à une feuille

on est bien d'accord que chaque couple des cellule D1 et K1 est à chaque fois sur la même feuille et dans le même classeur ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
Option Explicit
Sub Test()
Dim Plage As Range, InpRng As Range
Dim Cel As Range
Dim Derl As Long
Dim Wb As Workbook
Dim Sh As Worksheet
 
Derl = ThisWorkbook.Worksheets("Feuil1").Range("A" & Cells.Rows.Count).End(xlUp).Row
Set InpRng = ThisWorkbook.Worksheets("Feuil1").Range("A2:A" & Derl)
 
For Each Cel In InpRng
    If Trim("" & Cel) <> "" Then
        Application.DisplayAlerts = False
        Set Wb = Workbooks.Open(Cel)
        Application.DisplayAlerts = True
        For Each Sh In Wb.Sheets
            If UCase(Left(Sh.Name, 5)) = UCase("Valor") Then
                Sh.Range("D1").Copy Sh.Range("K1")
            End If
        Next Sh
 
        Wb.Close True
 
    Else
        MsgBox Cel.Address & " invalide"
    End If
Next
 
End Sub

[gilles171]

C'est génial , ça marche parfaitement bien !
Merci beaucoup et bonne fin de journée !