Discussion :

[Max11121990]

Bonjour,

Je suis nouveau sur Excel, ci-joint un fichier (trouvé sur internet) montrant comment trier des valeurs Excel sans doublon pour faire de graphs dynamiques, Dans la feuille "graph" puis la colonne "Pays" je n'arrive pas à comprendre la logique de la formule =INDEX(pays;EQUIV(MIN(SI(NB.SI(A$1:A1;pays)=0;SI(pays<>"";NB.SI(pays;"<"&pays);"")));SI(NB.SI(A$1:A1;pays)=0;SI(pays<>"";NB.SI(pays;"<"&pays);""));0))

Je comprends le début INDEX(pays;EQUIV mais après la logique MIN(SI(NB.SI(A$1:A1;pays)=0;SI(pays<>"";NB.SI(pays;"<"&pays);"")));SI(NB.SI(A$1:A1;pays)=0;SI(pays<>"";NB.SI(pays;"<"&pays);""));0)) j'ai beaucoup de mal.


Un grand merci d'avance si quelqu'un peut m'expliquer étape par étape.

Max

[Didier Ch.]

Bonjour,
Franchement, je n'aurais jamais inventé ça !

Il faut déjà bien voir au départ que :

• C'est une formule matricielle qui est répétée sur chaque ligne du tableau de synthèse
• Elle s'appuye sur un nom pays qui est calculé :
  =DECALER(Database!$A$2;;;NBVAL(Database!$A:$A)-1) : en partant de A2 avec autant de lignes que de valeurs non vides dans A (-1 pour le titre)

En lisant, voilà ce que je comprends et comment je l'expliquerais :

1. NB.SI(pays;"<"&pays) : Pour chaque ligne de la Database, je compte combien d'autres lignes ont un nom de pays qui arrive avant
2. SI(NB.SI(A$1:A1;pays)=0 : j'ignore les lignes dont j'ai déjà le nom dans mon tableau
3. MIN() : Je prends le plus petit de ces nombres
4. EQUIV() : Je cherche sa position dans la liste des pays
5. INDEX() : J'ai son nom dans la liste des pays
6. Et j'itère, sachant qu'au step 2, je vais exclure aux itérations suivantes toutes les lignes du pays que je viens d'obtenir

J'ai fait un tableau Excel qui découpe un peu plus clairement les arguments et les formules matricielles utilisées : Dédoublonner et trier avec des formules.xlsx

J'espère que ça devient clair.

Pour aller plus loin, 2 remarques :

• Pour le calcul des ventes =SI(ESTERREUR(SOMMEPROD((pays=A2)*vente));"";SOMMEPROD((pays=A2)*vente)) se simplifie en =SIERREUR(SOMMEPROD((pays=A2)*vente);"") depuis Excel 2007 (respect si ça a été fait avant !)
• Le test SI(pays<>"" me semble inutile car si il y a une ligne vide (ou plus) au milieu des pays, alors le nom pays ne tient pas compte de la dernière ligne (ou plus) de la Database et donc de toutes façons le total sera faux (incomplet).
  Pour contourner ce problème, si il peut y avoir des lignes vides, il faudrait remplacer la définition de pays par :
  =DECALER(Database!$A$2;;;MAX(NON(ESTVIDE(Database!$A:$A))*LIGNE(Database!$A:$A))-1)
  Si on est sûr de ne pas avoir de lignes vides, alors :
  
  • on peut remplacer SI(pays<>"";NB.SI(pays;"<"&pays);"") par NB.SI(pays;"<"&pays)
  • on peut garder la définition initiale de pays

[Max11121990]

Merci beaucoup pour votre aide,

Ca devient bien plus clair,