Scinder une cellule avec des passages à la ligne (ALT-ENTER) en plusieurs lignes

**MJrush** · 11/01/2017, 22h24

Bonjour,

J'ai converti un fichier pdf en fichier Excel. Je cherche à utiliser les données d'un tableau qui s'y trouve. Malheureusement, la conversion me donne toutes les données dans une même cellule avec des retours de chariots (ALT_ENTER) au lieu de lignes.

En clair...

J'ai dans la cellule A1
client1
client2
client3

Au lieu d'avoir
cellule A1 : client1
cellule A2: client2
cellule A3: client3

Comment puisque traiter la cellule A1 pour que ses lignes se répartissent en A1, A2 et A3 ?

Merci d'avance!

MJ

Invité · 12/01/2017, 03h36

Envoyé par MJrush

Bonjour,

Essayez ce code à placer dans un module standard de votre fichier (ou d'un autre). Le principe est de balayer un onglet source et de déverser le résultat sur un onglet cible.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
 
Sub TestSpliterLesCellulesAvecRetourChariot()
 
    SpliterLesCellulesAvecRetourChariot Sheets("Source"), Sheets("Cible")
 
End Sub
 
Sub SpliterLesCellulesAvecRetourChariot(ByVal FeuilleSource As Worksheet, ByVal FeuilleCible As Worksheet)
 
Dim RetoursChariots As Variant
Dim I As Long, J As Long
Dim PremiereLigneSource As Long, DerniereLigneSource As Long
Dim LigneCible As Long
 
    With FeuilleCible
         LigneCible = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
    End With
 
    With FeuilleSource
         PremiereLigneSource = 1
         DerniereLigneSource = .Cells(.Rows.Count, 1).End(xlUp).Row
         For I = PremiereLigneSource To DerniereLigneSource
             RetoursChariots = Split(.Cells(I, 1), Chr(10))
             If UBound(RetoursChariots) > 0 Then
                For J = LBound(RetoursChariots) To UBound(RetoursChariots)
                    With FeuilleCible
                         FeuilleCible.Cells(LigneCible, 1) = Trim(RetoursChariots(J))
                         LigneCible = LigneCible + 1
                    End With
                Next J
             Else
                FeuilleCible.Cells(LigneCible, 1) = Trim(.Cells(I, 1))
                LigneCible = LigneCible + 1
             End If
          Next I
   End With
 
End Sub

Cordialement.

**unparia** · 12/01/2017, 07h48

Bonjour
On peut rester sur la même feuille avec par exemple ceci (colonne traitée = colonne A)
derlig = Range("A" & Rows.Count).End(xlUp).Row

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
For i = derlig To 1 Step -1
 toto = Split(Range("A" & i).Value, Chr(10))
 For k = 1 To UBound(toto)
   Rows(i + k).Insert
   Range("A" & CStr(i + k)).Value = toto(k)
 Next
   Range("A" & i).Value = toto(0)
Next

Le seul problème, par contre (et ce : quelle que soit la méthode) est de s'assurer de ce que le caractère de saut de ligne présent est bien le caractère 10 et non autre (sinon : modifier chr(10) par ce qui correspond).

**Menhir** · 12/01/2017, 09h29

Méthode simple et rapide :
Tu sélectionnes toutes tes cellules > Ctrl+C
Tu ouvres Word > Ctrl+V
Ruban Accueil > Remplacer > Tu remplaces les " par rien > Remplacer tout
Tu sélectionnes tout > Ctrl+C
Tu retournes sous Exel > Ctrl+V

Normalement, tu devrais avoir toutes tes données dans des cellules séparées.

Mais il serait plus simple de faire directement PDF > Word > Excel et non pas PDF > Excel > Word > Excel.

**MJrush** · 12/01/2017, 22h31

Merci!

Je mets en mémoire les codes vba, mais pour l'instant, le "short and sweet" copier-coller à travers Word fonctionnera.

**IronHeavy** · 05/06/2019, 14h49

Bonjour,

Le sujet a déjà été clôturé, mais serait il possible d'étendre les propositions de UNPARIA et ERIC KERGRESSE à plusieurs colonnes?

ou bien dois-je ouvrir un nouveau sujet?

Merci!

**Menhir** · 05/06/2019, 15h18

Dans un code comme dans l'autre, il suffit de rajouter une boucle For To qui embrasse celles existantes avec une variable d'itération qui aille du numéro de la première colonne au numéro de la dernière.
Et dans l'intérieur de la boucle, remplacer les Range("A" par des Cells dont le second paramètre est cette variable.

Invité · 05/06/2019, 15h27

Envoyé par IronHeavy

Bonjour,

Il vaudrait mieux créer un nouveau sujet et faire référence à ce message en précisant le sens de votre question.
En effet, d'après ce que je comprends, vous voulez déverser le contenu de la matrice RetoursChariots dans ma solution sur la même ligne et donc supprimer l'incrémentation des lignes. Mais j'ai sans doute mal compris.

**IronHeavy** · 05/06/2019, 15h30

J'ouvre un nouveau sujet!

Merci

**IronHeavy** · 05/06/2019, 16h37

Envoyé par Menhir

Dans un code comme dans l'autre, il suffit de rajouter une boucle For To qui embrasse celles existantes avec une variable d'itération qui aille du numéro de la première colonne au numéro de la dernière.
Et dans l'intérieur de la boucle, remplacer les Range("A" par des Cells dont le second paramètre est cette variable.

Ci dessous mon adaptation...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
Sub TestSpliterLesCellulesAvecRetourChariot()
 
    SpliterLesCellulesAvecRetourChariot Sheets("Source"), Sheets("Cible")
 
End Sub
 
Sub SpliterLesCellulesAvecRetourChariot(ByVal FeuilleSource As Worksheet, ByVal FeuilleCible As Worksheet)
 
Dim RetoursChariots As Variant
Dim I As Long, J As Long
Dim PremiereLigneSource As Long, DerniereLigneSource As Long
Dim LigneCible As Long
 
    With FeuilleCible
         LigneCible = .Cells(.Rows.Count, 2).End(xlUp).Row + 1
    End With
 
    With FeuilleSource
         PremiereLigneSource = 1
         DerniereLigneSource = .Cells(.Rows.Count, 2).End(xlUp).Row
         PremiereColonneSource = 1
         DerniereColonneSource = 3
 
         For I = PremiereLigneSource To DerniereLigneSource
         For K = PremiereColonneSource To DerniereColonneSource
             RetoursChariots = Split(.Cells(I, K), Chr(10))
             If UBound(RetoursChariots) > 0 Then
                For J = LBound(RetoursChariots) To UBound(RetoursChariots)
                    With FeuilleCible
                         FeuilleCible.Cells(LigneCible, K) = Trim(RetoursChariots(J))
                         LigneCible = LigneCible + 1
                    End With
                Next J
             Else
                FeuilleCible.Cells(LigneCible, K) = Trim(.Cells(I, K))
                LigneCible = LigneCible + 1
             End If
             Next K
          Next I
   End With
End Sub

J'observe un décalage de 1 ligne entre la colonne B et la colonne 1 et encore 1 ligne entre la C et la B ... ? il doit s'agir d'une erreur de ma part. Puis des sauts de lignes coordonnés mais surnuméraires...

D'autre part, mais cela vient probablement du fichier d'origine, certaines cellules en C ne sont pas en face de leurs sœurs en B (43 occurences). Mais ailleurs ça tombe juste... (32 occurences)?

fichier TEST:

TEST NOMENCLATURE.xlsm

**pepesese** · 17/03/2023, 13h38

Bonjour,
Je viens d'utiliser cette macro pour mon fichier.
Elle fonctionne très bien.
Mais lorsque vous avez une cellule intercalée avec une seule ligne de caractères(sans retour à la ligne ALT-ENTER), celle-ci n'est pas recopiée .
Est-ce qu'il y a une possibilité de faire évoluer cette macro?
Merci d'avance pour vos réponses .
Je ne suis qu'un petit utilisateur d'excel, avec zéro connaissance en programmation.

**Raccourcix** · 17/03/2023, 14h16

Bonjour

Pour info, si vous utilisez une version récente d'Excel365 vous disposez désormais de la fonction FRACTIONNER.TEXTE

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

FRACTIONNER.TEXTE(A1;CAR(10))

renverra le contenu de A1 sur plusieurs colonnes suivant les retours ALT+ENTREE

ajoutez un TRANSPOSE pour avoir le résultat en lignes

Stéphane

**pepesese** · 17/03/2023, 15h21

Merci raccourcix pour ta réponse, mais je n'ai pas office365.
De plus j'ai apporté deux modifications à la macro précédente pour mes besoins.

Scinder une cellule avec des passages à la ligne (ALT-ENTER) en plusieurs lignes

Excel

Discussions similaires

Partager

Partager