Discussion :

[havannah]

Bonjour à tous

j'ai dans une colonne B une liste de titres de différentes publications, dont certains contiennent le mot "SWOT". J'aimerais à chaque fois qu'apparaît ce mot dans un titre lui attribuer un id type particulier (par exemple 1) dans une colonne appelée id-type(=colonne A)

J'ai essayé le code suivant mais ça ne marche pas du tout. On dirait que le logiciel ne repère pas le mot SWOT dans la colonne B et attribue 1 indifféremment dans la colonne A. J'ai essayé avec et sans boucle. Est-ce que qqn peut m'aider ? Merci d'avance. Hélène

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Sub swot()
'
' swot Macro
 
Dim*Trouve*As*Range,*PlageDeRecherche*As*Range
Dim*Valeur_Cherchee*As*String
 
Set PlageDeRecherche = Sheets("Feuil1").Range("B2:B7")
Valeur_Cherchee = "SWOT"
Set Trouve = PlageDeRecherche.Cells.find(what:=Valeur_Cherchee, LookAt:=xlWhole)
For i = 2 To 7
If Trouve Is Nothing Then
Sheets("Feuil1").Range("A2:A7").Value = 1
Else
 
Sheets("Feuil1").Range("A2:A7").Value = 2
End If
Next i
End Sub

[eriiic]

Bonjour,

pour 'contient' c'est LookAt:=xlPart
L'aide excel t'aurait fourni la réponse tout de suite.
eric

[anasecu]

Bonjour,

Ton code est un peu bizarre avec tes astérisques et l'erreur signalée par eriiic, je te propose celui-ci qui fonctionne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Sub swot()
'
' swot Macro
 
Dim Trouve As Integer, i As Integer
Dim Valeur_Cherchee As String
 
Valeur_Cherchee = "SWOT"
For i = 2 To 7
    Trouve = InStr(1, Range("B" & i), Valeur_Cherchee)
    If Trouve = 0 Then   ' non trouvé
        Sheets("Feuil1").Range("A" & i).Value = 1
    Else    ' trouvé
        Sheets("Feuil1").Range("A" & i).Value = 2
    End If
Next i
End Sub

[joe.levrai]

Bonjour,

en utilisant la formule NB.SI comme tel (exemple sur A2)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(NB.SI(B2;"*SWOT*");1;2)

On obtient en A2 la valeur 1 si B2 contient SWOT, sinon la valeur de A2 sera 2

On utilise cette formule via la propriété R1C1 pour appliquer la formule sur la plage A2:A7

et si pas besoin de conserver les formules, on remplace par sa valeur

ce qui donne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub toto()
' des variables pour faciliter la lecture
' et la maintenance
Const LaValeur As String = "SWOT"
Dim Plage As Range
 
Set Plage = Range("A2:A7")
    With Plage
        .FormulaR1C1 = "=IF(COUNTIF(RC[1],""*" & LaValeur & "*""),1,2)"
        .Value = .Value ' pour remplacer les formules par la valeur
    End With
End Sub

D'autres méthodes possibles, suivant le contexte

[patricktoulon]

Bonjour
Dans le cadre ou tu utilise une nouvelle colonne alors ne pas se priver de formule je suis Joe sur ce coup la

[Marc-L]

Bonjour !

Joe, il est possible d'utiliser directement la propriété Formula
ou encore FormulaLocal pour une version française d'Excel :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Sub Demo()
    With [A2:A7]
        .FormulaLocal = "=SI(NB.SI(B2;""*SWOT*"");1;2)"
             .Formula = .Value
    End With
End Sub

Sinon ne pas oublier de libérer les variables de type objet (Range) en fin de procédure …

_________________________________________________________________________________________________________

Je suis Paris, Nice, Bruxelles, Charlie, …

[havannah]

Merci pour toutes vos propositions. Elles m'ont aidé à résoudre mon pb.

Bonne soirée,

Hélène