manipulation des tableaux comme objets

**Grem974** · 28/05/2015, 12h14

Bonjour,
Je cherche à ajouter une ligne dans un tableau existant (que je complète en partie automatiquement via un fichier et en partie manuellement).

Il s'agit de pouvoir ajouter une ligne dans la partie automatisée dans le tableau, me positionner dans la première colonne de la ligne ajoutée et de ranger ensuite ce tableau par ordre alphabétique.

Pour le moment j'ai une info :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 Worksheets(1).Range("data_NometPrenom").ListObject.ListRows.Add (1)

Apparemment ca permet d'ajouter une ligne mais j'ai pour cette ligne l'erreur : "Erreur définie par l'application ou par l'objet"

Je pensais définir une variable et lui attribuer la position de la première cellule de la ligne ajoutée avec (selon une aide du forum) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 DerLig = .[A65536].End(xlUp)(2).Row

Avec juste ce dernier code et le reste permettant de remplir les cellules de la ligne ça marche (je remplis la dernière ligne). L'idée maintenant est de pouvoir rester dans l'objet tableau pour permettre les filtres (tableau dont je n'ai pas d'autre choix de l'utiliser).

Merci de votre aide!

**joe.levrai** · 28/05/2015, 12h38

Bonjour,

déjà, je te conseille de mettre ton ListObject sous variable, pour pas recopier tout le temps son chemin
et ça te permet aussi de conserver la saisie intuitive dans ton code

voici une petite boite à outils, pioche ce qui t'intéresse

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Sub MonBeauTableau()
 
Dim Tablo As ListObject
Set Tablo = ActiveSheet.ListObjects("Tableau1")
 
With Tablo
    ' ajout de ligne en fin de tableau
    .ListRows.Add
 
    ' écrire TOTO sur chaque cellule de la nouvelle ligne
    For j = 1 To .ListColumns.Count
        .Range(.ListRows.Count + 1, j) = "TOTO"
    Next j
 
    'sélectionner la cellule de la première colonne de la dernère ligne
    .Range(.ListRows.Count + 1, 1).Select
 
    ' tri ascendant de la colonne 1
    With .Sort
        .SortFields.Clear
        .SortFields.Add Tablo.ListColumns(1).Range, xlSortOnValues, xlAscending
        .Header = xlYes
        .MatchCase = True
        .Apply
    End With
End With
 
End Sub

**vinc_bilb** · 28/05/2015, 13h19

Bonjour

ListRows.Add nécessite une table, pas un range à ma connaissance et Range("data_NometPrenom") retourne un range .... donc ça ne devrait pas pouvoir marcher

**Grem974** · 28/05/2015, 14h13

salut,

J'ai testé ton code et j'obtiens l'erreur d'incompatibilité de type pour :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 
Dim Tableau As ListObjects
Set Tableau = ActiveSheet.ListObjects("Tableau1") 'erreur sur cette ligne

Je comprends pas

Merci

**joe.levrai** · 28/05/2015, 14h23

C'était un exemple basique

tu dois adapter à ton ListObject

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set Tablo = Sheets("NomDeTaFeuille").ListObjects("NomDeTonTableau")

**Grem974** · 28/05/2015, 15h25

Re,
c'est ce que j'ai fait le tableau s'appelle Tableau1 et la feuille est bien la feuille active dans le code.

**Grem974** · 28/05/2015, 15h35

Je pense que je le place mal :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
 
Private Sub CommandButton2_Click()
Application.ScreenUpdating = False
Dim FichierTampon As Workbook
Dim Tableau As ListObjects
Dim DerLig As Long
Dim NOM As String, Prenom As String
    Set FichierTampon = Workbooks.Open("E:\Planning-travail\Classeur2")
 
    NOM = TextBox1
    Prenom = TextBox5
'au moment de clique lebouton il se passe :
    With FichierTampon
        Set Tableau = ActiveWorkbook.Sheets(1).ListObjects("Tableau1")
        With .Worksheets(1)
         DerLig = .[A65536].End(xlUp).Offset(1, 1).Row
            .Cells(DerLig, 1) = NOM & " " & Prenom
            .Cells(DerLig, 2) = TextBox6.Value
            .Cells(DerLig, 7) = Label6.Caption
            .Cells(DerLig, 8) = TextBox2.Value
            .Cells(DerLig, 9) = Label8.Caption
            .Cells(DerLig, 10) = TextBox3.Value
 
            If OptionButton1 Then
                .Cells(DerLig, 5) = "J"
            Else
                .Cells(DerLig, 5) = "N"
            End If
 
            If OptionButton3 Then
                .Cells(DerLig, 4) = "IDE"
            Else
                .Cells(DerLig, 4) = "ASD"
            End If
 
            If Chekbox1 Then
                .Cells(DerLig, 6) = "dimanche"
            ElseIf CheckBox2 Then
                .Cells(DerLig, 6) = "férié"
            ElseIf CheckBox1 = True And CheckBox2 = True Then
                .Cells(DerLig, 6) = "Dimanche et férié"
            Else
                .Cells(DerLig, 6) = ""
            End If
 
         '.Tableau.Sort Key1:=Range("A1"), order1:=xlAscending
        End With
 
        .Save
        .Close
    End With
 
    Unload Me 'vide et ferme l'USerForm
    ActiveCell.Value = NOM 'la cellule active prend la valeur de NOM
 
End Sub

Qu'en penses-tu?

**vinc_bilb** · 28/05/2015, 15h44

Bonjour,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
Dim Tablo As ListObject
Dim Tableau As ListObjects 'Non: 's' à enlever comme la ligne précédente: vous définissez une collection d'objet et non pas un objet

**joe.levrai** · 28/05/2015, 16h01

tu n'utilises pas ton listobject dans ce code, tu l'affectes (enfin du tu essayes) à une variable et ensuite tu fais des choses sans l'utiliser.

il est dans ton fichier tampon le tableau, dans le première feuille ?

pourquoi ne pas réutiliser cette variable, puisqu'elle existe ?
pourquoi tu n'utilises pas ce tableau pour ton remplissage, et te cantonnent à ton code initial qui ajoute une ligne sauvagement en dessous de ton listobject ?

j'extrapole : tu veux créer une nouvelle ligne à ton listobject, et y mettre la valeur de tes contrôles
je te propose un code comme ça ... je te laisse testé, je n'ai pas pu le faire

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
Private Sub CommandButton2_Click()
Dim FichierTampon As Workbook
Dim Tablo As ListObject
Dim TabloValeur()
 
' pour stocker tes valeurs conditionnelles
Dim Val4 As String
Dim Val5 As String
Dim Val6 As String
 
' on définie les valeurs conditionnelles
If OptionButton1 Then
    Val5 = "J"
Else
    Val5 = "N"
End If
 
If OptionButton3 Then
    Val4 = "IDE"
Else
    Val4 = "ASD"
End If
 
' j'ai changé l'ordre de ton test
' on doit d'abord tester si les deux sont à True
' avant de regarder si un seul est à True
If Checkbox1 And CheckBox2 Then
    Val6 = "Dimanche et férié"
ElseIf CheckBox2 Then
    Val6 = "férié"
ElseIf CheckBox1 Then
    Val6 = "Dimanche"
Else
    Val6 = ""
End If
 
 
' on rempli dans un tableau virtuel, l'ensemble des valeurs à remplir
' les valeurs sont rangées dans l'ordre des colonnes de destination
' ATTENTION : tu n'as aucune valeur pour la colonne 3 ==> j'ai donc mis une chaine vide dans le tableau de valeurs
TabloValeur = Array(TextBox1.Value & " " & textbox5.Value, TextBox6.Value, "", valeur4, valeur5, valeur6, Label6.Caption, TextBox2.Value, Label8.Caption, TextBox3.Value)
 
Application.ScreenUpdating = False
 
Set FichierTampon = Workbooks.Open("E:\Planning-travail\Classeur2")
Set Tablo = FichierTampon.Sheets(1).ListObjects("Tableau1")
 
With Tablo
    ' ajout de ligne en fin de tableau
    .ListRows.Add
 
    ' écrire les 10 valeurs dans les 10 colonnes en bouclant simplement sur le tableau virtuel
    For j = LBound(TabloValeur) To UBound(TabloValeur)
        .Range(.ListRows.Count + 1, j + 1) = TabloValeur(j)
    Next j
End With
 
'fermeture du fichier en l'enregistrant en même temps
FichierTampon.Close True
Set FichierTampon = Nothing
Set Tablo = Nothing
 
Unload Me
ActiveCell.Value = TextBox1.Value
End Sub

**Grem974** · 28/05/2015, 16h10

Re,

Cette fois c'est une autre erreur qui apparait... : "propriété ou méthode non gérée par cet objet"
et l'erreur s'arrête sur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set Tableau = ActiveSheet.ListObject("Tableau1")

**Grem974** · 28/05/2015, 16h11

Envoyé par Grem974

Re,

Cette fois c'est une autre erreur qui apparait... : "propriété ou méthode non gérée par cet objet"
et l'erreur s'arrête sur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set Tableau = ActiveSheet.ListObject("Tableau1")

et quand le mets le "S" c'est sur :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

With .Tableau1

**Grem974** · 28/05/2015, 16h35

Envoyé par joe.levrai

tu n'utilises pas ton listobject dans ce code, tu l'affectes (enfin du tu essayes) à une variable et ensuite tu fais des choses sans l'utiliser.

il est dans ton fichier tampon le tableau, dans le première feuille ?

pourquoi ne pas réutiliser cette variable, puisqu'elle existe ?
pourquoi tu n'utilises pas ce tableau pour ton remplissage, et te cantonnent à ton code initial qui ajoute une ligne sauvagement en dessous de ton listobject ?

j'extrapole : tu veux créer une nouvelle ligne à ton listobject, et y mettre la valeur de tes contrôles
je te propose un code comme ça ... je te laisse testé, je n'ai pas pu le faire

Tu as parfaitement compris mon objectif et je t'en remercie. Je m'obstine dans le code initial pour essayer de modifier petit à petit essayer d'améliorer ce que je peux comme je peux (j'y connais rien en programmation et j'essaie de comprendre je suis loin d'être efficient

) et je suis impressionné par la vitesse à la quelle, vous tous qui répondez, arrivez à produire des codes aussi beaux et efficaces. Vous êtes des professionnels?

Pour le côté "sauvage" c'est simplement l'absence de formation ... je trouve des tutos, des réponses de forums, parfois des questions et j'essaie (à l'instar d'une polymérase eucaryote) avec des erreurs et je constitue de cette façon mon projet de stage. J'essaie d'adapter ce que j'apprends à ce je veux obtenir. Ce qui fait que j'ai un code plutôt sale et brutal... pour le moment j'ai réussi à limiter mes plantages de système à 2

Merci en tout cas de ton aide!
Ce que tu me propose fonctionne parfaitement! Grace à la mobilisation de tous vous me permettez d'acquérir des connaissances et des compétences. Et ca me va droit au coeur

**joe.levrai** · 28/05/2015, 17h22

Je suis loin d'être professionnel .... j'ai tout appris sur mon temps libre et sans formation (et j'utilise mon capital connaissance pour m'aider au boulot du coup)

j'ai parlé de sauvagerie comme d'un constat, et pas un jugement ... si tu voyais la tête de mes codes quand j'ai débuté, c'est toi qui me traiterai de sauvage

on est pas efficace, on l'es devenu avec le temps, à force de rencontrer des problématiques et d'en définir un schéma cohérent ... qui du coup devient un outil utilisable sur d'autres problématiques.

ce forum est une chance de partager, mais aussi d'apprendre ... plus je participe et plus j'apprend ... parfois à coup de "essaye, échoue, comprend, rectifie/recommence"

et surtout en acceptant, comprenant, réutilisant l'ensemble des critiques qu'on peut me faire et qu'on me fera

manipulation des tableaux comme objets [Toutes versions]

Excel

Discussions similaires

Partager

Partager