Discussion :

[PCL51]

Bonjour,

Je ne sais pas écrire de macros alors quand je veux utiliser un bouton commande je passe par l'enregistreur puis je copie/colle. Sauf que là je ne m'en sors pas donc voici un exemple :

Mon tableur utilise deux feuilles A et B. La première utilise tout l'écran d'un T. B. I. alors que la seconde est faite pour être diffusée sur le web voire imprimée en portrait A4. Quand j'ai fini de travailler sur A, je dois passer à B, cliquer sur imprimer et sélectionner pdf pour en fait enregistrer selon le chemin voulu.

Quelqu'un pourrait il m'indiquer le texte à saisir dans visual basic pour que mon bouton de commande (placé dans la feuille A) enregistre la feuille B dans le répertoire "téléchargement" sous le nom "test". Facultatif : Si en plus il pouvait enregistrer tout le tableur sous son nom d'utilisation en cours dans le répertoire "mes documents" ce serait génial.

J'espère avoir été assez clair sinon je peux joindre un fichier.

Merci d'avance.

[kiki29]

Salut, à lire et pratiquer : Excel et l'enregistreur de macro.

Sinon voir Impression de certaines Feuilles d'un classeur via un tableau dans un seul Pdf résultant en bas ce post#1.

Pour accéder au Dossier "mes documents" : résultats sous XP et W10

Un rappel

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Option Explicit
 
Sub Tst()
Dim WshShell As Object, MesDocs As String
    Set WshShell = CreateObject("WScript.Shell")
    MesDocs = WshShell.SpecialFolders("MyDocuments")
    MsgBox MesDocs
    Set WshShell = Nothing
End Sub

[PCL51]

Merci, je vais tâcher de me débrouiller avec ça. En fait j'ai déjà parcouru ces articles mais je n'ai pas compris grand chose

[kiki29]

Re, à adapter à ton contexte

Feuil1 et Feuil2 sont les CodeNames des feuilles

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Option Explicit
 
Sub Macro1()
Dim sDossier As String, sNom As String
 
    sDossier = "C:\Users\kiki\Downloads"
    sNom = "Test.pdf"
 
    Application.ScreenUpdating = False
    Feuil2.Activate
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, _
                                    Filename:=sDossier & "\" & sNom, Quality:=xlQualityStandard, _
                                    IncludeDocProperties:=True, IgnorePrintAreas:=False, OpenAfterPublish:=False
    Feuil1.Activate
    Application.ScreenUpdating = True
End Sub
 
Sub Macro2()
Dim WshShell As Object, sDossierDocs As String
    Set WshShell = CreateObject("WScript.Shell")
    sDossierDocs = WshShell.SpecialFolders("MyDocuments")
    Set WshShell = Nothing
    Application.DisplayAlerts = False
    ThisWorkbook.SaveAs Filename:=sDossierDocs & "\" & ThisWorkbook.Name, _
                          FileFormat:=xlExcel12, CreateBackup:=False
    Application.DisplayAlerts = True
End Sub

[PCL51]

Super. Non seulement ça marche mais en plus je suis sûr que cet exemple pratique va m'aider à comprendre des choses. Vraiment un grand merci!