Discussion :

[Christophe P.]

Bonjour,

avec MailItem, je crée et sauvegarde des e-mails dans des fichiers "*.msg". J'aimerais pouvoir les ouvrir afin de les compléter mais je n'ai pas trouvé de méthode permettant de faire cela.
Avez-vous une astuce pour cela ?

[Oliv-]

Bonjour,

Avec une version de outlook 2007 et au delà : IL FAUT UTILISER OpenSharedItem

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
Public Sub OpenSharedMSG()
 
    Dim oNamespace As NameSpace
    Dim oSharedItem As MailItem
    Dim oFolder As Folder
 
    On Error GoTo ErrRoutine
 
    ' Get a reference to a NameSpace object.
    Set oNamespace = Application.GetNamespace("MAPI")
 
    ' Open the vCard (.vcf) file containing the shared item.
    Set oSharedItem = oNamespace.OpenSharedItem( _
        "C:\temp\Mise à jour CRM.msg")
 
    ' Pour l'enregistrer dans la boite de reception !
    oSharedItem.Save
 
    ' Get a reference to and display the Contacts default folder.
    Set oFolder = oNamespace.GetDefaultFolder( _
        olFolderInbox)
    oFolder.Display
 
EndRoutine:
    On Error GoTo 0
    Set oSharedItem = Nothing
    Set oFolder = Nothing
    Set oNamespace = Nothing
Exit Sub
 
ErrRoutine:
    Select Case Err.Number
        Case 287 ' &H0000011F
            ' This error occurs if the code is run by an
            ' untrusted application, and the user chose not to
            ' allow access.
            MsgBox "Access to Outlook was denied by the user.", _
                vbOKOnly, _
                Err.Number & " - " & Err.Source
        Case -2147024894  ' &H80070002
            ' Occurs if the specified file or URL could not
            ' be found, or the file or URL cannot be
            ' processed by the OpenSharedItem method.
            MsgBox Err.Description, _
                vbOKOnly, _
                Err.Number & " - " & Err.Source
        Case -2147352567  ' &H80020009
            ' Occurs if the specified file or URL is not valid,
            ' or you attempt to use the Move method on
            ' an Outlook item that represents a shared item.
            MsgBox Err.Description, _
                vbOKOnly, _
                Err.Number & " - " & Err.Source
        Case Else
            ' Any other error that may occur.
            MsgBox Err.Description, _
                vbOKOnly, _
                Err.Number & " - " & Err.Source
    End Select
 
    GoTo EndRoutine
End Sub

[Christophe P.]

J'ai l'erreur suivante :

Erreur de compilation
Membre de méthode ou de données introuvable

sur GetNamespace dans

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Set oNamespace = Application.GetNamespace("MAPI")

Dans les références j'ai "Microsoft Outlook 14.0 Object Library", faut-il autre chose en plus ?
J'ai ajouté la référence "Microsoft IMAPI2 Base Functionality" mais il y a toujours la même erreur.

[Oliv-]

Si tu utilises cela a partir d un autre programme comme excel ou access il faut l adapter pour l automation
Si ta variable outlook s appelle olapp
Exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

set olapp=createobject ("outlook.application")

Tu remplaces dans le code que j ai donné "application." Par "olapp."

[Christophe P.]

Merci ça fonctionne. Il faut cependant que je fasse un SaveAs au lieu d'un Save pour avoir des fichiers .msg non vides !

[Oliv-]

Save Enregistre l’élément (dans OUTLOOK). Les éléments incluent les messages électroniques, les rendez-vous, les contacts, les tâches, les entrées du journal, les notes, ainsi que les éléments et documents publiés.) Microsoft Outlook vers le dossier actif ou, s’il s’agit d’un nouvel élément, vers le dossier Outlook par défaut correspondant au type d’élément.

SaveAs Enregistre l’élément (dans Windows). Les éléments incluent les messages électroniques, les rendez-vous, les contacts, les tâches, les entrées du journal, les notes, ainsi que les éléments et documents publiés.) Microsoft Outlook sur le chemin d’accès indiqué et au format du type de fichier spécifié. Si ce dernier n’est pas précisé, le format MSG (.msg) est utilisé.