Discussion :

[Papapetch]

Bonjour
J'importe des images dans un état par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.imgPhoto.Picture = CurrentProject.Path & "\Images\Sans-photo.jpg"

Ces images sont rectangulaires et peuvent avoir une présentation verticale ou horizontale.
Est-il possible de faire pivoter les images verticales d'un quart de tour afin d'éviter qu'elles soient comprimées en hauteur ?
Merci pour vos réponses

[Arkham46]

Slt,

Si c'est vraiment important tu peux essayer avec la classe clImage
cf :
http://arkham46.developpez.com/artic...ge/tutosimple/

Je pense qu'il faudrait faire un peu comme dans le tuto et charger l'image dans la liste d'images, en appliquant en plus une transformation de rotation
Puis dessiner l'image sur toute la taille du contrôle.
Bon ça fait peur mais c'est pas si compliqué, une fois le tuto digéré.

En tout cas c'est faisable mais je ne vois que la classe clImage pour retourner une image, ou alors un activeX peut-être mais est-ce qu'il en existe un?

[Papapetch]

Merci pour cette réponse
Je vais bien regarder le tuto et me jeter à l'eau (à première vue, ça parait un peu compliqué pour une débutant).

[Arkham46]

Slt,

J'ai essayé ça donne ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
Option Compare Database
Option Explicit

Private Sub Détail_Format(Cancel As Integer, FormatCount As Integer)
    Dim clImg As ClImage
    Dim lImgWidth As Long, lImgHeight As Long
    If FormatCount = 1 Then
        ' Initialise la classe Image
        Set clImg = New ClImage
        ' Initialisation du contrôle image
        clImg.SetImgCtrl Me.ImgPhoto
        ' On remplit l'image de la couleur de fond de l'état
        clImg.FillColor Me.Section(acDetail).BackColor
        ' Limite la taille de l'image chargée à la largeur du contrôle
        ' (gain de mémoire et de temps d'exécution pour la rotation)
        lImgWidth = Me.ImgPhoto.Width
        ' Chargement de l'image (avec miniature EXIF si elle existe)
        clImg.ImageListAdd "Photo", Me.fichier.Value, lImgWidth, lImgHeight, , , , True
        ' Dessine l'image
        ' Si l'image est verticale on la tourne de 90 degrés vers la gauche
        clImg.PaintImage "Photo", 0, 0, Me.ImgPhoto.Width, Me.ImgPhoto.Height, , _
                         Me.ImgPhoto.SizeMode, Me.ImgPhoto.PictureAlignment, , , _
                         IIf(lImgHeight > lImgWidth, "ROTATELEFT", Null)
        ' Supprimer l'image après l'avoir dessinée
        clImg.ImageListDel "Photo"
        ' Applique les changements dans le contrôle image
        clImg.Repaint
        ' Libère la classe Image
        Set clImg = Nothing
    End If
End Sub

Avec :
ImgPhoto : le contrôle image
fichier : un contrôle qui contient le nom du fichier

N'hésite pas à dire si tu rencontres des difficultés, des bugs, ... ou si ça marche