Discussion :

[chrtophe]

Bonsoir,

J'aurais souhaité savoir si il était possible d'utiliser la fonction Application.saveAsText avec une base externe.

J'ai l'erreur :

Aucun objet du nom et type spécifiés n'existe dans la base de données active

Mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
dim db as database
set db=DBEngine.OpenDatabase(nom_de_la_base)
set c=db.containers("Forms")
for each d in c.Documents
  Application.SaveAsText, acForm, d.Name, chemin
next d

Je précise que l'accès à la base est valide (je peux afficher le nom des formulaires qu'elle contient)

[loufab]

Bonjour,

Application "représente" l'application courante, celle qui contient ton code mais pas les formulaires.

Il faut ouvrir une nouvelle instance de l'application sur le fichier contenant les formulaires. Comme ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Dim app As Access.Application
Set app = New Access.Application
app.OpenCurrentDatabase "C:\appli_avec_formulaire.accdb"
app....

Tout ce qui est sous app s'appliquera à l'application "distante".

Cordialement,

[chrtophe]

Merci pour ton retour, ça je l'ai compris en recherchant des infos. Je reviens quand j'ai avancé (positivement ou négativement). J'arrive à ouvrir une base externe avec Application (ce que je n'avais jamais fait), je n'arrive pas pour le moment à utiliser saveastext, j’avoue que je cafouille avec les workspaces, dbengine, etc... et donc je ne sais pas si c'est mon code qui est faux ou si la fonction saveastext je ne peux l'utiliser que depuis la base courante (fonction non documentée)

Je vous tiens au courant.

[loufab]

La commande SaveAsText n'est pas documentée car c'est une méthode cachée. On l'utilise pour créer des fichiers compatible VB.

Elle fonctionne parfaitement depuis une base distante du moment que tu utilises les bons objets.
Voici un exemple d'export d'objets.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
 
Function fSaveAsText()
Dim appAccess  As Access.Application
Dim db         As DAO.Database
Dim obj        As Object
Dim i          As Integer
Dim chemin     As String
 
    chemin = "d:\"
    Set appAccess = New Access.Application
    appAccess.OpenCurrentDatabase "C:\fichier.accdb"
 
    Set db = appAccess.CurrentDb
 
    With appAccess
 
        For Each obj In db.Containers("Forms").Documents
            .SaveAsText acForm, obj.Name, chemin & obj.Name & ".frm"
        Next
 
        For Each obj In db.Containers("Reports").Documents
            .SaveAsText acReport, obj.Name, chemin & obj.Name & ".rpt"
        Next
 
        For Each obj In db.Containers("Modules").Documents
            .SaveAsText acModule, obj.Name, chemin & obj.Name & ".bas"
        Next
 
        For Each obj In db.Containers("Scripts").Documents
            .SaveAsText acMacro, obj.Name, chemin & obj.Name & ".mac"
        Next
 
        For i = 0 To db.QueryDefs.Count - 1
            If Not db.QueryDefs(i).Name Like "~*" Then
                .SaveAsText acQuery, db.QueryDefs(i).Name, chemin & db.QueryDefs(i).Name & ".qry"
            End If
        Next i
    End With
 
    db.Close
    appAccess.CloseCurrentDatabase
    Set db = Nothing
    Set appAccess = Nothing
End Function

Quel but poursuis-tu ?

[chrtophe]

Ca y est je m'en suis sorti. Notamment avec ceci :

http://ahisoft.jp/subt/mdbexporttool.html

C'est en japonais mais la traduction google des commentaires donne un résultat compréhensible.

C'est bien foutu.

Tu utilises :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set db = appAccess.CurrentDb

dans le code le gars utilise :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set db = DBEngine.Workspaces(0).OpenDatabase(inputDbName)

Je pense que ça revient au même, mais j'ai pas testé.

J'ai galéré un moment car si le code VBA de la base externe est protégé, cela génère une erreur.

Merci de ton retour.

[loufab]

Le code que je t'ai fourni ne fonctionne ?

Protégée, si tu parles de accde c'est normal, si c'est protégé par mot de passe il y a des options à la commande OpenCurrentDatabase.

[chrtophe]

Le code que je t'ai fourni ne fonctionne ?

Je présumes que si mais comme entretemps j'avais trouvé et testé le lien ...

Protégée, si tu parles de accde c'est normal, si c'est protégé par mot de passe il y a des options à la commande OpenCurrentDatabase.

Non, en cas de protection de code VBA, pas le mot de passe d'ouverture de la base. (propriété dans VBA j'ai pas le nomenclature en tête et n'ai pas access sous le coude là.). En supprimant le mot de passe VBA, ça fonctionne. Et je pense pas qu'on puisse passer le code de protection VBA à OpenCurrentDatabase

[loufab]

Je présumes que si mais comme entretemps j'avais trouvé et testé le lien ...

Je m'étonnais car c'est quasiment le même, il n'y a pas 50 manières de faire ça.