Discussion :

[mia.555]

Bonjour,

ce code suivant me permet d'ouvrir le chemin d'accès de mon répertoire.et j'aimerais avoir un code qui me permet d'afficher le chemin d'accès de mon fichier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub ParcourirEmplacementPlan_Bouton_Click()
On Error Resume Next
  Dim Chemin As String, dossier As String
 Chemin = Me.EmplacementPlan_Champ
 With Application.FileDialog(msoFileDialogFolderPicker)
 .InitialFileName = Chemin
 .Show
 If .SelectedItems.Count > 0 Then dossier = .SelectedItems(1)
 End With
end sub

merci d'avance

[Philippe Tulliez]

Bonjour,
la propriété Path d'un objet Workbook permet de connaître le chemin du répertoire de cet objet.
Ainsi le code ci-dessous permet d'afficher le chemin du classeur où se trouve le code VBA

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

MsgBox ThisWorkbook.Path

[mia.555]

j'aimerais ouvrir le chemin d'accès d'un fichier

[Menhir]

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

On Error Resume Next

Ca, c'est pas beau.
Je te le déconseille fortement.
Mieux vaut anticiper clairement les cas de dysfonctionnement pour les gérer spécifiquement que de balancer un On Error en début de code qui n'est qu'un emplâtre sur une jambe de bois, c'est à dire qui masque les problèmes au lieu de les résoudre.

j'aimerais ouvrir le chemin d'accès d'un fichier

Qu'est-ce que tu appelles "ouvrir un chemin" ?

[mia.555]

merci pour votre remarque. J'aimerais parcourir sur le chemin c'est à dire l'emplacement de mon fichier si une fois l'emplacement est renseigné sur cette capture. Le code que j'ai au début me permet de parcourir sur le répertoire dans lequel mon fichier est rattaché.

[Menhir]

Tu n'as pas clairement répondu à la question mais si cette ouverture est dans le but d'ouvrir un fichier, alors tu peux utiliser GetOpenFilename en combinaison avec le ThisWorkbook.Path que t'a proposé Philippe Tulliez.
https://msdn.microsoft.com/fr-fr/lib.../ff834966.aspx

[mia.555]

Est ce que c'est possible de l'ouvrir à partir du bouton parcourir?
cette ouverture est dans le but d'ouvrir à partir du bouton partir du bouton parcourir le chemin du fichier

[Menhir]

Désolé mais si tu persistes à ne pas faire d'effort pour donner des explications claire sur ce que tu fais et ce que tu veux faire, je ne pourrais pas t'aider.

[mia.555]

Je m'explique, j'ai mon fichier qui est /mv/documents/dossier1/monfichier .Ainsi j'aimerais qu'une fois que je clique sur le bouton parcourir que ça ouvre une boite de dialogue qui se positionne automatiquement sur monfichier

[Menhir]

Ca, je l'ai compris.
Mais je suppose que si tu ouvres cette boite de dialogue, ce n'est pas uniquement pour l'admirer.
Que veux-tu sélectionner dans cette boite de dialogue ?
Que comptes-tu faire avec ce que tu auras sélectionné ?

Ce n'est pas pour t'embêter que je demande ça mais le code dépend de ces réponses.

[mia.555]

Ma boite de dialogue s'ouvre sur "c:/Mes documents" et moi j'aimerais qu'elle s'ouvre sur mon chemin d'accès que j'ai mis sur mon champ emplacement.

[Menhir]

J'ai posé deux questions simples et claires. Tu n'y réponds pas.
Assez perdu de temps inutilement à essayer de te tirer les vers du nez pour que tu daignes fournir les informations nécessaires à la résolution de ton problème.
Je laisse tomber.

Bonne chance

[Philippe Tulliez]

Bonjour,
Exemple d'une fonction qui utilise la boîte de dialogue Ouverture de fichier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
Function FileOpen(Optional Folder As String) As String
  Dim dlgOpen As FileDialog, FileName As String
  Set dlgOpen = Application.FileDialog(msoFileDialogOpen)
  ' Si l'argument n'est pas rempli, sélection du dossier de ThisWorkbook
  If Len(Folder) = 0 Then Folder = ThisWorkbook.Path
  With dlgOpen
  .Title = "Sélection de fichier"
  .InitialFileName = Folder
  .InitialView = msoFileDialogViewDetails
    If .Show Then
        FileName = .SelectedItems(1)
        FileOpen = Mid(FileName, InStrRev(FileName, "\") + 1)
      Else
        FileOpen = ""
    End If
  End With
End Function

Instruction appelante

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

File = FileOpen

ou

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

File = FileOpen("c:\")

Exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub Main()
 Dim File As String
 File = FileOpen
 If Len(File) Then
    MsgBox "Ouverture de " & File
  Else
    MsgBox "Vous n'avez pas sélectionné de fichier"
  End If
End Sub

[mia.555]

Merci Philippe , ça marche bien mais le problème est que je n'arrive pas à changer le chemin d'accès. Par exemple il m'arrive des fois de choisir un autre fichier que celui qui était dans mon champ emplacement. Et la il n'enregistre pas ce chemin sur mon champ

[mia.555]

Merci à tous .ça marche .Voici le code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
Function FileOpen(Optional Folder As String) As String
  Dim dlgOpen As FileDialog, FileName As String
  Set dlgOpen = Application.FileDialog(msoFileDialogOpen)
  ' Si l'argument n'est pas rempli, sélection du dossier de ThisWorkbook
  If Len(Folder) = 0 Then Folder = Me.EmplacementPlan_Champ
  With dlgOpen
   .AllowMultiSelect = False
  .Title = "Sélection de fichier"
  .InitialFileName = Folder
  .InitialView = msoFileDialogViewDetails
    If .Show Then
        FileName = .SelectedItems(1)
        FileOpen = Mid(FileName, InStrRev(FileName, "\") + 1)
        Me.EmplacementPlan_Champ = .SelectedItems(1)
      Else
        FileOpen = ""
    End If
  End With
End Function

[Philippe Tulliez]

Bonjour,

Merci à tous .ça marche .Voici le code:

Est-ce que je peux savoir quelle différence il y a entre le code que je t'ai proposé et celui que tu publies ?

[mia.555]

Bonjour Philippe,

C'est le même c'est juste que j'ai ajouté deux lignes de code. Merci

[Philippe Tulliez]

Bonjour Mia,

Bonjour Philippe,
C'est le même c'est juste que j'ai ajouté deux lignes de code. Merci

Le but d'une fonction est en principe de récupérer une valeur et en plus de pouvoir l'utiliser dans d'autres procédures du même projet voire de la réutiliser dans d'autres projets.
Ta demande devient enfin plus claire, tu voulais à la fois forcer la boîte de dialogue à afficher les classeurs d'un répertoire définit et en plus de récupérer le chemin complet de celui-ci.

En ajoutant la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Me.EmplacementPlan_Champ = .SelectedItems(1)

dans la fonction que j'ai publiée, tu te coupes de toutes possibilités de l'utiliser ailleurs que dans le UserForm où tu as placé un TextBox nommé EmplacementPlan_Champ (c'est du moins ce que j'ai deviné).

Au lieu de modifier la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Len(Folder) = 0 Then Folder = ThisWorkbook.Path

par

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

If Len(Folder) = 0 Then Folder = Me.EmplacementPlan_Champ

Il était plus cohérent d'appeler la fonction en lui passant Me.EmplacementPlan_Champ comme paramètre permettant ainsi d'avoir le Path du classeur dans le cas où la valeur de Me.EmplacementPlan_Champ est vide

Voici ma fonction (rebaptisée FullNameDlgBoxOpen) remaniée et utilisable avec ou sans la multi sélection puisque tu as également ajouté cette ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Function FullNameDlgBoxOpen(Optional dlgFolder As String, _
                         Optional IsAllowMultiSelect As Boolean) As String
 ' http://philippe.tulliez.be
 ' Fonction renvoyant une chaîne de caractères du ou des fichiers sélectionnés
 '          contenant le chemin complet + nom fichier des fichiers sélectionnés
 '          Les chaînes sont séparées par un ; si plus d'un fichier sélectionné
 ' Arguments
 ' [dlgFolder]          (String)  Chemin où doit se faire la sélection
 '                                Si l'arguement est vide, le chemin est celui du classeur
 ' [IsAllowMultiSelect] (Boolean) Indique si la multi*sélection est autorisée (True)
 Dim dlgOpen As FileDialog, myTable(), Elem As Integer
 Set dlgOpen = Application.FileDialog(msoFileDialogOpen)
 ' Si l'argument n'est pas rempli, sélection du dossier de ThisWorkbook
 If Len(dlgFolder) = 0 Then dlgFolder = ThisWorkbook.Path
 With dlgOpen
 .AllowMultiSelect = IsAllowMultiSelect
 .Title = "Sélection de fichier"
 .InitialFileName = dlgFolder
 .InitialView = msoFileDialogViewDetails
  If .Show Then
   For Elem = 1 To .SelectedItems.Count
    ReDim Preserve myTable(Elem - 1): myTable(Elem - 1) = .SelectedItems(Elem)
   Next
   FullNameDlgBoxOpen = Join(myTable, ";") ' .SelectedItems(1)
  End If
 End With
End Function

Procédure à placer dans un module standard (utilisable ainsi depuis n'importe quelle autre procédure du projet) mais bien entendu peut également être placée dans le UserForm

Dans UserForm il suffit d'appeler la fonction avec argument comme ci-dessous

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub cmdOpenDlgFile_Click()
 Me.EmplacementPlan_Champ = FullNameDlgBoxOpen(Me.EmplacementPlan_Champ)
End Sub

On pourrait aussi ajouter un argument pour le titre de la boîte de dialogue, pour ne renvoyer que le chemin sans le nom du fichier, etc.