Discussion :

[MEZER]

Bonjour,

je rempli un premier tableau mytab1 a partir d'une plage de cellules. Ensuite je dois remplir un deuxieme tableau mytab2 à partir de mytab1 en ayant éliminé les doublons de la première colonne de mytab1.
pour cela je dois surement faire un redim preserve car le nombre de ligne de mytab2 est dynamique et le nombre de colonnes est toujours égale au nombre de colonne de mytab1. les 2 tableaux sont en option base 1.
Je n'arrive pas a comprendre pourquoi j'ai un message d'erreur "subscript out of range". Pouvez vous m'aider svp?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Dim mytab1() As Variant
Dim mytab2() As Variant
Dim i As Integer
 
Dim j As Integer
Dim k As Integer
Dim doublon As Boolean
 
Dim iCount As Integer
Dim kmax As Integer
 
temp1 = Timer
 
k = 1
mytab1 = Range("A2:AC497").Value
kmax = UBound(mytab1, 2)
doublon = False
 
For i = 1 To UBound(mytab1, 1)
    doublon = False
    For j = i + 1 To UBound(mytab1, 1)
        If mytab1(i, 1) = mytab1(j, 1) Then
            doublon = True
        End If
    Next j
 
    If doublon = False Then
         iCount = iCount + 1
            For k = 1 To UBound(mytab1, 2)      
                ReDim Preserve mytab2(1 To iCount, 1 To kmax)
                mytab2(iCount, k) = mytab1(i, k)
                k = k + 1
            Next k
    End If
Next i
 
Range(Sheets("TEST").Cells(1, 1), Sheets("TEST").Cells(iCount, kmax)) = mytab2

[joe.levrai]

Bonjour,

peux-tu reformuler le comportement attendu ?

Plus précisément : si tu as deux lignes qui ont la même valeur en colonne 1 ... tu conserves les deux lignes ou une seule ? Laquelle des deux ? Ou alors autre comportement ?

[MEZER]

je conserve la premiere ligne de mytab1 qu'il rencontre dans la colonne 1 pour l'inserer dans mytab2

[joe.levrai]

Voici une proposition un peu différente :

- on copie toutes les données dans une nouvelle feuille
- on utilise l'outil "nettoyer les doublons" (removeduplicates) sur la colonne 1
- on a plus qu'à récupérer la plage dédoublonnée
- on supprime la nouvelle feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Sub toto()
Dim Tabl()
 
With ThisWorkbook.Worksheets.Add
   Thisworkbook .Worksheets("MaFeuille").UsedRange.Resize(Feuil1.UsedRange.Rows.Count - 1, Feuil1.UsedRange.Columns.Count).Offset(1, 0).Copy .Cells(1, 1)
 
    With .Cells(1, 1)
        .CurrentRegion.RemoveDuplicates 1
        Tabl = .CurrentRegion.Value
    End With
    Application.DisplayAlerts = False: .Delete: Application.DisplayAlerts = True
End With
 
End Sub

[MEZER]

merci pour ta réponse mais je souhaite utiliser exclusivement des tableaux car je dois également y importer les données de toutes les colonnes et j'ai plein de calculs ensuite à effectuer (je ne veux pas de dico non plus). merci

[Al__22]

Bonjour,

Avec la solution de joe tu as toujours un tableau que je sache, du coup je comprends pas pourquoi tu ne souhaites pas l'utiliser

[MEZER]

je souhaite me perfectionner avec les tableaux....essayer de comprendre leur fonctionnement et essayer de savoir pourquoi mon code bug...

[pijaku]

Bonjour,

Pour reprendre ton code simplement, cette partie ne peut pas fonctionner :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
iCount = iCount + 1
For k = 1 To UBound(mytab1, 2) 
    ReDim Preserve mytab2(1 To iCount, 1 To kmax)
    mytab2(iCount, k) = mytab1(i, k)
    k = k + 1
Next k

Pourquoi?
Un tableau dynamique ne peut faire "évoluer" que sa seconde dimension.

Secundo : tu ne dois pas redimensionner à chaque "tour de boucle" sur k, mais simplement avant la boucle.

Autrement dit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
iCount = iCount + 1
ReDim Preserve mytab2(1 To kmax, 1 To iCount)
For k = 1 To UBound(mytab1, 2) 
    mytab2(k, iCount) = mytab1(i, k)
 'k = k + 1 '==> ???????????????
Next k

Ne te reste plus qu'à transposer le cas échéant ton tableau (avec la fonction Transpose si nb éléments < 65000 et des poussières)

Remarque : Regarde aussi mon commentaire ??? et dis nous a quoi peux bien te servir cette ligne k = k + 1 dans une boucle For k = ... To ... Next k

EDIT :
à lire :
http://didier-gonard.developpez.com/...s-tableau-vba/
également :
http://silkyroad.developpez.com/vba/tableaux/

[MEZER]

Merci pour vos explication...ca marche nickel! bravo