Discussion :

[adnane01]

Bonjour,
J'ai plusieurs feuilles de 1 à N-1, et une feuille N.
Sur la feuille N j'ai des codes sur la colonne D, je souhaiterai comparer la valeur de chaque cellule de cette colonne avec les cellules de la colonne A des feuilles de 1 à N-1, si la comparaison est OK, je prends la valeur des lignes des feuille 1 à N-1 et je la met dans ma feuille N à coté du code qui correspond.

j'ai réfléchi à un algorithme du style :

Pour j de F1-->F(N-1)
pour i de ligne 1 à la ligne K
Si la cellule Numéro i (feuille j) == cellule numéro x de la feuille N
instruction : copier la ligne i de la feuille j et la mettre dans la ligne x de la feuille N
Sinon on sort de la boucle


J'ai donc besoin de la version Macro
Merci d'avance

[Thautheme]

Bonjour Adnane, bonjour le forum,

je prends la valeur des lignes

Pas très clair tout ça !...

Si tu trouves une occurrences tu copie la ligne (ne serait-ce pas plutôt les cellules éditées de la ligne?) en colonne E donc ?
Si tu trouves plusieurs occurrences tu insères des lignes alors ?

[adnane01]

Bonjour,
Quand je trouve une occurence je copie uniquement la ligne
Par exemple :
J'ai un code 40 sur la feuille N et je cherche un code pareil dans les feuille de 1 à N-1 si je trouve un qui correspond par exemple dans la feuille 5 je copie la ligne qui corresponds et je la met dans la feuille N en face de mon code 40
Je suis clair ?

[Thautheme]

Re,

Non !...
Si il en existe un autre code 40 à l'onglet 7. Que fait-on ?...

[adnane01]

s'il existe dans une autre feuille il est unique

[Thautheme]

Re,

Tu veux dire : si il en existe dans d'autres onglets on les ignore ! C'est ça ?

[Édition]

Essaie ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub Macro1()
Dim OV As Worksheet 'déclare la variable OV (Onglet des Valeurs)
Dim DL As Integer 'déclare la variable DL (Dernière ligne)
Dim TC As Variant 'déclare la variable TC (Tableau de Cellules)
Dim O As Worksheet 'déclare la variable O (Onglets)
Dim R As Range 'déclare la variable R (Recherche)
 
Set OV = Sheets(Sheets.Count) 'définit l'onglet OV (le dernier onglet du classeur)
DL = OV.Cells(Application.Rows.Count, 4).End(xlUp).Row 'définit la dernière ligne éditée DL de la colonne 4 (=D) de l'onglet OV
TC = OV.Range("D1:D" & DL) 'définit le tableau de cellules TC (la liste des codes)
For I = 1 To UBound(TC, 1) 'boucle 1 : sur toutes les lignes I du tableau de cellules TC
    For J = 1 To Sheets(Sheets.Count - 1) 'boucle 2 : sur tous les onglets J du classeur (du premier à l'avant dernier)
        Set O = Sheets(J) 'définit l'onglet O
        Set R = O.Columns(1).Find(TC(I, 1), , xlValues, xlWhole) 'définit la recherche R (recherche le code TC(I, 1) dans la colonne 1 (=A) de l'onglet O)
        If Not R Is Nothing Then 'condition : sil il existe au moins une occurrence trouvée
            Set PL = O.Range(R, O.Cells(R.Row, Application.Columns.Count).End(xlToLeft)) 'définit la plage PL (les cellules éditées de la ligne de l'occurrence trouvée)
            PL.Copy OV.Cells(I, 5) 'copie les cellules dans la colonne E à coté du code
            Exit For 'sort de la boucle 2 (donc ignore d'éventuelles autres occurrences possibles)
        End If 'fin de la condition
    Next J 'prochain onglet de la boucle 2
Next I 'prochaine ligne de la boucle 1
End Sub

[adnane01]

Superbe ça marche !