Discussion :

[sakhob]

Bonjour,
je me permets de vous écrire pour solliciter votre aide.
je m'explique:

j'ai un fichier (echantillon pour test) avec en colonne A la ident,colonne B la date ,colonne C immat,colonne D corporel(o/n),colonne E statut et en colonne F le %tage de resp
ce que je veux faire c'est ça.
- si j'ai la meme ident en A à la meme date en B avec la meme immat en C alors si en colonne D j'ai du O et N alors je mets tout en "O" sinon je laisse tel quel.
et si en colonne E , j'ai le statut OPEN et Close alors je mets tout en OPEN sinon je laisse tel quel.
ET si en colonne F, j'ai 2 resp qui sont differents je prend le plus grand partout.

je fais ça pour toutes les lignes où j'ai une meme ident,meme date et meme immat.

j'ai commencé à ecrire un code mais ça marche pas.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
Sub test()
Dim Plage As Range, C As Range, Teste
Dim Offset As Long
Dim derlign, i, j, k As Integer
 
derlign = Range("a65536").End(xlUp).Row
'Plage = .Range(.[A1].Offset(i, 1), .Cells(.Rows.Count, 1 + i).End(xlUp))
'With Sheets("New")
 
For j = 2 To derlign + 1
 
If Cells(j - 1, 1) = Cells(j, 1) And Cells(j - 1, 2) = Cells(j, 2) And Cells(j - 1, 3) = Cells(j, 3) Then
 
  If Cells(j - 1, 4).Value <> Cells(j, 4).Value Then Range("d" & j - 1).Value = "O" And Range("d" & j) = "O"
 
    End If
 
  If Cells(j - 1, 5).Value <> Cells(j, 5).Value Then Range("e" & j - 1).Value = "OPEN" And Range("e" & j).Value = "OPEN"
 
 
 
If Cells(j - 1, 6).Value <> Cells(j, 6).Value Then Cells(j - 1, 6).Value = 100 And Cells(j, 4).Value = O
 
End
 
Next
 
 
End Sub

je vous joint le fichier pour plus d'explication
merci de votre aide

[parmi]

Bonjour,

Je n'ouvre pas les fichiers avec macros...

Ici

If Cells(j - 1, 1) = Cells(j, 1) And Cells(j - 1, 2) = Cells(j, 2) And Cells(j - 1, 3) = Cells(j, 3) Then
If Cells(j - 1, 4).Value <> Cells(j, 4).Value Then Range("d" & j - 1).Value = "O" And Range("d" & j) = "O" End If

Tu ne peux pas mettre ce AND
Essaie plutôt

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
If Cells(j - 1, 1) = Cells(j, 1) And Cells(j - 1, 2) = Cells(j, 2) And Cells(j - 1, 3) = Cells(j, 3) Then
  If Cells(j - 1, 4).Value <> Cells(j, 4).Value Then 
      Range("d" & j - 1).Value = "O" 
      Range("d" & j) = "O"
  End If
End If

[sakhob]

Merci parmi pour l'intervention.
pour info j'ai enlever les macro dans le fichier
pour vérifier la 2 eme et la 3 eme condition c'est la ou je bloque.
je renvoi le fichier sans macro

[parmi]

Tu n'as qu'à utiliser la même méthode que je t'ai mise pour la 1ere condition.
Enlève le AND et mets tes résultats sur plusieurs lignes.

[sakhob]

Bonsoir
j ai fait comme tu as dit mais sa l fait que pour la colonne D mais rien en E et F.
en plus il ne fait rien sur les suivantes.
merci de votre aide

[parmi]

Bon, essaie comme ceci et essaie de comprendre ce que ça fait.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub test()
    Dim derlign As Long, j As Long
    Dim Valeur
 
    derlign = Range("a65536").End(xlUp).Row
 
    For j = 2 To derlign + 1
        If Cells(j - 1, 1) = Cells(j, 1) And Cells(j - 1, 2) = Cells(j, 2) And Cells(j - 1, 3) = Cells(j, 3) Then
            If Cells(j - 1, 4).Value <> Cells(j, 4).Value Then
                Range("d" & j - 1).Value = "O"
                Range("d" & j) = "O"
            End If
            If Cells(j - 1, 5).Value <> Cells(j, 5).Value Then
                Range("e" & j - 1).Value = "OPEN"
                Range("e" & j).Value = "OPEN"
            End If
            If Cells(j - 1, 6).Value <> Cells(j, 6).Value Then
                Valeur = Application.WorksheetFunction.Max(Cells(j - 1, 6).Value, Cells(j, 6).Value)
                Range("f" & j - 1).Value = Valeur
                Range("f" & j).Value = Valeur
            End If
        End If
    Next
End Sub

[joe.levrai]

Bonjour,

une autre approche, pour éviter la multiplication des AND et des If
Bien sûr, je suis (comme probablement parmi) parti du principe qu'il les données sont triées vu la façon dont tu les parcours

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub test()
Dim j As Long, i As Long, Valeur
    For j = 2 To Cells(Rows.Count, 1).End(xlUp).Row
        If Join(Application.Transpose(Application.Transpose(Cells(j, 1).Resize(1, 3).Offset(-1, 0).Value))) = _
           Join(Application.Transpose(Application.Transpose(Cells(j, 1).Resize(1, 3).Value))) Then
            For i = 4 To 6
                If Cells(j - 1, i).Value <> Cells(j, i).Value Then
                    Select Case i
                        Case 4: Valeur = "O"
                        Case 5: Valeur = "OPEN"
                        Case 6: Valeur = Application.WorksheetFunction.Max(Cells(j - 1, i).Value, Cells(j, i).Value)
                    End Select
 
                    Cells(j - 1, i).Resize(2, 1).Value = Valeur
                End If
            Next i
        End If
    Next j
End Sub

[parmi]

Intéressant comme méthode Joe.Levrai

[sakhob]

Merci beaucoup Joe.Levrai et Parmi.
j'y suis presque.
je viens de me rendre compte la 3eme condition n'est pas la bonne.
En effet au lieu de prendre le max en colonne F, je veux prendre le resp de la ligne qui etait initialement à OPEN en colonne E.
Merci de votre aide
cdt

[joe.levrai]

Bonjour,
en inversant l'ordre de traitement des colonnes (on commence par la 6 et on fini par la 4)
et en testant la cellule qui contient OPEN

ça devrait être ce que tu souhaites ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub test()
Dim j As Long, i As Long, Valeur
    For j = 2 To Cells(Rows.Count, 1).End(xlUp).Row
        If Join(Application.Transpose(Application.Transpose(Cells(j, 1).Resize(1, 3).Offset(-1, 0).Value))) = _
           Join(Application.Transpose(Application.Transpose(Cells(j, 1).Resize(1, 3).Value))) Then
            For i = 6 To 4 Step -1
                If Cells(j - 1, i).Value <> Cells(j, i).Value Then
                    Select Case i
                        Case 4: Valeur = "O"
                        Case 5: Valeur = "OPEN"
                        Case 6
                            Valeur = IIf(Cells(j - 1, 5).Value = "OPEN", Cells(j - 1, i).Value, Cells(j, i).Value)
                    End Select
 
                    Cells(j - 1, i).Resize(2, 1).Value = Valeur
                End If
            Next i
        End If
    Next j
End Sub

[sakhob]

c'est exactement ce que je veux.
Mille merci joe.levrai.
merci egalement à parmi.

parcontre je n'ai bien compri ce que fait ces 2 lignes de code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
If Join(Application.Transpose(Application.Transpose(Cells(j, 1).Resize(1, 3).Offset(-1, 0).Value))) = _
           Join(Application.Transpose(Application.Transpose(Cells(j, 1).Resize(1, 3).Value))) Then

et

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

IIf(Cells(j - 1, 5).Value = "OPEN", Cells(j - 1, i).Value, Cells(j, i).Value)

[joe.levrai]

Join est une méthode qui va prendre tous les éléments d'un tableau unidimensionnel, et les concaténer en une seule chaine.
On peut spécifier un séparateur entre chaque élément, là on en a pas besoin

Etant donné qu'une plage de cellule est toujours en deux dimensions, si on est sur une seule ligne, on doit transposer deux fois de suite :

- première transposition : la ligne devient une colonne mais le tableau est toujours en 2D
- seconde transposition : la colonne revient en ligne .... et miracle, le tableau repasse en 1D

(si on était sur une seule colonne, seule la seconde transposition est nécessaire)

On obtient donc une chaine de caractère composée de la réunion des trois cellules, pour tes deux lignes.
On regarde si les chaines sont identiques et on sait si les lignes sont identiques comme ça.


Iif est un traitement conditionnel (comme un traitement If/End If), à la différence qu'on lui demande de vérifier une condition et de faire Action1 si c'est vrai et Action2 si c'est faux

Iif(MaCondition, Traitement si Vrai, Traitement si Faux)
Ca evite le If/Else/End If .... mais attention quand on utilise ça car les deux Action sont évaluées lors du traitement. Donc il faut obligatoirement que les 2 actions sont possibles :

- Iif(i = 1, j = 2, j =3) ==> aucun souci
- Iif(i <> 0, j = 1 / i, j = 25) ==> ça va planter si i = 0 ... car VBA va évaluer quand même l'Action1 et faire 1/0 dans son test (division par 0)

[sakhob]

mille merci
je suis impressioné .
je passe beaucoup de temp pour comprendre les lignes de code.
manque de methodologie je crois.