Discussion :

[stan314]

Salut tout le monde,

J'utilise le formulaire de connexion ci dessous (que j'ai trouver dans le la faq)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
Private Sub connexion_Click()
Me.Requery
Dim sql, User_id, User_groupe   As String
Dim rs As DAO.Recordset
Static i As Byte
sql = "SELECT * FROM T_USERS WHERE TRIGRAMME = '" & Me.txt_user & "' AND PASSWD ='"& Me.txt_pass & "';"
Set rs = CurrentDb.OpenRecordset(sql)
If Not rs.EOF Then
  DoCmd.OpenForm "F_Autre_Formulaire", acNormal, , , , acWindowNormal
  DoCmd.close acForm, "F_CONNEXION"
  User_id = rs("TRIGRAMME").value
  User_groupe = rs("GROUPE").value
Else
  MsgBox "(Identifiant, Mot de Passe) incorrect ", vbInformation, "Connexion"
  i = i + 1
End If
If i = 3 Then 
Msgbox "Vous avez dépassé le nombre de tentatives autorisés", vbCritical
DoCmd.Quit
End If
End Sub

Je voudrais savoir comment je peux réutiliser le User_Id
dans des requetes qui ne font pas parties de ce formulaires...
Merci d'avance pour votre response

stan314

[philben]

Bonjour,

Dans une appli j'ai crée un module avec le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 
 
Private gvsLogin As String 'login de l'utilisateur courant
Private gvsUser As String 'prénom / nom de l'utilisateur courant
Private gvlGroupe As Long 'groupe de l'utilisateur courant
 
Public Sub SetMyConnexion(sLogin As String, lGroupe As Long, sNom As String, sPrenom As String)
   gvsLogin = sLogin
   gvlGroupe = lGroupe
   gvsUser = sPrenom & " " & sNom
End Sub
 
Public Sub CloseMyConnexion()
   gvsLogin = vbNullString
   gvsUser = vbNullString
   gvlGroupe = 0
End Sub
 
Public Function GetMyLogin() As String
   GetMyLogin = gvsLogin
End Function
 
Public Function GetMyUser() As String
   GetMyUser = gvsUser
End Function
 
Public Function GetMyGroupe() As Long
   GetMyGroupe = gvlGroupe
End Function

Ca me permet de réutiliser les infos ailleurs que dans le formulaire courant

[Fablondon]

Tu peux aussi declarer ton user_id comme variable globale dans ton projet et ainsi elle pourra etre lu, modifiee dans tout ton projet.
Peut etre as tu interet a creer un module de declaration de toutes tes variables globales si tu en as bcp.
PAr contre c est moins securise que ce que te propose philben, car il faudra que tu garantisse que rien d autre ne modifie ces variable dans ton progamme.
A++

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
Global user_id As String